extra/gpu/framebuffers/framebuffers.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien.c-types alien.data arrays byte-arrays
   3 combinators destructors gpu gpu.buffers gpu.private gpu.textures
   4 gpu.textures.private images kernel locals math math.rectangles
   5 opengl opengl.framebuffers opengl.gl opengl.textures sequences
   6 specialized-arrays typed ui.gadgets.worlds variants ;
   7 SPECIALIZED-ARRAY: int
   8 SPECIALIZED-ARRAY: uint
   9 IN: gpu.framebuffers
  10
  11 SINGLETON: system-framebuffer
  12
  13 TUPLE: renderbuffer < gpu-object
  14     { component-order component-order initial: RGBA }
  15     { component-type component-type initial: ubyte-components }
  16     { samples integer initial: 0 } ;
  17
  18 <PRIVATE
  19
  20 : get-framebuffer-int ( enum -- value )
  21     GL_RENDERBUFFER swap 0 int <ref>
  22     [ glGetRenderbufferParameteriv ] keep int deref ;
  23
  24 PRIVATE>
  25
  26 TYPED:: allocate-renderbuffer ( renderbuffer: renderbuffer dim -- )
  27     GL_RENDERBUFFER renderbuffer handle>> glBindRenderbuffer
  28     GL_RENDERBUFFER
  29     renderbuffer samples>> dup zero?
  30     [ drop renderbuffer texture-gl-internal-format dim first2 glRenderbufferStorage ]
  31     [ renderbuffer texture-gl-internal-format dim first2 glRenderbufferStorageMultisample ]
  32     if ;
  33
  34 TYPED:: renderbuffer-dim ( renderbuffer: renderbuffer -- dim: array )
  35     GL_RENDERBUFFER renderbuffer handle>> glBindRenderbuffer
  36     GL_RENDERBUFFER_WIDTH get-framebuffer-int
  37     GL_RENDERBUFFER_HEIGHT get-framebuffer-int 2array ;
  38
  39 TYPED: <renderbuffer> ( component-order: component-order
  40                         component-type: component-type
  41                         samples
  42                         dim
  43                         --
  44                         renderbuffer )
  45     [ [ gen-renderbuffer ] 3dip renderbuffer boa dup ] dip
  46     [ allocate-renderbuffer ] [ drop ] if*
  47     window-resource ;
  48
  49 M: renderbuffer dispose
  50     [ [ delete-renderbuffer ] when* f ] change-handle drop ;
  51
  52 TUPLE: texture-1d-attachment
  53     { texture texture-1d-data-target read-only initial: T{ texture-1d } }
  54     { level integer read-only } ;
  55
  56 C: <texture-1d-attachment> texture-1d-attachment
  57
  58 TUPLE: texture-2d-attachment
  59     { texture texture-2d-data-target read-only initial: T{ texture-2d } }
  60     { level integer read-only } ;
  61
  62 C: <texture-2d-attachment> texture-2d-attachment
  63
  64 TUPLE: texture-3d-attachment
  65     { texture texture-3d read-only initial: T{ texture-3d } }
  66     { z-offset integer read-only }
  67     { level integer read-only } ;
  68
  69 C: <texture-3d-attachment> texture-3d-attachment
  70
  71 TUPLE: texture-layer-attachment
  72     { texture texture-3d-data-target read-only initial: T{ texture-3d } }
  73     { layer integer read-only }
  74     { level integer read-only } ;
  75
  76 C: <texture-layer-attachment> texture-layer-attachment
  77
  78 UNION: texture-attachment
  79     texture-1d-attachment texture-2d-attachment texture-3d-attachment texture-layer-attachment ;
  80
  81 M: texture-attachment dispose texture>> dispose ;
  82
  83 UNION: framebuffer-attachment renderbuffer texture-attachment ;
  84 UNION: ?framebuffer-attachment framebuffer-attachment POSTPONE: f ;
  85
  86 GENERIC: attachment-object ( attachment -- object )
  87 M: renderbuffer attachment-object ;
  88 M: texture-attachment attachment-object texture>> texture-object ;
  89
  90 TUPLE: framebuffer < gpu-object
  91     { color-attachments array read-only }
  92     { depth-attachment ?framebuffer-attachment read-only initial: f }
  93     { stencil-attachment ?framebuffer-attachment read-only initial: f } ;
  94
  95 UNION: any-framebuffer system-framebuffer framebuffer ;
  96
  97 VARIANT: framebuffer-attachment-side
  98     left-side right-side ;
  99
 100 VARIANT: framebuffer-attachment-face
 101     back-face front-face ;
 102
 103 UNION: ?framebuffer-attachment-side framebuffer-attachment-side POSTPONE: f ;
 104 UNION: ?framebuffer-attachment-face framebuffer-attachment-face POSTPONE: f ;
 105
 106 VARIANT: color-attachment-ref
 107     default-attachment
 108     system-attachment: {
 109         { side ?framebuffer-attachment-side initial: f }
 110         { face ?framebuffer-attachment-face initial: back-face }
 111     }
 112     color-attachment: { { index integer } } ;
 113
 114 VARIANT: non-color-attachment-ref
 115     depth-attachment
 116     stencil-attachment ;
 117
 118 UNION: attachment-ref
 119     color-attachment-ref
 120     non-color-attachment-ref
 121     POSTPONE: f ;
 122
 123 TUPLE: framebuffer-rect
 124     { framebuffer any-framebuffer read-only initial: system-framebuffer }
 125     { attachment color-attachment-ref read-only initial: default-attachment }
 126     { rect rect read-only } ;
 127
 128 C: <framebuffer-rect> framebuffer-rect
 129
 130 TYPED: framebuffer-attachment-at ( framebuffer: framebuffer
 131                                    attachment-ref: attachment-ref
 132                                    --
 133                                    attachment: framebuffer-attachment )
 134     {
 135         { default-attachment [ color-attachments>> first ] }
 136         { color-attachment [ swap color-attachments>> nth ] }
 137         { depth-attachment [ depth-attachment>> ] }
 138         { stencil-attachment [ stencil-attachment>> ] }
 139     } match ;
 140
 141 <PRIVATE
 142
 143 GENERIC: framebuffer-handle ( framebuffer -- handle )
 144
 145 M: system-framebuffer framebuffer-handle drop 0 ;
 146 M: framebuffer framebuffer-handle handle>> ;
 147
 148 GENERIC# allocate-framebuffer-attachment 1 ( framebuffer-attachment dim -- )
 149
 150 M: texture-attachment allocate-framebuffer-attachment
 151     [ [ texture>> ] [ level>> ] bi ] dip f allocate-texture ;
 152 M: renderbuffer allocate-framebuffer-attachment
 153     allocate-renderbuffer ;
 154
 155 GENERIC: framebuffer-attachment-dim ( framebuffer-attachment -- dim )
 156
 157 M: texture-attachment framebuffer-attachment-dim
 158     [ texture>> ] [ level>> ] bi texture-dim
 159     dup number? [ 1 2array ] [ 2 head ] if ;
 160
 161 M: renderbuffer framebuffer-attachment-dim
 162     renderbuffer-dim ;
 163
 164 : each-attachment ( framebuffer quot: ( attachment -- ) -- )
 165     [ [ color-attachments>> ] dip each ]
 166     [ swap depth-attachment>>   [ swap call ] [ drop ] if* ]
 167     [ swap stencil-attachment>> [ swap call ] [ drop ] if* ] 2tri ; inline
 168
 169 :: each-attachment-target ( framebuffer quot: ( attachment-target attachment -- ) -- )
 170     framebuffer color-attachments>>
 171     [| attachment n | n GL_COLOR_ATTACHMENT0 + attachment quot call ] each-index
 172     framebuffer depth-attachment>>
 173     [| attachment | GL_DEPTH_ATTACHMENT attachment quot call ] when*
 174     framebuffer stencil-attachment>>
 175     [| attachment | GL_STENCIL_ATTACHMENT attachment quot call ] when* ; inline
 176
 177 GENERIC: bind-framebuffer-attachment ( attachment-target attachment -- )
 178
 179 M:: renderbuffer bind-framebuffer-attachment ( attachment-target renderbuffer -- )
 180     GL_DRAW_FRAMEBUFFER attachment-target
 181     GL_RENDERBUFFER renderbuffer handle>>
 182     glFramebufferRenderbuffer ;
 183
 184 M:: texture-1d-attachment bind-framebuffer-attachment ( attachment-target texture-attachment -- )
 185     GL_DRAW_FRAMEBUFFER attachment-target
 186     texture-attachment [ texture>> [ texture-data-gl-target ] [ texture-object handle>> ] bi ] [ level>> ] bi
 187     glFramebufferTexture1D ;
 188
 189 M:: texture-2d-attachment bind-framebuffer-attachment ( attachment-target texture-attachment -- )
 190     GL_DRAW_FRAMEBUFFER attachment-target
 191     texture-attachment [ texture>> [ texture-data-gl-target ] [ texture-object handle>> ] bi ] [ level>> ] bi
 192     glFramebufferTexture2D ;
 193
 194 M:: texture-3d-attachment bind-framebuffer-attachment ( attachment-target texture-attachment -- )
 195     GL_DRAW_FRAMEBUFFER attachment-target
 196     texture-attachment
 197     [ texture>> [ texture-data-gl-target ] [ texture-object handle>> ] bi ]
 198     [ level>> ] [ z-offset>> ] tri
 199     glFramebufferTexture3D ;
 200
 201 M:: texture-layer-attachment bind-framebuffer-attachment ( attachment-target texture-attachment -- )
 202     GL_DRAW_FRAMEBUFFER attachment-target
 203     texture-attachment
 204     [ texture>> texture-object handle>> ]
 205     [ level>> ] [ layer>> ] tri
 206     glFramebufferTextureLayer ;
 207
 208 GENERIC: (default-gl-attachment) ( framebuffer -- gl-attachment )
 209 GENERIC: (default-attachment-type) ( framebuffer -- type )
 210 GENERIC: (default-attachment-image-type) ( framebuffer -- order type )
 211
 212 M: system-framebuffer (default-gl-attachment)
 213     drop GL_BACK ;
 214 M: framebuffer (default-gl-attachment)
 215     drop GL_COLOR_ATTACHMENT0 ;
 216
 217 SYMBOLS: float-type int-type uint-type ;
 218
 219 : (color-attachment-type) ( framebuffer index -- type )
 220     swap color-attachments>> nth attachment-object component-type>> {
 221         { [ dup signed-unnormalized-integer-components?   ] [ drop int-type  ] }
 222         { [ dup unsigned-unnormalized-integer-components? ] [ drop uint-type ] }
 223         [ drop float-type ]
 224     } cond ;
 225
 226 M: system-framebuffer (default-attachment-type)
 227     drop float-type ;
 228 M: framebuffer (default-attachment-type)
 229     0 (color-attachment-type) ;
 230
 231 M: system-framebuffer (default-attachment-image-type) ( framebuffer -- order type )
 232     drop RGBA ubyte-components ;
 233 M: framebuffer (default-attachment-image-type) ( framebuffer -- order type )
 234     color-attachments>> first attachment-object
 235     [ component-order>> ] [ component-type>> ] bi ;
 236
 237 : gl-system-attachment ( side face -- attachment )
 238     2array {
 239         { { f          f          } [ GL_FRONT_AND_BACK ] }
 240         { { f          front-face } [ GL_FRONT          ] }
 241         { { f          back-face  } [ GL_BACK           ] }
 242         { { left-side  f          } [ GL_LEFT           ] }
 243         { { left-side  front-face } [ GL_FRONT_LEFT     ] }
 244         { { left-side  back-face  } [ GL_BACK_LEFT      ] }
 245         { { right-side f          } [ GL_RIGHT          ] }
 246         { { right-side front-face } [ GL_FRONT_RIGHT    ] }
 247         { { right-side back-face  } [ GL_BACK_RIGHT     ] }
 248     } case ;
 249
 250 : gl-attachment ( framebuffer attachment-ref -- gl-attachment )
 251     [ {
 252         { depth-attachment [ GL_DEPTH_ATTACHMENT ] }
 253         { stencil-attachment [ GL_STENCIL_ATTACHMENT ] }
 254         { color-attachment [ GL_COLOR_ATTACHMENT0 + ] }
 255         { system-attachment [ gl-system-attachment ] }
 256         { default-attachment [ dup (default-gl-attachment) ] }
 257     } match ] [ GL_NONE ] if* nip ;
 258
 259 : color-attachment-image-type ( framebuffer attachment-ref -- order type )
 260     {
 261         { color-attachment [
 262             swap color-attachments>> nth
 263             attachment-object [ component-order>> ] [ component-type>> ] bi
 264         ] }
 265         { system-attachment [ 3drop RGBA ubyte-components ] }
 266         { default-attachment [ (default-attachment-image-type) ] }
 267     } match ;
 268
 269 : framebuffer-rect-image-type ( framebuffer-rect -- order type )
 270     [ framebuffer>> ] [ attachment>> ] bi color-attachment-image-type ;
 271
 272 HOOK: (clear-integer-color-attachment) gpu-api ( type value -- )
 273
 274 M: opengl-2 (clear-integer-color-attachment)
 275     4 0 pad-tail first4
 276     swap {
 277         { int-type [ glClearColorIiEXT ] }
 278         { uint-type [ glClearColorIuiEXT ] }
 279     } case GL_COLOR_BUFFER_BIT glClear ;
 280
 281 M: opengl-3 (clear-integer-color-attachment)
 282     [ GL_COLOR 0 ] dip 4 0 pad-tail
 283     swap {
 284         { int-type  [ int >c-array  glClearBufferiv  ] }
 285         { uint-type [ uint >c-array glClearBufferuiv ] }
 286     } case ;
 287
 288 :: (clear-color-attachment) ( type attachment value -- )
 289     attachment glDrawBuffer
 290     type float-type =
 291     [ value 4 value last pad-tail first4 glClearColor GL_COLOR_BUFFER_BIT glClear ]
 292     [ type value (clear-integer-color-attachment) ] if ;
 293
 294 : framebuffer-rect-size ( framebuffer-rect -- size )
 295     [ rect>> dim>> product ]
 296     [ framebuffer-rect-image-type (bytes-per-pixel) ] bi * ;
 297
 298 PRIVATE>
 299
 300 TYPED: <full-framebuffer-rect> ( framebuffer: any-framebuffer
 301                                  attachment: attachment-ref
 302                                  --
 303                                  framebuffer-rect: framebuffer-rect )
 304     2dup framebuffer-attachment-at
 305     { 0 0 } swap framebuffer-attachment-dim <rect>
 306     <framebuffer-rect> ;
 307
 308 TYPED: resize-framebuffer ( framebuffer: framebuffer dim -- )
 309     [ allocate-framebuffer-attachment ] curry each-attachment ;
 310
 311 :: attach-framebuffer-attachments ( framebuffer -- )
 312     GL_DRAW_FRAMEBUFFER framebuffer handle>> glBindFramebuffer
 313     framebuffer [ bind-framebuffer-attachment ] each-attachment-target ; inline
 314
 315 M: framebuffer dispose
 316     [ [ delete-framebuffer ] when* f ] change-handle drop ;
 317
 318 TYPED: dispose-framebuffer-attachments ( framebuffer: framebuffer -- )
 319     [ [ dispose ] when* ] each-attachment ;
 320
 321 : <framebuffer> ( color-attachments
 322                   depth-attachment: framebuffer-attachment
 323                   stencil-attachment: framebuffer-attachment
 324                   dim
 325                   --
 326                   framebuffer: framebuffer )
 327     [ [ 0 ] 3dip framebuffer boa dup ] dip
 328     [ resize-framebuffer ] [ drop ] if*
 329     gen-framebuffer >>handle
 330     dup attach-framebuffer-attachments
 331     window-resource ;
 332
 333 TYPED:: clear-framebuffer-attachment ( framebuffer: any-framebuffer
 334                                        attachment-ref: attachment-ref
 335                                        value -- )
 336     GL_DRAW_FRAMEBUFFER framebuffer framebuffer-handle glBindFramebuffer
 337     attachment-ref {
 338         { system-attachment [| side face |
 339             float-type
 340             side face gl-system-attachment
 341             value (clear-color-attachment)
 342         ] }
 343         { color-attachment [| i |
 344             framebuffer i (color-attachment-type)
 345             GL_COLOR_ATTACHMENT0 i +
 346             value (clear-color-attachment)
 347         ] }
 348         { default-attachment [
 349             framebuffer [ (default-attachment-type) ] [ (default-gl-attachment) ] bi
 350             value (clear-color-attachment)
 351         ] }
 352         { depth-attachment   [ value glClearDepth GL_DEPTH_BUFFER_BIT glClear ] }
 353         { stencil-attachment [ value glClearStencil GL_STENCIL_BUFFER_BIT glClear ] }
 354     } match ;
 355
 356 : clear-framebuffer ( framebuffer alist -- )
 357     [ first2 clear-framebuffer-attachment ] with each ; inline
 358
 359 TYPED:: read-framebuffer-to ( framebuffer-rect: framebuffer-rect
 360                               gpu-data-ptr -- )
 361     GL_READ_FRAMEBUFFER framebuffer-rect framebuffer>> framebuffer-handle glBindFramebuffer
 362     framebuffer-rect [ framebuffer>> ] [ attachment>> ] bi gl-attachment glReadBuffer
 363     framebuffer-rect rect>> [ loc>> first2 ] [ dim>> first2 ] bi
 364     framebuffer-rect framebuffer-rect-image-type image-data-format
 365     gpu-data-ptr pixel-pack-buffer [ glReadPixels ] with-gpu-data-ptr ;
 366
 367 : read-framebuffer ( framebuffer-rect -- byte-array )
 368     dup framebuffer-rect-size <byte-array> [ read-framebuffer-to ] keep ; inline
 369
 370 TYPED: read-framebuffer-image ( framebuffer-rect -- image )
 371     [ <image> ] dip {
 372         [ rect>> dim>> >>dim ]
 373         [
 374             framebuffer-rect-image-type
 375             [ >>component-order ] [ >>component-type ] bi*
 376         ]
 377         [ read-framebuffer >>bitmap ]
 378     } cleave ;
 379
 380 TYPED:: copy-framebuffer ( to-fb-rect: framebuffer-rect
 381                            from-fb-rect: framebuffer-rect
 382                            depth? stencil? filter: texture-filter -- )
 383     GL_DRAW_FRAMEBUFFER to-fb-rect framebuffer>> framebuffer-handle glBindFramebuffer
 384     to-fb-rect [ framebuffer>> ] [ attachment>> ] bi gl-attachment glDrawBuffer
 385     GL_READ_FRAMEBUFFER from-fb-rect framebuffer>> framebuffer-handle glBindFramebuffer
 386     from-fb-rect [ framebuffer>> ] [ attachment>> ] bi gl-attachment glReadBuffer
 387     to-fb-rect attachment>> [ GL_COLOR_BUFFER_BIT ] [ 0 ] if
 388     depth?   [ GL_DEPTH_BUFFER_BIT   ] [ 0 ] if bitor
 389     stencil? [ GL_STENCIL_BUFFER_BIT ] [ 0 ] if bitor :> mask
 390
 391     from-fb-rect rect>> rect-extent [ first2 ] bi@
 392     to-fb-rect   rect>> rect-extent [ first2 ] bi@
 393     mask filter gl-mag-filter glBlitFramebuffer ;
 394