extra/gpu/textures/textures.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien.c-types arrays byte-arrays combinators
   3 destructors fry gpu gpu.buffers images kernel locals math
   4 opengl opengl.gl opengl.textures sequences
   5 specialized-arrays typed ui.gadgets.worlds variants ;
   6 FROM: alien.c-types => float ;
   7 SPECIALIZED-ARRAY: float
   8 IN: gpu.textures
   9
  10 TUPLE: texture < gpu-object
  11     { component-order component-order read-only initial: RGBA }
  12     { component-type component-type read-only initial: ubyte-components } ;
  13
  14 TUPLE: texture-1d < texture ;
  15 TUPLE: texture-2d < texture ;
  16 TUPLE: texture-rectangle < texture ;
  17 TUPLE: texture-3d < texture ;
  18 TUPLE: texture-cube-map < texture ;
  19
  20 TUPLE: texture-1d-array < texture ;
  21 TUPLE: texture-2d-array < texture ;
  22
  23 VARIANT: cube-map-axis
  24     -X -Y -Z +X +Y +Z ;
  25
  26 TUPLE: cube-map-face
  27     { texture texture-cube-map read-only }
  28     { axis cube-map-axis read-only } ;
  29 C: <cube-map-face> cube-map-face
  30
  31 UNION: texture-1d-data-target
  32     texture-1d ;
  33 UNION: texture-2d-data-target
  34     texture-2d texture-rectangle texture-1d-array cube-map-face ;
  35 UNION: texture-3d-data-target
  36     texture-3d texture-2d-array ;
  37 UNION: texture-data-target
  38     texture-1d-data-target texture-2d-data-target texture-3d-data-target ;
  39
  40 M: texture dispose
  41     [ [ delete-texture ] when* f ] change-handle drop ;
  42
  43 TUPLE: texture-data
  44     { ptr read-only }
  45     { component-order component-order read-only initial: RGBA }
  46     { component-type component-type read-only initial: ubyte-components } ;
  47
  48 C: <texture-data> texture-data
  49
  50 VARIANT: compressed-texture-format
  51     DXT1-RGB DXT1-RGBA DXT3 DXT5
  52     LATC1 LATC1-SIGNED LATC2 LATC2-SIGNED
  53     RGTC1 RGTC1-SIGNED RGTC2 RGTC2-SIGNED ;
  54
  55 TUPLE: compressed-texture-data
  56     { ptr read-only }
  57     { format compressed-texture-format read-only }
  58     { length integer read-only } ;
  59
  60 C: <compressed-texture-data> compressed-texture-data
  61
  62 VARIANT: texture-wrap
  63     clamp-texcoord-to-edge clamp-texcoord-to-border repeat-texcoord repeat-texcoord-mirrored ;
  64 VARIANT: texture-filter
  65     filter-nearest filter-linear ;
  66
  67 UNION: wrap-set texture-wrap sequence ;
  68
  69 TUPLE: texture-parameters
  70     { wrap wrap-set initial: { repeat-texcoord repeat-texcoord repeat-texcoord } }
  71     { min-filter texture-filter initial: filter-nearest }
  72     { min-mipmap-filter maybe{ texture-filter } initial: filter-linear }
  73     { mag-filter texture-filter initial: filter-linear }
  74     { min-lod integer initial: -1000 }
  75     { max-lod integer initial:  1000 }
  76     { lod-bias integer initial: 0 }
  77     { base-level integer initial: 0 }
  78     { max-level integer initial: 1000 } ;
  79
  80 <PRIVATE
  81
  82 GENERIC: texture-object ( texture-data-target -- texture )
  83 M: cube-map-face texture-object
  84     texture>> ; inline
  85 M: texture texture-object
  86     ; inline
  87
  88 : gl-compressed-texture-format ( format -- gl-format )
  89     {
  90         { DXT1-RGB     [ GL_COMPRESSED_RGB_S3TC_DXT1_EXT  ] }
  91         { DXT1-RGBA    [ GL_COMPRESSED_RGBA_S3TC_DXT1_EXT ] }
  92         { DXT3         [ GL_COMPRESSED_RGBA_S3TC_DXT3_EXT ] }
  93         { DXT5         [ GL_COMPRESSED_RGBA_S3TC_DXT5_EXT ] }
  94         { RGTC1        [ GL_COMPRESSED_RED_RGTC1          ] }
  95         { RGTC1-SIGNED [ GL_COMPRESSED_SIGNED_RED_RGTC1   ] }
  96         { RGTC2        [ GL_COMPRESSED_RG_RGTC2           ] }
  97         { RGTC2-SIGNED [ GL_COMPRESSED_SIGNED_RG_RGTC2    ] }
  98     } case ; inline
  99
 100 : gl-wrap ( wrap -- gl-wrap )
 101     {
 102         { clamp-texcoord-to-edge [ GL_CLAMP_TO_EDGE ] }
 103         { clamp-texcoord-to-border [ GL_CLAMP_TO_BORDER ] }
 104         { repeat-texcoord [ GL_REPEAT ] }
 105         { repeat-texcoord-mirrored [ GL_MIRRORED_REPEAT ] }
 106     } case ; inline
 107
 108 : set-texture-gl-wrap ( target wraps -- )
 109     dup sequence? [ 1array ] unless 3 over last pad-tail {
 110         [ [ GL_TEXTURE_WRAP_S ] dip first  gl-wrap glTexParameteri ]
 111         [ [ GL_TEXTURE_WRAP_T ] dip second gl-wrap glTexParameteri ]
 112         [ [ GL_TEXTURE_WRAP_R ] dip third  gl-wrap glTexParameteri ]
 113     } 2cleave ; inline
 114
 115 : gl-mag-filter ( filter -- gl-filter )
 116     {
 117         { filter-nearest [ GL_NEAREST ] }
 118         { filter-linear [ GL_LINEAR ] }
 119     } case ; inline
 120
 121 : gl-min-filter ( filter mipmap-filter -- gl-filter )
 122     2array {
 123         { { filter-nearest f              } [ GL_NEAREST                ] }
 124         { { filter-linear  f              } [ GL_LINEAR                 ] }
 125         { { filter-nearest filter-nearest } [ GL_NEAREST_MIPMAP_NEAREST ] }
 126         { { filter-linear  filter-nearest } [ GL_LINEAR_MIPMAP_NEAREST  ] }
 127         { { filter-linear  filter-linear  } [ GL_LINEAR_MIPMAP_LINEAR   ] }
 128         { { filter-nearest filter-linear  } [ GL_NEAREST_MIPMAP_LINEAR  ] }
 129     } case ; inline
 130
 131 GENERIC: texture-gl-target ( texture -- target )
 132 GENERIC: texture-data-gl-target ( texture -- target )
 133
 134 M: texture-1d        texture-gl-target drop GL_TEXTURE_1D ; inline
 135 M: texture-2d        texture-gl-target drop GL_TEXTURE_2D ; inline
 136 M: texture-rectangle texture-gl-target drop GL_TEXTURE_RECTANGLE ; inline
 137 M: texture-3d        texture-gl-target drop GL_TEXTURE_3D ; inline
 138 M: texture-cube-map  texture-gl-target drop GL_TEXTURE_CUBE_MAP ; inline
 139 M: texture-1d-array  texture-gl-target drop GL_TEXTURE_1D_ARRAY ; inline
 140 M: texture-2d-array  texture-gl-target drop GL_TEXTURE_2D_ARRAY ; inline
 141
 142 M: texture-1d        texture-data-gl-target drop GL_TEXTURE_1D ; inline
 143 M: texture-2d        texture-data-gl-target drop GL_TEXTURE_2D ; inline
 144 M: texture-rectangle texture-data-gl-target drop GL_TEXTURE_RECTANGLE ; inline
 145 M: texture-3d        texture-data-gl-target drop GL_TEXTURE_3D ; inline
 146 M: texture-1d-array  texture-data-gl-target drop GL_TEXTURE_1D_ARRAY ; inline
 147 M: texture-2d-array  texture-data-gl-target drop GL_TEXTURE_2D_ARRAY ; inline
 148 M: cube-map-face     texture-data-gl-target
 149     axis>> {
 150         { -X [ GL_TEXTURE_CUBE_MAP_NEGATIVE_X ] }
 151         { -Y [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Y ] }
 152         { -Z [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Z ] }
 153         { +X [ GL_TEXTURE_CUBE_MAP_POSITIVE_X ] }
 154         { +Y [ GL_TEXTURE_CUBE_MAP_POSITIVE_Y ] }
 155         { +Z [ GL_TEXTURE_CUBE_MAP_POSITIVE_Z ] }
 156     } case ; inline
 157
 158 : texture-gl-internal-format ( texture -- internal-format )
 159     [ component-order>> ] [ component-type>> ] bi image-internal-format ; inline
 160
 161 : texture-data-gl-args ( texture data -- format type ptr )
 162     [
 163         nip
 164         [ [ component-order>> ] [ component-type>> ] bi image-data-format ]
 165         [ ptr>> ] bi
 166     ] [
 167         [ component-order>> ] [ component-type>> ] bi image-data-format f
 168     ] if* ; inline
 169
 170 :: bind-tdt ( tdt -- texture )
 171     tdt texture-object :> texture
 172     texture [ texture-gl-target ] [ handle>> ] bi glBindTexture
 173     texture ; inline
 174
 175 : ?product ( x -- y )
 176     dup number? [ product ] unless ; inline
 177
 178 :: (allocate-texture) ( tdt level dim data dim-quot teximage-quot -- )
 179     tdt bind-tdt :> texture
 180     tdt texture-data-gl-target level texture texture-gl-internal-format
 181     dim dim-quot call 0 texture data texture-data-gl-args
 182     pixel-unpack-buffer teximage-quot with-gpu-data-ptr ; inline
 183
 184 :: (allocate-compressed-texture) ( tdt level dim compressed-data dim-quot teximage-quot -- )
 185     tdt bind-tdt :> texture
 186     tdt texture-data-gl-target level compressed-data format>> gl-compressed-texture-format
 187     dim dim-quot call 0 compressed-data [ length>> ] [ ptr>> ] bi
 188     pixel-unpack-buffer teximage-quot with-gpu-data-ptr ; inline
 189
 190 :: (update-texture) ( tdt level loc dim data dim-quot texsubimage-quot -- )
 191     tdt bind-tdt :> texture
 192     tdt texture-data-gl-target level
 193     loc dim dim-quot bi@
 194     texture data texture-data-gl-args
 195     pixel-unpack-buffer texsubimage-quot with-gpu-data-ptr ; inline
 196
 197 :: (update-compressed-texture) ( tdt level loc dim compressed-data dim-quot texsubimage-quot -- )
 198     tdt bind-tdt :> texture
 199     tdt texture-data-gl-target level
 200     loc dim dim-quot bi@
 201     compressed-data [ format>> gl-compressed-texture-format ] [ length>> ] [ ptr>> ] tri
 202     pixel-unpack-buffer texsubimage-quot with-gpu-data-ptr ; inline
 203
 204 PRIVATE>
 205
 206 GENERIC#: allocate-texture 3 ( tdt level dim data -- )
 207
 208 M: texture-1d-data-target allocate-texture ( tdt level dim data -- )
 209     [ ] [ glTexImage1D ] (allocate-texture) ;
 210
 211 M: texture-2d-data-target allocate-texture ( tdt level dim data -- )
 212     [ first2 ] [ glTexImage2D ] (allocate-texture) ;
 213
 214 M: texture-3d-data-target allocate-texture ( tdt level dim data -- )
 215     [ first3 ] [ glTexImage3D ] (allocate-texture) ;
 216
 217 GENERIC#: allocate-compressed-texture 3 ( tdt level dim compressed-data -- )
 218
 219 M: texture-1d-data-target allocate-compressed-texture ( tdt level dim compressed-data -- )
 220     [ ] [ glCompressedTexImage1D ] (allocate-compressed-texture) ;
 221
 222 M: texture-2d-data-target allocate-compressed-texture ( tdt level dim compressed-data -- )
 223     [ first2 ] [ glCompressedTexImage2D ] (allocate-compressed-texture) ;
 224
 225 M: texture-3d-data-target allocate-compressed-texture ( tdt level dim compressed-data -- )
 226     [ first3 ] [ glCompressedTexImage3D ] (allocate-compressed-texture) ;
 227
 228 GENERIC#: update-texture 4 ( tdt level loc dim data -- )
 229
 230 M: texture-1d-data-target update-texture ( tdt level loc dim data -- )
 231     [ ] [ glTexSubImage1D ] (update-texture) ;
 232
 233 M: texture-2d-data-target update-texture ( tdt level loc dim data -- )
 234     [ first2 ] [ glTexSubImage2D ] (update-texture) ;
 235
 236 M: texture-3d-data-target update-texture ( tdt level loc dim data -- )
 237     [ first3 ] [ glTexSubImage3D ] (update-texture) ;
 238
 239 GENERIC#: update-compressed-texture 4 ( tdt level loc dim compressed-data -- )
 240
 241 M: texture-1d-data-target update-compressed-texture ( tdt level loc dim compressed-data -- )
 242     [ ] [ glCompressedTexSubImage1D ] (update-compressed-texture) ;
 243
 244 M: texture-2d-data-target update-compressed-texture ( tdt level loc dim compressed-data -- )
 245     [ first2 ] [ glCompressedTexSubImage2D ] (update-compressed-texture) ;
 246
 247 M: texture-3d-data-target update-compressed-texture ( tdt level loc dim compressed-data -- )
 248     [ first3 ] [ glCompressedTexSubImage3D ] (update-compressed-texture) ;
 249
 250 : image>texture-data ( image -- dim texture-data )
 251     { [ dim>> ] [ bitmap>> ] [ component-order>> ] [ component-type>> ] } cleave
 252     <texture-data> ; inline
 253
 254 GENERIC#: texture-dim 1 ( tdt level -- dim )
 255
 256 M:: texture-1d-data-target texture-dim ( tdt level -- dim )
 257     tdt bind-tdt :> texture
 258     tdt texture-data-gl-target level GL_TEXTURE_WIDTH get-texture-int ; inline
 259
 260 M:: texture-2d-data-target texture-dim ( tdt level -- dim )
 261     tdt bind-tdt :> texture
 262     tdt texture-data-gl-target level
 263     [ GL_TEXTURE_WIDTH get-texture-int ] [ GL_TEXTURE_HEIGHT get-texture-int ] 2bi
 264     2array ; inline
 265
 266 M:: texture-3d-data-target texture-dim ( tdt level -- dim )
 267     tdt bind-tdt :> texture
 268     tdt texture-data-gl-target level
 269     [ GL_TEXTURE_WIDTH get-texture-int ]
 270     [ GL_TEXTURE_HEIGHT get-texture-int ]
 271     [ GL_TEXTURE_DEPTH get-texture-int ] 2tri
 272     3array ; inline
 273
 274 : compressed-texture-data-size ( tdt level -- size )
 275     [ [ bind-tdt drop ] [ texture-data-gl-target ] bi ] dip
 276     GL_TEXTURE_COMPRESSED_IMAGE_SIZE get-texture-int ; inline
 277
 278 : texture-data-size ( tdt level -- size )
 279     [ texture-dim ?product ] [ drop texture-object bytes-per-pixel ] 2bi * ; inline
 280
 281 TYPED:: read-texture-to ( tdt: texture-data-target level: integer gpu-data-ptr -- )
 282     tdt bind-tdt :> texture
 283     tdt texture-data-gl-target level
 284     texture [ component-order>> ] [ component-type>> ] bi image-data-format
 285     gpu-data-ptr pixel-pack-buffer [ glGetTexImage ] with-gpu-data-ptr ;
 286
 287 TYPED: read-texture ( tdt: texture-data-target level: integer -- byte-array: byte-array )
 288     2dup texture-data-size (byte-array)
 289     [ read-texture-to ] keep ;
 290
 291 TYPED:: read-compressed-texture-to ( tdt: texture-data-target level: integer gpu-data-ptr -- )
 292     tdt bind-tdt :> texture
 293     tdt texture-data-gl-target level
 294     gpu-data-ptr pixel-pack-buffer [ glGetCompressedTexImage ] with-gpu-data-ptr ;
 295
 296 TYPED: read-compressed-texture ( tdt: texture-data-target level: integer -- byte-array: byte-array )
 297     2dup compressed-texture-data-size (byte-array)
 298     [ read-compressed-texture-to ] keep ;
 299
 300 : allocate-texture-image ( tdt level image -- )
 301     image>texture-data allocate-texture ; inline
 302
 303 : update-texture-image ( tdt level loc image -- )
 304     image>texture-data update-texture ; inline
 305
 306 : read-texture-image ( tdt level -- image )
 307     [ texture-dim ]
 308     [ drop texture-object [ component-order>> ] [ component-type>> ] bi f f ]
 309     [ read-texture ] 2tri
 310     f image boa ; inline
 311
 312 <PRIVATE
 313 : bind-texture ( texture -- gl-target )
 314     [ texture-gl-target dup ] [ handle>> ] bi glBindTexture ; inline
 315 PRIVATE>
 316
 317 : generate-mipmaps ( texture -- )
 318     bind-texture glGenerateMipmap ; inline
 319
 320 TYPED: set-texture-parameters ( texture: texture parameters: texture-parameters -- )
 321     [ bind-texture ] dip {
 322         [ wrap>> set-texture-gl-wrap ]
 323         [
 324             [ GL_TEXTURE_MIN_FILTER ] dip
 325             [ min-filter>> ] [ min-mipmap-filter>> ] bi gl-min-filter glTexParameteri
 326         ] [
 327             [ GL_TEXTURE_MAG_FILTER ] dip
 328             mag-filter>> gl-mag-filter glTexParameteri
 329         ]
 330         [ [ GL_TEXTURE_MIN_LOD ] dip min-lod>> glTexParameteri ]
 331         [ [ GL_TEXTURE_MAX_LOD ] dip max-lod>> glTexParameteri ]
 332         [ [ GL_TEXTURE_LOD_BIAS ] dip lod-bias>> glTexParameteri ]
 333         [ [ GL_TEXTURE_BASE_LEVEL ] dip base-level>> glTexParameteri ]
 334         [ [ GL_TEXTURE_MAX_LEVEL ] dip max-level>> glTexParameteri ]
 335     } 2cleave ;
 336
 337 <PRIVATE
 338
 339 : <texture> ( component-order component-type parameters class -- texture )
 340     '[ [ gen-texture ] 2dip _ boa dup window-resource ] dip
 341     [ T{ texture-parameters } clone ] unless* set-texture-parameters ; inline
 342
 343 PRIVATE>
 344
 345 : <texture-1d> ( component-order component-type parameters -- texture )
 346     texture-1d <texture> ; inline
 347 : <texture-2d> ( component-order component-type parameters -- texture )
 348     texture-2d <texture> ; inline
 349 : <texture-3d> ( component-order component-type parameters -- texture )
 350     texture-3d <texture> ; inline
 351 : <texture-cube-map> ( component-order component-type parameters -- texture )
 352     texture-cube-map <texture> ; inline
 353 : <texture-rectangle> ( component-order component-type parameters -- texture )
 354     texture-rectangle <texture> ; inline
 355 : <texture-1d-array> ( component-order component-type parameters -- texture )
 356     texture-1d-array <texture> ; inline
 357 : <texture-2d-array> ( component-order component-type parameters -- texture )
 358     texture-2d-array <texture> ; inline