extra/gpu/render/render.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien alien.c-types alien.data arrays
   3 assocs classes classes.mixin classes.parser classes.singleton classes.struct
   4 classes.tuple classes.tuple.private combinators combinators.tuple destructors fry
   5 generic generic.parser gpu gpu.buffers gpu.framebuffers
   6 gpu.framebuffers.private gpu.shaders gpu.shaders.private gpu.state
   7 gpu.textures gpu.textures.private math.floats.half images kernel
   8 lexer locals math math.order math.parser namespaces opengl
   9 opengl.gl parser quotations sequences slots sorting
  10 specialized-arrays strings ui.gadgets.worlds variants
  11 vocabs.parser words math.vectors.simd ;
  12 FROM: math => float ;
  13 QUALIFIED-WITH: alien.c-types c
  14 SPECIALIZED-ARRAYS: c:float c:int c:uchar c:ushort c:uint c:void* ;
  15 IN: gpu.render
  16
  17 VARIANT: uniform-type
  18     bool-uniform
  19     bvec2-uniform
  20     bvec3-uniform
  21     bvec4-uniform
  22     uint-uniform
  23     uvec2-uniform
  24     uvec3-uniform
  25     uvec4-uniform
  26     int-uniform
  27     ivec2-uniform
  28     ivec3-uniform
  29     ivec4-uniform
  30     float-uniform
  31     vec2-uniform
  32     vec3-uniform
  33     vec4-uniform
  34
  35     mat2-uniform
  36     mat2x3-uniform
  37     mat2x4-uniform
  38
  39     mat3x2-uniform
  40     mat3-uniform
  41     mat3x4-uniform
  42
  43     mat4x2-uniform
  44     mat4x3-uniform
  45     mat4-uniform
  46
  47     texture-uniform ;
  48
  49 ALIAS: mat2x2-uniform mat2-uniform
  50 ALIAS: mat3x3-uniform mat3-uniform
  51 ALIAS: mat4x4-uniform mat4-uniform
  52
  53 TUPLE: uniform
  54     { name         string   read-only initial: "" }
  55     { uniform-type class    read-only initial: float-uniform }
  56     { dim          maybe{ integer } read-only initial: f } ;
  57
  58 VARIANT: index-type
  59     ubyte-indexes
  60     ushort-indexes
  61     uint-indexes ;
  62
  63 TUPLE: index-range
  64     { start integer read-only }
  65     { count integer read-only } ;
  66
  67 C: <index-range> index-range
  68
  69 TUPLE: multi-index-range
  70     { starts uint-array read-only }
  71     { counts uint-array read-only } ;
  72
  73 C: <multi-index-range> multi-index-range
  74
  75 TUPLE: index-elements
  76     { ptr read-only }
  77     { count integer read-only }
  78     { index-type index-type read-only } ;
  79
  80 C: <index-elements> index-elements
  81
  82 TUPLE: multi-index-elements
  83     { buffer maybe{ buffer } read-only }
  84     { ptrs   read-only }
  85     { counts uint-array read-only }
  86     { index-type index-type read-only } ;
  87
  88 C: <multi-index-elements> multi-index-elements
  89
  90 UNION: vertex-indexes
  91     index-range
  92     multi-index-range
  93     index-elements
  94     multi-index-elements
  95     uchar-array
  96     ushort-array
  97     uint-array ;
  98
  99 VARIANT: primitive-mode
 100     points-mode
 101     lines-mode
 102     line-strip-mode
 103     lines-with-adjacency-mode
 104     line-strip-with-adjacency-mode
 105     line-loop-mode
 106     triangles-mode
 107     triangle-strip-mode
 108     triangles-with-adjacency-mode
 109     triangle-strip-with-adjacency-mode
 110     triangle-fan-mode ;
 111
 112 TUPLE: uniform-tuple ;
 113
 114 ERROR: invalid-uniform-type uniform ;
 115
 116 <PRIVATE
 117
 118 : gl-index-type ( index-type -- gl-index-type )
 119     {
 120         { ubyte-indexes  [ GL_UNSIGNED_BYTE  ] }
 121         { ushort-indexes [ GL_UNSIGNED_SHORT ] }
 122         { uint-indexes   [ GL_UNSIGNED_INT   ] }
 123     } case ; inline
 124
 125 : gl-primitive-mode ( primitive-mode -- gl-primitive-mode )
 126     {
 127         { points-mode         [ GL_POINTS         ] }
 128         { lines-mode          [ GL_LINES          ] }
 129         { line-strip-mode     [ GL_LINE_STRIP     ] }
 130         { line-loop-mode      [ GL_LINE_LOOP      ] }
 131         { triangles-mode      [ GL_TRIANGLES      ] }
 132         { triangle-strip-mode [ GL_TRIANGLE_STRIP ] }
 133         { triangle-fan-mode   [ GL_TRIANGLE_FAN   ] }
 134         { lines-with-adjacency-mode          [ GL_LINES_ADJACENCY          ] }
 135         { line-strip-with-adjacency-mode     [ GL_LINE_STRIP_ADJACENCY     ] }
 136         { triangles-with-adjacency-mode      [ GL_TRIANGLES_ADJACENCY      ] }
 137         { triangle-strip-with-adjacency-mode [ GL_TRIANGLE_STRIP_ADJACENCY ] }
 138     } case ; inline
 139
 140 GENERIC: render-vertex-indexes ( primitive-mode vertex-indexes -- )
 141
 142 GENERIC# render-vertex-indexes-instanced 1 ( primitive-mode vertex-indexes instances -- )
 143
 144 GENERIC: gl-array-element-type ( array -- type )
 145 M: uchar-array  gl-array-element-type drop GL_UNSIGNED_BYTE  ; inline
 146 M: ushort-array gl-array-element-type drop GL_UNSIGNED_SHORT ; inline
 147 M: uint-array   gl-array-element-type drop GL_UNSIGNED_INT   ; inline
 148
 149 M: index-range render-vertex-indexes
 150     [ gl-primitive-mode ] [ [ start>> ] [ count>> ] bi ] bi* glDrawArrays ;
 151
 152 M: index-range render-vertex-indexes-instanced
 153     [ gl-primitive-mode ] [ [ start>> ] [ count>> ] bi ] [ ] tri*
 154     glDrawArraysInstanced ;
 155
 156 M: multi-index-range render-vertex-indexes
 157     [ gl-primitive-mode ] [ [ starts>> ] [ counts>> dup length ] bi ] bi*
 158     glMultiDrawArrays ;
 159
 160 M: index-elements render-vertex-indexes
 161     [ gl-primitive-mode ]
 162     [ [ count>> ] [ index-type>> gl-index-type ] [ ptr>> ] tri ] bi*
 163     index-buffer [ glDrawElements ] with-gpu-data-ptr ;
 164
 165 M: index-elements render-vertex-indexes-instanced
 166     [ gl-primitive-mode ]
 167     [ [ count>> ] [ index-type>> gl-index-type ] [ ptr>> ] tri ]
 168     [ ] tri*
 169     swap index-buffer [ swap glDrawElementsInstanced ] with-gpu-data-ptr ;
 170
 171 M: specialized-array render-vertex-indexes
 172     GL_ELEMENT_ARRAY_BUFFER 0 glBindBuffer
 173     [ gl-primitive-mode ]
 174     [ [ length ] [ gl-array-element-type ] [ >c-ptr ] tri ] bi*
 175     glDrawElements ;
 176
 177 M: specialized-array render-vertex-indexes-instanced
 178     GL_ELEMENT_ARRAY_BUFFER 0 glBindBuffer
 179     [ gl-primitive-mode ]
 180     [ [ length ] [ gl-array-element-type ] [ >c-ptr ] tri ]
 181     [ ] tri* glDrawElementsInstanced ;
 182
 183 M: multi-index-elements render-vertex-indexes
 184     [ gl-primitive-mode ]
 185     [ { [ counts>> ] [ index-type>> gl-index-type ] [ ptrs>> dup length ] [ buffer>> ] } cleave ]
 186     bi*
 187     GL_ELEMENT_ARRAY_BUFFER swap [ handle>> ] [ 0 ] if* glBindBuffer glMultiDrawElements ;
 188
 189 : (bind-texture-unit) ( texture texture-unit -- )
 190     swap [ GL_TEXTURE0 + glActiveTexture ] [ bind-texture drop ] bi* ; inline
 191
 192 GENERIC: (bind-uniform-textures) ( program-instance uniform-tuple -- )
 193 GENERIC: (bind-uniforms) ( program-instance uniform-tuple -- )
 194
 195 M: uniform-tuple (bind-uniform-textures)
 196     2drop ;
 197 M: uniform-tuple (bind-uniforms)
 198     2drop ;
 199
 200 : uniform-slot-type ( uniform -- type )
 201     dup dim>> [ drop sequence ] [
 202         uniform-type>> {
 203             { bool-uniform    [ boolean ] }
 204             { uint-uniform    [ integer ] }
 205             { int-uniform     [ integer ] }
 206             { float-uniform   [ float   ] }
 207             { texture-uniform [ texture ] }
 208             [ drop sequence ]
 209         } case
 210     ] if ;
 211
 212 : uniform>slot ( uniform -- slot )
 213     [ name>> ] [ uniform-slot-type ] bi 2array ;
 214
 215 : uniform-type-texture-units ( uniform-type -- units )
 216     dup texture-uniform = [ drop 1 ] [ "uniform-tuple-texture-units" word-prop 0 or ] if ;
 217
 218 : all-uniform-tuple-slots ( class -- slots )
 219     dup "uniform-tuple-slots" word-prop
 220     [ [ superclass all-uniform-tuple-slots ] dip append ] [ drop { } ] if* ;
 221
 222 DEFER: uniform-texture-accessors
 223
 224 : uniform-type-texture-accessors ( uniform-type -- accessors )
 225     texture-uniform = [ { [ ] } ] [ { } ] if ;
 226
 227 : uniform-slot-texture-accessor ( uniform -- accessor )
 228     [ name>> reader-word ] [ [ uniform-type>> ] [ dim>> ] bi uniform-texture-accessors ] bi
 229     dup length 1 = [ first swap prefix ] [ [ ] 2sequence ] if ;
 230
 231 : uniform-tuple-texture-accessors ( uniform-type -- accessors )
 232     all-uniform-tuple-slots [ uniform-type>> uniform-type-texture-units zero? ] reject
 233     [ uniform-slot-texture-accessor ] map ;
 234
 235 : uniform-texture-accessors ( uniform-type dim -- accessors )
 236     [
 237         dup uniform-type?
 238         [ uniform-type-texture-accessors ]
 239         [ uniform-tuple-texture-accessors ] if
 240     ] [
 241         2dup swap empty? not and [
 242             iota [
 243                 [ swap nth ] swap prefix
 244                 over length 1 = [ swap first append ] [ swap suffix ] if
 245             ] with map
 246         ] [ drop ] if
 247     ] bi* ;
 248
 249 : texture-accessor>cleave ( unit accessors -- unit' cleaves )
 250     dup last sequence?
 251     [ [ last [ texture-accessor>cleave ] map ] [ but-last ] bi swap suffix \ cleave suffix ]
 252     [ over suffix \ (bind-texture-unit) suffix [ 1 + ] dip ] if ;
 253
 254 : [bind-uniform-textures] ( class -- quot )
 255     f uniform-texture-accessors
 256     0 swap [ texture-accessor>cleave ] map nip
 257     \ nip swap \ cleave [ ] 3sequence ;
 258
 259 UNION: binary-data
 260     c-ptr specialized-array struct simd-128 ;
 261
 262 GENERIC: >uniform-bool-array ( sequence -- c-array )
 263 GENERIC: >uniform-int-array ( sequence -- c-array )
 264 GENERIC: >uniform-uint-array ( sequence -- c-array )
 265 GENERIC: >uniform-float-array  ( sequence -- c-array )
 266
 267 GENERIC# >uniform-bvec-array 1 ( sequence dim -- c-array )
 268 GENERIC# >uniform-ivec-array 1 ( sequence dim -- c-array )
 269 GENERIC# >uniform-uvec-array 1 ( sequence dim -- c-array )
 270 GENERIC# >uniform-vec-array  1 ( sequence dim -- c-array )
 271
 272 GENERIC# >uniform-matrix 2 ( sequence cols rows -- c-array )
 273
 274 GENERIC# >uniform-matrix-array 2 ( sequence cols rows -- c-array )
 275
 276 GENERIC: bind-uniform-bvec2 ( index sequence -- )
 277 GENERIC: bind-uniform-bvec3 ( index sequence -- )
 278 GENERIC: bind-uniform-bvec4 ( index sequence -- )
 279 GENERIC: bind-uniform-ivec2 ( index sequence -- )
 280 GENERIC: bind-uniform-ivec3 ( index sequence -- )
 281 GENERIC: bind-uniform-ivec4 ( index sequence -- )
 282 GENERIC: bind-uniform-uvec2 ( index sequence -- )
 283 GENERIC: bind-uniform-uvec3 ( index sequence -- )
 284 GENERIC: bind-uniform-uvec4 ( index sequence -- )
 285 GENERIC: bind-uniform-vec2  ( index sequence -- )
 286 GENERIC: bind-uniform-vec3  ( index sequence -- )
 287 GENERIC: bind-uniform-vec4  ( index sequence -- )
 288
 289 M: object >uniform-bool-array [ >c-bool ] int-array{ } map-as ; inline
 290 M: binary-data >uniform-bool-array ; inline
 291
 292 M: object >uniform-int-array c:int >c-array ; inline
 293 M: binary-data >uniform-int-array ; inline
 294
 295 M: object >uniform-uint-array c:uint >c-array ; inline
 296 M: binary-data >uniform-uint-array ; inline
 297
 298 M: object >uniform-float-array c:float >c-array ; inline
 299 M: binary-data >uniform-float-array ; inline
 300
 301 M: object >uniform-bvec-array '[ _ head-slice [ >c-bool ] int-array{ } map-as ] map concat ; inline
 302 M: binary-data >uniform-bvec-array drop ; inline
 303
 304 M: object >uniform-ivec-array '[ _ head ] map int-array{ } concat-as ; inline
 305 M: binary-data >uniform-ivec-array drop ; inline
 306
 307 M: object >uniform-uvec-array '[ _ head ] map uint-array{ } concat-as ; inline
 308 M: binary-data >uniform-uvec-array drop ; inline
 309
 310 M: object >uniform-vec-array '[ _ head ] map float-array{ } concat-as ; inline
 311 M: binary-data >uniform-vec-array drop ; inline
 312
 313 M:: object >uniform-matrix ( sequence cols rows -- c-array )
 314      sequence flip cols head-slice
 315      [ rows head-slice c:float >c-array ] { } map-as concat ; inline
 316 M: binary-data >uniform-matrix 2drop ; inline
 317
 318 M: object >uniform-matrix-array
 319      '[ _ _ >uniform-matrix ] map concat ; inline
 320 M: binary-data >uniform-matrix-array 2drop ; inline
 321
 322 M: object bind-uniform-bvec2 ( index sequence -- )
 323     1 swap 2 head-slice [ >c-bool ] int-array{ } map-as glUniform2iv ; inline
 324 M: binary-data bind-uniform-bvec2 ( index sequence -- )
 325     1 swap glUniform2iv ; inline
 326 M: object bind-uniform-bvec3 ( index sequence -- )
 327     1 swap 3 head-slice [ >c-bool ] int-array{ } map-as glUniform3iv ; inline
 328 M: binary-data bind-uniform-bvec3 ( index sequence -- )
 329     1 swap glUniform3iv ; inline
 330 M: object bind-uniform-bvec4 ( index sequence -- )
 331     1 swap 4 head-slice [ >c-bool ] int-array{ } map-as glUniform4iv ; inline
 332 M: binary-data bind-uniform-bvec4 ( index sequence -- )
 333     1 swap glUniform4iv ; inline
 334
 335 M: object bind-uniform-ivec2 ( index sequence -- ) first2 glUniform2i ; inline
 336 M: binary-data bind-uniform-ivec2 ( index sequence -- ) 1 swap glUniform2iv ; inline
 337
 338 M: object bind-uniform-ivec3 ( index sequence -- ) first3 glUniform3i ; inline
 339 M: binary-data bind-uniform-ivec3 ( index sequence -- ) 1 swap glUniform3iv ; inline
 340
 341 M: object bind-uniform-ivec4 ( index sequence -- ) first4 glUniform4i ; inline
 342 M: binary-data bind-uniform-ivec4 ( index sequence -- ) 1 swap glUniform4iv ; inline
 343
 344 M: object bind-uniform-uvec2 ( index sequence -- ) first2 glUniform2ui ; inline
 345 M: binary-data bind-uniform-uvec2 ( index sequence -- ) 1 swap glUniform2uiv ; inline
 346
 347 M: object bind-uniform-uvec3 ( index sequence -- ) first3 glUniform3ui ; inline
 348 M: binary-data bind-uniform-uvec3 ( index sequence -- ) 1 swap glUniform3uiv ; inline
 349
 350 M: object bind-uniform-uvec4 ( index sequence -- ) first4 glUniform4ui ; inline
 351 M: binary-data bind-uniform-uvec4 ( index sequence -- ) 1 swap glUniform4uiv ; inline
 352
 353 M: object bind-uniform-vec2 ( index sequence -- ) first2 glUniform2f ; inline
 354 M: binary-data bind-uniform-vec2 ( index sequence -- ) 1 swap glUniform2fv ; inline
 355
 356 M: object bind-uniform-vec3 ( index sequence -- ) first3 glUniform3f ; inline
 357 M: binary-data bind-uniform-vec3 ( index sequence -- ) 1 swap glUniform3fv ; inline
 358
 359 M: object bind-uniform-vec4 ( index sequence -- ) first4 glUniform4f ; inline
 360 M: binary-data bind-uniform-vec4 ( index sequence -- ) 1 swap glUniform4fv ; inline
 361
 362 DEFER: [bind-uniform-tuple]
 363
 364 :: [bind-uniform-array] ( value>>-quot type texture-unit name dim -- texture-unit' quot )
 365     { name uniform-index } >quotation :> index-quot
 366     { index-quot value>>-quot bi* } >quotation :> pre-quot
 367
 368     type H{
 369         { bool-uniform  { dim swap >uniform-bool-array  glUniform1iv  } }
 370         { int-uniform   { dim swap >uniform-int-array   glUniform1iv  } }
 371         { uint-uniform  { dim swap >uniform-uint-array  glUniform1uiv } }
 372         { float-uniform { dim swap >uniform-float-array glUniform1fv  } }
 373
 374         { bvec2-uniform { dim swap 2 >uniform-bvec-array glUniform2iv  } }
 375         { ivec2-uniform { dim swap 2 >uniform-ivec-array glUniform2i  } }
 376         { uvec2-uniform { dim swap 2 >uniform-uvec-array glUniform2ui } }
 377         { vec2-uniform  { dim swap 2 >uniform-vec-array  glUniform2f  } }
 378
 379         { bvec3-uniform { dim swap 3 >uniform-bvec-array glUniform3iv  } }
 380         { ivec3-uniform { dim swap 3 >uniform-ivec-array glUniform3i  } }
 381         { uvec3-uniform { dim swap 3 >uniform-uvec-array glUniform3ui } }
 382         { vec3-uniform  { dim swap 3 >uniform-vec-array  glUniform3f  } }
 383
 384         { bvec4-uniform { dim swap 4 >uniform-bvec-array glUniform4iv  } }
 385         { ivec4-uniform { dim swap 4 >uniform-ivec-array glUniform4iv  } }
 386         { uvec4-uniform { dim swap 4 >uniform-uvec-array glUniform4uiv } }
 387         { vec4-uniform  { dim swap 4 >uniform-vec-array  glUniform4fv  } }
 388
 389         { mat2-uniform   { [ dim 0 ] dip 2 2 >uniform-matrix-array glUniformMatrix2fv   } }
 390         { mat2x3-uniform { [ dim 0 ] dip 2 3 >uniform-matrix-array glUniformMatrix2x3fv } }
 391         { mat2x4-uniform { [ dim 0 ] dip 2 4 >uniform-matrix-array glUniformMatrix2x4fv } }
 392
 393         { mat3x2-uniform { [ dim 0 ] dip 3 2 >uniform-matrix-array glUniformMatrix3x2fv } }
 394         { mat3-uniform   { [ dim 0 ] dip 3 3 >uniform-matrix-array glUniformMatrix3fv   } }
 395         { mat3x4-uniform { [ dim 0 ] dip 3 4 >uniform-matrix-array glUniformMatrix3x4fv } }
 396
 397         { mat4x2-uniform { [ dim 0 ] dip 4 2 >uniform-matrix-array glUniformMatrix4x2fv } }
 398         { mat4x3-uniform { [ dim 0 ] dip 4 3 >uniform-matrix-array glUniformMatrix4x3fv } }
 399         { mat4-uniform   { [ dim 0 ] dip 4 4 >uniform-matrix-array glUniformMatrix4fv   } }
 400
 401         { texture-uniform { drop dim dup iota [ texture-unit + ] int-array{ } map-as glUniform1iv } }
 402     } at [ uniform invalid-uniform-type ] unless* >quotation :> value-quot
 403
 404     type uniform-type-texture-units dim * texture-unit +
 405     pre-quot value-quot append ;
 406
 407 :: [bind-uniform-value] ( value>>-quot type texture-unit name -- texture-unit' quot )
 408     { name uniform-index } >quotation :> index-quot
 409     { index-quot value>>-quot bi* } >quotation :> pre-quot
 410
 411     type H{
 412         { bool-uniform  [ >c-bool glUniform1i  ] }
 413         { int-uniform   [ glUniform1i  ] }
 414         { uint-uniform  [ glUniform1ui ] }
 415         { float-uniform [ glUniform1f  ] }
 416
 417         { bvec2-uniform [ bind-uniform-bvec2 ] }
 418         { ivec2-uniform [ bind-uniform-ivec2 ] }
 419         { uvec2-uniform [ bind-uniform-uvec2 ] }
 420         { vec2-uniform  [ bind-uniform-vec2  ] }
 421
 422         { bvec3-uniform [ bind-uniform-bvec3 ] }
 423         { ivec3-uniform [ bind-uniform-ivec3 ] }
 424         { uvec3-uniform [ bind-uniform-uvec3 ] }
 425         { vec3-uniform  [ bind-uniform-vec3  ] }
 426
 427         { bvec4-uniform [ bind-uniform-bvec4 ] }
 428         { ivec4-uniform [ bind-uniform-ivec4 ] }
 429         { uvec4-uniform [ bind-uniform-uvec4 ] }
 430         { vec4-uniform  [ bind-uniform-vec4  ] }
 431
 432         { mat2-uniform   [ [ 1 0 ] dip 2 2 >uniform-matrix glUniformMatrix2fv   ] }
 433         { mat2x3-uniform [ [ 1 0 ] dip 2 3 >uniform-matrix glUniformMatrix2x3fv ] }
 434         { mat2x4-uniform [ [ 1 0 ] dip 2 4 >uniform-matrix glUniformMatrix2x4fv ] }
 435
 436         { mat3x2-uniform [ [ 1 0 ] dip 3 2 >uniform-matrix glUniformMatrix3x2fv ] }
 437         { mat3-uniform   [ [ 1 0 ] dip 3 3 >uniform-matrix glUniformMatrix3fv   ] }
 438         { mat3x4-uniform [ [ 1 0 ] dip 3 4 >uniform-matrix glUniformMatrix3x4fv ] }
 439
 440         { mat4x2-uniform [ [ 1 0 ] dip 4 2 >uniform-matrix glUniformMatrix4x2fv ] }
 441         { mat4x3-uniform [ [ 1 0 ] dip 4 3 >uniform-matrix glUniformMatrix4x3fv ] }
 442         { mat4-uniform   [ [ 1 0 ] dip 4 4 >uniform-matrix glUniformMatrix4fv   ] }
 443
 444         { texture-uniform { drop texture-unit glUniform1i } }
 445     } at [ uniform invalid-uniform-type ] unless* >quotation :> value-quot
 446
 447     type uniform-type-texture-units texture-unit +
 448     pre-quot value-quot append ;
 449
 450 :: [bind-uniform-struct] ( value>>-quot type texture-unit name dim -- texture-unit' quot )
 451     dim
 452     [
 453         iota
 454         [ [ [ swap nth ] swap prefix ] map ]
 455         [ [ number>string name "[" append "]." surround ] map ] bi
 456     ] [
 457         { [ ] }
 458         name "." append 1array
 459     ] if* :> ( quot-prefixes name-prefixes )
 460     type all-uniform-tuple-slots :> uniforms
 461
 462     texture-unit quot-prefixes name-prefixes [| quot-prefix name-prefix |
 463         uniforms name-prefix [bind-uniform-tuple]
 464         quot-prefix prepend
 465     ] 2map :> ( texture-unit' value-cleave )
 466
 467     texture-unit'
 468     value>>-quot { value-cleave 2cleave } append ;
 469
 470 :: [bind-uniform] ( texture-unit uniform prefix -- texture-unit' quot )
 471     prefix uniform name>> append hyphens>underscores :> name
 472     uniform uniform-type>> :> type
 473     uniform dim>> :> dim
 474     uniform name>> reader-word 1quotation :> value>>-quot
 475
 476     value>>-quot type texture-unit name {
 477         { [ type uniform-type? dim     and ] [ dim [bind-uniform-array] ] }
 478         { [ type uniform-type? dim not and ] [ [bind-uniform-value] ] }
 479         [ dim [bind-uniform-struct] ]
 480     } cond ;
 481
 482 :: [bind-uniform-tuple] ( texture-unit uniforms prefix -- texture-unit' quot )
 483     texture-unit uniforms [ prefix [bind-uniform] ] map :> ( texture-unit' uniforms-cleave )
 484
 485     texture-unit'
 486     { uniforms-cleave 2cleave } >quotation ;
 487
 488 :: [bind-uniforms] ( superclass uniforms -- quot )
 489     superclass "uniform-tuple-texture-units" word-prop 0 or :> first-texture-unit
 490     superclass \ (bind-uniforms) lookup-method :> next-method
 491     first-texture-unit uniforms "" [bind-uniform-tuple] nip :> bind-quot
 492
 493     { 2dup next-method } bind-quot [ ] append-as ;
 494
 495 : define-uniform-tuple-methods ( class superclass uniforms -- )
 496     [
 497         2drop
 498         [ \ (bind-uniform-textures) create-method-in ]
 499         [ [bind-uniform-textures] ] bi define
 500     ] [
 501         [ \ (bind-uniforms) create-method-in ] 2dip
 502         [bind-uniforms] define
 503     ] 3bi ;
 504
 505 : parse-uniform-tuple-definition ( -- class superclass uniforms )
 506     scan-new-class scan-token {
 507         { ";" [ uniform-tuple f ] }
 508         { "<" [ scan-word parse-definition [ first3 uniform boa ] map ] }
 509         { "{" [
 510             uniform-tuple
 511             \ } parse-until parse-definition swap prefix
 512             [ first3 uniform boa ] map
 513         ] }
 514     } case ;
 515
 516 : (define-uniform-tuple) ( class superclass uniforms -- )
 517     {
 518         [ [ uniform>slot ] map define-tuple-class ]
 519         [
 520             [ uniform-type-texture-units ]
 521             [
 522                 [ [ uniform-type>> uniform-type-texture-units ] [ dim>> 1 or ] bi * ]
 523                 [ + ] map-reduce
 524             ] bi* +
 525             "uniform-tuple-texture-units" set-word-prop
 526         ]
 527         [ nip "uniform-tuple-slots" set-word-prop ]
 528         [ define-uniform-tuple-methods ]
 529     } 3cleave ;
 530
 531 : true-subclasses ( class -- seq )
 532     [ subclasses ] keep [ = ] curry reject ;
 533
 534 PRIVATE>
 535
 536 : define-uniform-tuple ( class superclass uniforms -- )
 537     (define-uniform-tuple) ; inline
 538
 539 SYNTAX: UNIFORM-TUPLE:
 540     parse-uniform-tuple-definition define-uniform-tuple ;
 541
 542 <PRIVATE
 543
 544 : bind-unnamed-output-attachments ( framebuffer attachments -- )
 545     [ gl-attachment ] with map
 546     dup length 1 =
 547     [ first glDrawBuffer ]
 548     [ [ length ] [ c:int >c-array ] bi glDrawBuffers ] if ;
 549
 550 : bind-named-output-attachments ( program-instance framebuffer attachments -- )
 551     rot '[ first _ swap output-index ] sort-with values
 552     bind-unnamed-output-attachments ;
 553
 554 : bind-output-attachments ( program-instance framebuffer attachments -- )
 555     dup first sequence?
 556     [ bind-named-output-attachments ] [ [ drop ] 2dip bind-unnamed-output-attachments ] if ;
 557
 558 GENERIC: bind-transform-feedback-output ( output -- )
 559
 560 M: buffer bind-transform-feedback-output
 561     [ GL_TRANSFORM_FEEDBACK_BUFFER 0 ] dip handle>> glBindBufferBase ; inline
 562
 563 M: buffer-range bind-transform-feedback-output
 564     [ GL_TRANSFORM_FEEDBACK_BUFFER 0 ] dip
 565     [ handle>> ] [ offset>> ] [ size>> ] tri glBindBufferRange ; inline
 566
 567 M: buffer-ptr bind-transform-feedback-output
 568     buffer-ptr>range bind-transform-feedback-output ; inline
 569
 570 : gl-feedback-primitive-mode ( primitive-mode -- gl-mode )
 571     {
 572         { points-mode         [ GL_POINTS    ] }
 573         { lines-mode          [ GL_LINES     ] }
 574         { line-strip-mode     [ GL_LINES     ] }
 575         { line-loop-mode      [ GL_LINES     ] }
 576         { triangles-mode      [ GL_TRIANGLES ] }
 577         { triangle-strip-mode [ GL_TRIANGLES ] }
 578         { triangle-fan-mode   [ GL_TRIANGLES ] }
 579     } case ;
 580
 581 PRIVATE>
 582
 583 UNION: transform-feedback-output buffer buffer-range POSTPONE: f ;
 584
 585 TUPLE: render-set
 586     { primitive-mode primitive-mode read-only }
 587     { vertex-array vertex-array initial: T{ vertex-array-collection } read-only }
 588     { uniforms uniform-tuple read-only }
 589     { indexes vertex-indexes initial: T{ index-range } read-only }
 590     { instances maybe{ integer } initial: f read-only }
 591     { framebuffer maybe{ any-framebuffer } initial: system-framebuffer read-only }
 592     { output-attachments sequence initial: { default-attachment } read-only }
 593     { transform-feedback-output transform-feedback-output initial: f read-only } ;
 594
 595 : <render-set> ( x quot-assoc -- render-set )
 596     render-set swap make-tuple ; inline
 597
 598 : 2<render-set> ( x y quot-assoc -- render-set )
 599     render-set swap 2make-tuple ; inline
 600
 601 : 3<render-set> ( x y z quot-assoc -- render-set )
 602     render-set swap 3make-tuple ; inline
 603
 604 : bind-uniforms ( program-instance uniforms -- )
 605     [ (bind-uniform-textures) ] [ (bind-uniforms) ] 2bi ; inline
 606
 607 : render ( render-set -- )
 608     {
 609         [ vertex-array>> program-instance>> handle>> glUseProgram ]
 610         [
 611             [ vertex-array>> program-instance>> ] [ uniforms>> ] bi
 612             bind-uniforms
 613         ]
 614         [
 615             framebuffer>>
 616             [ GL_DRAW_FRAMEBUFFER swap framebuffer-handle glBindFramebuffer ]
 617             [ GL_DRAW_FRAMEBUFFER 0 glBindFramebuffer GL_RASTERIZER_DISCARD glEnable ] if*
 618         ]
 619         [
 620             [ vertex-array>> program-instance>> ]
 621             [ framebuffer>> ]
 622             [ output-attachments>> ] tri
 623             bind-output-attachments
 624         ]
 625         [ vertex-array>> bind-vertex-array ]
 626         [
 627             dup transform-feedback-output>> [
 628                 [ primitive-mode>> gl-feedback-primitive-mode glBeginTransformFeedback ]
 629                 [ bind-transform-feedback-output ] bi*
 630             ] [ drop ] if*
 631         ]
 632
 633         [
 634             [ primitive-mode>> ] [ indexes>> ] [ instances>> ] tri
 635             [ render-vertex-indexes-instanced ]
 636             [ render-vertex-indexes ] if*
 637         ]
 638
 639         [ transform-feedback-output>> [ glEndTransformFeedback ] when ]
 640         [ framebuffer>> [ GL_RASTERIZER_DISCARD glDisable ] unless ]
 641     } cleave ; inline
 642