extra/gpu/textures/textures.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien.c-types arrays byte-arrays combinators
   3 destructors fry gpu gpu.buffers images kernel locals math
   4 opengl opengl.gl opengl.textures sequences
   5 specialized-arrays ui.gadgets.worlds variants ;
   6 SPECIALIZED-ARRAY: float
   7 IN: gpu.textures
   8
   9 TUPLE: texture < gpu-object
  10     { component-order component-order read-only initial: RGBA }
  11     { component-type component-type read-only initial: ubyte-components } ;
  12
  13 TUPLE: texture-1d < texture ;
  14 TUPLE: texture-2d < texture ;
  15 TUPLE: texture-rectangle < texture ;
  16 TUPLE: texture-3d < texture ;
  17 TUPLE: texture-cube-map < texture ;
  18
  19 TUPLE: texture-1d-array < texture ;
  20 TUPLE: texture-2d-array < texture ;
  21
  22 VARIANT: cube-map-axis
  23     -X -Y -Z +X +Y +Z ;
  24
  25 TUPLE: cube-map-face
  26     { texture texture-cube-map read-only }
  27     { axis cube-map-axis read-only } ;
  28 C: <cube-map-face> cube-map-face
  29
  30 UNION: texture-1d-data-target
  31     texture-1d ;
  32 UNION: texture-2d-data-target
  33     texture-2d texture-rectangle texture-1d-array cube-map-face ;
  34 UNION: texture-3d-data-target
  35     texture-3d texture-2d-array ;
  36 UNION: texture-data-target
  37     texture-1d-data-target texture-2d-data-target texture-3d-data-target ;
  38
  39 M: texture dispose
  40     [ [ delete-texture ] when* f ] change-handle drop ;
  41
  42 TUPLE: texture-data
  43     { ptr read-only }
  44     { component-order component-order read-only initial: RGBA }
  45     { component-type component-type read-only initial: ubyte-components } ;
  46
  47 C: <texture-data> texture-data
  48 UNION: ?texture-data texture-data POSTPONE: f ;
  49 UNION: ?float-array float-array POSTPONE: f ;
  50
  51 VARIANT: texture-wrap
  52     clamp-texcoord-to-edge clamp-texcoord-to-border repeat-texcoord repeat-texcoord-mirrored ;
  53 VARIANT: texture-filter
  54     filter-nearest filter-linear ;
  55
  56 UNION: wrap-set texture-wrap sequence ;
  57 UNION: ?texture-filter texture-filter POSTPONE: f ;
  58
  59 TUPLE: texture-parameters
  60     { wrap wrap-set initial: { repeat-texcoord repeat-texcoord repeat-texcoord } }
  61     { min-filter texture-filter initial: filter-nearest }
  62     { min-mipmap-filter ?texture-filter initial: filter-linear }
  63     { mag-filter texture-filter initial: filter-linear }
  64     { min-lod integer initial: -1000 }
  65     { max-lod integer initial:  1000 }
  66     { lod-bias integer initial: 0 }
  67     { base-level integer initial: 0 }
  68     { max-level integer initial: 1000 } ;
  69
  70 <PRIVATE
  71
  72 GENERIC: texture-object ( texture-data-target -- texture )
  73 M: cube-map-face texture-object
  74     texture>> ;
  75 M: texture texture-object
  76     ;
  77
  78 : gl-wrap ( wrap -- gl-wrap )
  79     {
  80         { clamp-texcoord-to-edge [ GL_CLAMP_TO_EDGE ] }
  81         { clamp-texcoord-to-border [ GL_CLAMP_TO_BORDER ] }
  82         { repeat-texcoord [ GL_REPEAT ] }
  83         { repeat-texcoord-mirrored [ GL_MIRRORED_REPEAT ] }
  84     } case ;
  85
  86 : set-texture-gl-wrap ( target wraps -- )
  87     dup sequence? [ 1array ] unless 3 over last pad-tail {
  88         [ [ GL_TEXTURE_WRAP_S ] dip first  gl-wrap glTexParameteri ]
  89         [ [ GL_TEXTURE_WRAP_T ] dip second gl-wrap glTexParameteri ]
  90         [ [ GL_TEXTURE_WRAP_R ] dip third  gl-wrap glTexParameteri ]
  91     } 2cleave ;
  92
  93 : gl-mag-filter ( filter -- gl-filter )
  94     {
  95         { filter-nearest [ GL_NEAREST ] }
  96         { filter-linear [ GL_LINEAR ] }
  97     } case ;
  98
  99 : gl-min-filter ( filter mipmap-filter -- gl-filter )
 100     2array {
 101         { { filter-nearest f              } [ GL_NEAREST                ] }
 102         { { filter-linear  f              } [ GL_LINEAR                 ] }
 103         { { filter-nearest filter-nearest } [ GL_NEAREST_MIPMAP_NEAREST ] }
 104         { { filter-linear  filter-nearest } [ GL_LINEAR_MIPMAP_NEAREST  ] }
 105         { { filter-linear  filter-linear  } [ GL_LINEAR_MIPMAP_LINEAR   ] }
 106         { { filter-nearest filter-linear  } [ GL_NEAREST_MIPMAP_LINEAR  ] }
 107     } case ;
 108
 109 GENERIC: texture-gl-target ( texture -- target )
 110 GENERIC: texture-data-gl-target ( texture -- target )
 111
 112 M: texture-1d        texture-gl-target drop GL_TEXTURE_1D ;
 113 M: texture-2d        texture-gl-target drop GL_TEXTURE_2D ;
 114 M: texture-rectangle texture-gl-target drop GL_TEXTURE_RECTANGLE ;
 115 M: texture-3d        texture-gl-target drop GL_TEXTURE_3D ;
 116 M: texture-cube-map  texture-gl-target drop GL_TEXTURE_CUBE_MAP ;
 117 M: texture-1d-array  texture-gl-target drop GL_TEXTURE_1D_ARRAY ;
 118 M: texture-2d-array  texture-gl-target drop GL_TEXTURE_2D_ARRAY ;
 119
 120 M: texture-1d        texture-data-gl-target drop GL_TEXTURE_1D ;
 121 M: texture-2d        texture-data-gl-target drop GL_TEXTURE_2D ;
 122 M: texture-rectangle texture-data-gl-target drop GL_TEXTURE_RECTANGLE ;
 123 M: texture-3d        texture-data-gl-target drop GL_TEXTURE_3D ;
 124 M: texture-1d-array  texture-data-gl-target drop GL_TEXTURE_1D_ARRAY ;
 125 M: texture-2d-array  texture-data-gl-target drop GL_TEXTURE_2D_ARRAY ;
 126 M: cube-map-face     texture-data-gl-target
 127     axis>> {
 128         { -X [ GL_TEXTURE_CUBE_MAP_NEGATIVE_X ] }
 129         { -Y [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Y ] }
 130         { -Z [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Z ] }
 131         { +X [ GL_TEXTURE_CUBE_MAP_POSITIVE_X ] }
 132         { +Y [ GL_TEXTURE_CUBE_MAP_POSITIVE_Y ] }
 133         { +Z [ GL_TEXTURE_CUBE_MAP_POSITIVE_Z ] }
 134     } case ;
 135
 136 : texture-gl-internal-format ( texture -- internal-format )
 137     [ component-order>> ] [ component-type>> ] bi image-internal-format ; inline
 138
 139 : texture-data-gl-args ( texture data -- format type ptr )
 140     [
 141         nip
 142         [ [ component-order>> ] [ component-type>> ] bi image-data-format ]
 143         [ ptr>> ] bi
 144     ] [
 145         [ component-order>> ] [ component-type>> ] bi image-data-format f
 146     ] if* ;
 147
 148 :: bind-tdt ( tdt -- texture )
 149     tdt texture-object :> texture
 150     texture [ texture-gl-target ] [ handle>> ] bi glBindTexture
 151     texture ;
 152
 153 : get-texture-float ( target level enum -- value )
 154     0 <float> [ glGetTexLevelParameterfv ] keep *float ;
 155 : get-texture-int ( target level enum -- value )
 156     0 <int> [ glGetTexLevelParameteriv ] keep *int ;
 157
 158 : ?product ( x -- y )
 159     dup number? [ product ] unless ;
 160
 161 PRIVATE>
 162
 163 GENERIC# allocate-texture 3 ( tdt level dim data -- )
 164
 165 M:: texture-1d-data-target allocate-texture ( tdt level dim data -- )
 166     tdt bind-tdt :> texture
 167     tdt texture-data-gl-target level texture texture-gl-internal-format
 168     dim 0 texture data texture-data-gl-args
 169     pixel-unpack-buffer [ glTexImage1D ] with-gpu-data-ptr ;
 170
 171 M:: texture-2d-data-target allocate-texture ( tdt level dim data -- )
 172     tdt bind-tdt :> texture
 173     tdt texture-data-gl-target level texture texture-gl-internal-format
 174     dim first2 0 texture data texture-data-gl-args
 175     pixel-unpack-buffer [ glTexImage2D ] with-gpu-data-ptr ;
 176
 177 M:: texture-3d-data-target allocate-texture ( tdt level dim data -- )
 178     tdt bind-tdt :> texture
 179     tdt texture-data-gl-target level texture texture-gl-internal-format
 180     dim first3 0 texture data texture-data-gl-args
 181     pixel-unpack-buffer [ glTexImage3D ] with-gpu-data-ptr ;
 182
 183 GENERIC# update-texture 4 ( tdt level loc dim data -- )
 184
 185 M:: texture-1d-data-target update-texture ( tdt level loc dim data -- )
 186     tdt bind-tdt :> texture
 187     tdt texture-data-gl-target level
 188     loc dim texture data texture-data-gl-args
 189     pixel-unpack-buffer [ glTexSubImage1D ] with-gpu-data-ptr ;
 190
 191 M:: texture-2d-data-target update-texture ( tdt level loc dim data -- )
 192     tdt bind-tdt :> texture
 193     tdt texture-data-gl-target level
 194     loc dim [ first2 ] bi@
 195     texture data texture-data-gl-args
 196     pixel-unpack-buffer [ glTexSubImage2D ] with-gpu-data-ptr ;
 197
 198 M:: texture-3d-data-target update-texture ( tdt level loc dim data -- )
 199     tdt bind-tdt :> texture
 200     tdt texture-data-gl-target level
 201     loc dim [ first3 ] bi@
 202     texture data texture-data-gl-args
 203     pixel-unpack-buffer [ glTexSubImage3D ] with-gpu-data-ptr ;
 204
 205 : image>texture-data ( image -- dim texture-data )
 206     { [ dim>> ] [ bitmap>> ] [ component-order>> ] [ component-type>> ] } cleave
 207     <texture-data> ; inline
 208
 209 GENERIC# texture-dim 1 ( tdt level -- dim )
 210
 211 M:: texture-1d-data-target texture-dim ( tdt level -- dim )
 212     tdt bind-tdt :> texture
 213     tdt texture-data-gl-target level GL_TEXTURE_WIDTH get-texture-int ;
 214
 215 M:: texture-2d-data-target texture-dim ( tdt level -- dim )
 216     tdt bind-tdt :> texture
 217     tdt texture-data-gl-target level
 218     [ GL_TEXTURE_WIDTH get-texture-int ] [ GL_TEXTURE_HEIGHT get-texture-int ] 2bi
 219     2array ;
 220
 221 M:: texture-3d-data-target texture-dim ( tdt level -- dim )
 222     tdt bind-tdt :> texture
 223     tdt texture-data-gl-target level
 224     [ GL_TEXTURE_WIDTH get-texture-int ]
 225     [ GL_TEXTURE_HEIGHT get-texture-int ]
 226     [ GL_TEXTURE_DEPTH get-texture-int ] 2tri
 227     3array ;
 228
 229 : texture-data-size ( tdt level -- size )
 230     [ texture-dim ?product ] [ drop texture-object bytes-per-pixel ] 2bi * ;
 231
 232 :: read-texture-to ( tdt level gpu-data-ptr -- )
 233     tdt bind-tdt :> texture
 234     tdt texture-data-gl-target level
 235     texture [ component-order>> ] [ component-type>> ] bi image-data-format
 236     gpu-data-ptr pixel-pack-buffer [ glGetTexImage ] with-gpu-data-ptr ;
 237
 238 : read-texture ( tdt level -- byte-array )
 239     2dup texture-data-size <byte-array>
 240     [ read-texture-to ] keep ;
 241
 242 : allocate-texture-image ( tdt level image -- )
 243     image>texture-data allocate-texture ;
 244
 245 : update-texture-image ( tdt level loc image -- )
 246     image>texture-data update-texture ;
 247
 248 : read-texture-image ( tdt level -- image )
 249     [ texture-dim ]
 250     [ drop texture-object [ component-order>> ] [ component-type>> ] bi f ]
 251     [ read-texture ] 2tri
 252     image boa ;
 253
 254 <PRIVATE
 255 : bind-texture ( texture -- gl-target )
 256     [ texture-gl-target dup ] [ handle>> ] bi glBindTexture ;
 257 PRIVATE>
 258
 259 : generate-mipmaps ( texture -- )
 260     bind-texture glGenerateMipmap ;
 261
 262 : set-texture-parameters ( texture parameters -- )
 263     [ bind-texture ] dip {
 264         [ wrap>> set-texture-gl-wrap ]
 265         [
 266             [ GL_TEXTURE_MIN_FILTER ] dip
 267             [ min-filter>> ] [ min-mipmap-filter>> ] bi gl-min-filter glTexParameteri
 268         ] [
 269             [ GL_TEXTURE_MAG_FILTER ] dip
 270             mag-filter>> gl-mag-filter glTexParameteri
 271         ]
 272         [ [ GL_TEXTURE_MIN_LOD ] dip min-lod>> glTexParameteri ]
 273         [ [ GL_TEXTURE_MAX_LOD ] dip max-lod>> glTexParameteri ]
 274         [ [ GL_TEXTURE_LOD_BIAS ] dip lod-bias>> glTexParameteri ]
 275         [ [ GL_TEXTURE_BASE_LEVEL ] dip base-level>> glTexParameteri ]
 276         [ [ GL_TEXTURE_MAX_LEVEL ] dip max-level>> glTexParameteri ]
 277     } 2cleave ;
 278
 279 <PRIVATE
 280
 281 : <texture> ( component-order component-type parameters class -- texture )
 282     '[ [ gen-texture ] 2dip _ boa dup window-resource ] dip
 283     [ T{ texture-parameters } clone ] unless* set-texture-parameters ; inline
 284
 285 PRIVATE>
 286
 287 : <texture-1d> ( component-order component-type parameters -- texture )
 288     texture-1d <texture> ;
 289 : <texture-2d> ( component-order component-type parameters -- texture )
 290     texture-2d <texture> ;
 291 : <texture-3d> ( component-order component-type parameters -- texture )
 292     texture-3d <texture> ;
 293 : <texture-cube-map> ( component-order component-type parameters -- texture )
 294     texture-cube-map <texture> ;
 295 : <texture-rectangle> ( component-order component-type parameters -- texture )
 296     texture-rectangle <texture> ;
 297 : <texture-1d-array> ( component-order component-type parameters -- texture )
 298     texture-1d-array <texture> ;
 299 : <texture-2d-array> ( component-order component-type parameters -- texture )
 300     texture-2d-array <texture> ;
 301