extra/gpu/textures/textures.factor

   1 ! (c)2009 Joe Groff bsd license
   2 USING: accessors alien.c-types arrays byte-arrays combinators
   3 destructors fry gpu gpu.buffers images kernel locals math
   4 opengl opengl.gl opengl.textures sequences
   5 specialized-arrays typed ui.gadgets.worlds variants ;
   6 FROM: alien.c-types => float ;
   7 SPECIALIZED-ARRAY: float
   8 IN: gpu.textures
   9
  10 TUPLE: texture < gpu-object
  11     { component-order component-order read-only initial: RGBA }
  12     { component-type component-type read-only initial: ubyte-components } ;
  13
  14 TUPLE: texture-1d < texture ;
  15 TUPLE: texture-2d < texture ;
  16 TUPLE: texture-rectangle < texture ;
  17 TUPLE: texture-3d < texture ;
  18 TUPLE: texture-cube-map < texture ;
  19
  20 TUPLE: texture-1d-array < texture ;
  21 TUPLE: texture-2d-array < texture ;
  22
  23 VARIANT: cube-map-axis
  24     -X -Y -Z +X +Y +Z ;
  25
  26 TUPLE: cube-map-face
  27     { texture texture-cube-map read-only }
  28     { axis cube-map-axis read-only } ;
  29 C: <cube-map-face> cube-map-face
  30
  31 UNION: texture-1d-data-target
  32     texture-1d ;
  33 UNION: texture-2d-data-target
  34     texture-2d texture-rectangle texture-1d-array cube-map-face ;
  35 UNION: texture-3d-data-target
  36     texture-3d texture-2d-array ;
  37 UNION: texture-data-target
  38     texture-1d-data-target texture-2d-data-target texture-3d-data-target ;
  39
  40 M: texture dispose
  41     [ [ delete-texture ] when* f ] change-handle drop ;
  42
  43 TUPLE: texture-data
  44     { ptr read-only }
  45     { component-order component-order read-only initial: RGBA }
  46     { component-type component-type read-only initial: ubyte-components } ;
  47
  48 C: <texture-data> texture-data
  49 UNION: ?texture-data texture-data POSTPONE: f ;
  50 UNION: ?float-array float-array POSTPONE: f ;
  51
  52 VARIANT: compressed-texture-format
  53     DXT1-RGB DXT1-RGBA DXT3 DXT5
  54     LATC1 LATC1-SIGNED LATC2 LATC2-SIGNED
  55     RGTC1 RGTC1-SIGNED RGTC2 RGTC2-SIGNED ;
  56
  57 TUPLE: compressed-texture-data
  58     { ptr read-only }
  59     { format compressed-texture-format read-only }
  60     { length integer read-only } ;
  61
  62 C: <compressed-texture-data> compressed-texture-data
  63 UNION: ?compressed-texture-data compressed-texture-data POSTPONE: f ;
  64
  65 VARIANT: texture-wrap
  66     clamp-texcoord-to-edge clamp-texcoord-to-border repeat-texcoord repeat-texcoord-mirrored ;
  67 VARIANT: texture-filter
  68     filter-nearest filter-linear ;
  69
  70 UNION: wrap-set texture-wrap sequence ;
  71 UNION: ?texture-filter texture-filter POSTPONE: f ;
  72
  73 TUPLE: texture-parameters
  74     { wrap wrap-set initial: { repeat-texcoord repeat-texcoord repeat-texcoord } }
  75     { min-filter texture-filter initial: filter-nearest }
  76     { min-mipmap-filter ?texture-filter initial: filter-linear }
  77     { mag-filter texture-filter initial: filter-linear }
  78     { min-lod integer initial: -1000 }
  79     { max-lod integer initial:  1000 }
  80     { lod-bias integer initial: 0 }
  81     { base-level integer initial: 0 }
  82     { max-level integer initial: 1000 } ;
  83
  84 <PRIVATE
  85
  86 GENERIC: texture-object ( texture-data-target -- texture )
  87 M: cube-map-face texture-object
  88     texture>> ; inline
  89 M: texture texture-object
  90     ; inline
  91
  92 : gl-compressed-texture-format ( format -- gl-format )
  93     {
  94         { DXT1-RGB     [ GL_COMPRESSED_RGB_S3TC_DXT1_EXT  ] }
  95         { DXT1-RGBA    [ GL_COMPRESSED_RGBA_S3TC_DXT1_EXT ] }
  96         { DXT3         [ GL_COMPRESSED_RGBA_S3TC_DXT3_EXT ] }
  97         { DXT5         [ GL_COMPRESSED_RGBA_S3TC_DXT5_EXT ] }
  98         { RGTC1        [ GL_COMPRESSED_RED_RGTC1          ] }
  99         { RGTC1-SIGNED [ GL_COMPRESSED_SIGNED_RED_RGTC1   ] }
 100         { RGTC2        [ GL_COMPRESSED_RG_RGTC2           ] }
 101         { RGTC2-SIGNED [ GL_COMPRESSED_SIGNED_RG_RGTC2    ] }
 102     } case ; inline
 103
 104 : gl-wrap ( wrap -- gl-wrap )
 105     {
 106         { clamp-texcoord-to-edge [ GL_CLAMP_TO_EDGE ] }
 107         { clamp-texcoord-to-border [ GL_CLAMP_TO_BORDER ] }
 108         { repeat-texcoord [ GL_REPEAT ] }
 109         { repeat-texcoord-mirrored [ GL_MIRRORED_REPEAT ] }
 110     } case ; inline
 111
 112 : set-texture-gl-wrap ( target wraps -- )
 113     dup sequence? [ 1array ] unless 3 over last pad-tail {
 114         [ [ GL_TEXTURE_WRAP_S ] dip first  gl-wrap glTexParameteri ]
 115         [ [ GL_TEXTURE_WRAP_T ] dip second gl-wrap glTexParameteri ]
 116         [ [ GL_TEXTURE_WRAP_R ] dip third  gl-wrap glTexParameteri ]
 117     } 2cleave ; inline
 118
 119 : gl-mag-filter ( filter -- gl-filter )
 120     {
 121         { filter-nearest [ GL_NEAREST ] }
 122         { filter-linear [ GL_LINEAR ] }
 123     } case ; inline
 124
 125 : gl-min-filter ( filter mipmap-filter -- gl-filter )
 126     2array {
 127         { { filter-nearest f              } [ GL_NEAREST                ] }
 128         { { filter-linear  f              } [ GL_LINEAR                 ] }
 129         { { filter-nearest filter-nearest } [ GL_NEAREST_MIPMAP_NEAREST ] }
 130         { { filter-linear  filter-nearest } [ GL_LINEAR_MIPMAP_NEAREST  ] }
 131         { { filter-linear  filter-linear  } [ GL_LINEAR_MIPMAP_LINEAR   ] }
 132         { { filter-nearest filter-linear  } [ GL_NEAREST_MIPMAP_LINEAR  ] }
 133     } case ; inline
 134
 135 GENERIC: texture-gl-target ( texture -- target )
 136 GENERIC: texture-data-gl-target ( texture -- target )
 137
 138 M: texture-1d        texture-gl-target drop GL_TEXTURE_1D ; inline
 139 M: texture-2d        texture-gl-target drop GL_TEXTURE_2D ; inline
 140 M: texture-rectangle texture-gl-target drop GL_TEXTURE_RECTANGLE ; inline
 141 M: texture-3d        texture-gl-target drop GL_TEXTURE_3D ; inline
 142 M: texture-cube-map  texture-gl-target drop GL_TEXTURE_CUBE_MAP ; inline
 143 M: texture-1d-array  texture-gl-target drop GL_TEXTURE_1D_ARRAY ; inline
 144 M: texture-2d-array  texture-gl-target drop GL_TEXTURE_2D_ARRAY ; inline
 145
 146 M: texture-1d        texture-data-gl-target drop GL_TEXTURE_1D ; inline
 147 M: texture-2d        texture-data-gl-target drop GL_TEXTURE_2D ; inline
 148 M: texture-rectangle texture-data-gl-target drop GL_TEXTURE_RECTANGLE ; inline
 149 M: texture-3d        texture-data-gl-target drop GL_TEXTURE_3D ; inline
 150 M: texture-1d-array  texture-data-gl-target drop GL_TEXTURE_1D_ARRAY ; inline
 151 M: texture-2d-array  texture-data-gl-target drop GL_TEXTURE_2D_ARRAY ; inline
 152 M: cube-map-face     texture-data-gl-target
 153     axis>> {
 154         { -X [ GL_TEXTURE_CUBE_MAP_NEGATIVE_X ] }
 155         { -Y [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Y ] }
 156         { -Z [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Z ] }
 157         { +X [ GL_TEXTURE_CUBE_MAP_POSITIVE_X ] }
 158         { +Y [ GL_TEXTURE_CUBE_MAP_POSITIVE_Y ] }
 159         { +Z [ GL_TEXTURE_CUBE_MAP_POSITIVE_Z ] }
 160     } case ; inline
 161
 162 : texture-gl-internal-format ( texture -- internal-format )
 163     [ component-order>> ] [ component-type>> ] bi image-internal-format ; inline
 164
 165 : texture-data-gl-args ( texture data -- format type ptr )
 166     [
 167         nip
 168         [ [ component-order>> ] [ component-type>> ] bi image-data-format ]
 169         [ ptr>> ] bi
 170     ] [
 171         [ component-order>> ] [ component-type>> ] bi image-data-format f
 172     ] if* ; inline
 173
 174 :: bind-tdt ( tdt -- texture )
 175     tdt texture-object :> texture
 176     texture [ texture-gl-target ] [ handle>> ] bi glBindTexture
 177     texture ; inline
 178
 179 : ?product ( x -- y )
 180     dup number? [ product ] unless ; inline
 181
 182 :: (allocate-texture) ( tdt level dim data dim-quot teximage-quot -- )
 183     tdt bind-tdt :> texture
 184     tdt texture-data-gl-target level texture texture-gl-internal-format
 185     dim dim-quot call 0 texture data texture-data-gl-args
 186     pixel-unpack-buffer teximage-quot with-gpu-data-ptr ; inline
 187
 188 :: (allocate-compressed-texture) ( tdt level dim compressed-data dim-quot teximage-quot -- )
 189     tdt bind-tdt :> texture
 190     tdt texture-data-gl-target level compressed-data format>> gl-compressed-texture-format
 191     dim dim-quot call 0 compressed-data [ length>> ] [ ptr>> ] bi
 192     pixel-unpack-buffer teximage-quot with-gpu-data-ptr ; inline
 193
 194 :: (update-texture) ( tdt level loc dim data dim-quot texsubimage-quot -- )
 195     tdt bind-tdt :> texture
 196     tdt texture-data-gl-target level
 197     loc dim dim-quot bi@
 198     texture data texture-data-gl-args
 199     pixel-unpack-buffer texsubimage-quot with-gpu-data-ptr ; inline
 200
 201 :: (update-compressed-texture) ( tdt level loc dim compressed-data dim-quot texsubimage-quot -- )
 202     tdt bind-tdt :> texture
 203     tdt texture-data-gl-target level
 204     loc dim dim-quot bi@
 205     compressed-data [ format>> gl-compressed-texture-format ] [ length>> ] [ ptr>> ] tri
 206     pixel-unpack-buffer texsubimage-quot with-gpu-data-ptr ; inline
 207
 208 PRIVATE>
 209
 210 GENERIC# allocate-texture 3 ( tdt level dim data -- )
 211
 212 M: texture-1d-data-target allocate-texture ( tdt level dim data -- )
 213     [ ] [ glTexImage1D ] (allocate-texture) ;
 214
 215 M: texture-2d-data-target allocate-texture ( tdt level dim data -- )
 216     [ first2 ] [ glTexImage2D ] (allocate-texture) ;
 217
 218 M: texture-3d-data-target allocate-texture ( tdt level dim data -- )
 219     [ first3 ] [ glTexImage3D ] (allocate-texture) ;
 220
 221 GENERIC# allocate-compressed-texture 3 ( tdt level dim compressed-data -- )
 222
 223 M: texture-1d-data-target allocate-compressed-texture ( tdt level dim compressed-data -- )
 224     [ ] [ glCompressedTexImage1D ] (allocate-compressed-texture) ;
 225
 226 M: texture-2d-data-target allocate-compressed-texture ( tdt level dim compressed-data -- )
 227     [ first2 ] [ glCompressedTexImage2D ] (allocate-compressed-texture) ;
 228
 229 M: texture-3d-data-target allocate-compressed-texture ( tdt level dim compressed-data -- )
 230     [ first3 ] [ glCompressedTexImage3D ] (allocate-compressed-texture) ;
 231
 232 GENERIC# update-texture 4 ( tdt level loc dim data -- )
 233
 234 M: texture-1d-data-target update-texture ( tdt level loc dim data -- )
 235     [ ] [ glTexSubImage1D ] (update-texture) ;
 236
 237 M: texture-2d-data-target update-texture ( tdt level loc dim data -- )
 238     [ first2 ] [ glTexSubImage2D ] (update-texture) ;
 239
 240 M: texture-3d-data-target update-texture ( tdt level loc dim data -- )
 241     [ first3 ] [ glTexSubImage3D ] (update-texture) ;
 242
 243 GENERIC# update-compressed-texture 4 ( tdt level loc dim compressed-data -- )
 244
 245 M: texture-1d-data-target update-compressed-texture ( tdt level loc dim compressed-data -- )
 246     [ ] [ glCompressedTexSubImage1D ] (update-compressed-texture) ;
 247
 248 M: texture-2d-data-target update-compressed-texture ( tdt level loc dim compressed-data -- )
 249     [ first2 ] [ glCompressedTexSubImage2D ] (update-compressed-texture) ;
 250
 251 M: texture-3d-data-target update-compressed-texture ( tdt level loc dim compressed-data -- )
 252     [ first3 ] [ glCompressedTexSubImage3D ] (update-compressed-texture) ;
 253
 254 : image>texture-data ( image -- dim texture-data )
 255     { [ dim>> ] [ bitmap>> ] [ component-order>> ] [ component-type>> ] } cleave
 256     <texture-data> ; inline
 257
 258 GENERIC# texture-dim 1 ( tdt level -- dim )
 259
 260 M:: texture-1d-data-target texture-dim ( tdt level -- dim )
 261     tdt bind-tdt :> texture
 262     tdt texture-data-gl-target level GL_TEXTURE_WIDTH get-texture-int ; inline
 263
 264 M:: texture-2d-data-target texture-dim ( tdt level -- dim )
 265     tdt bind-tdt :> texture
 266     tdt texture-data-gl-target level
 267     [ GL_TEXTURE_WIDTH get-texture-int ] [ GL_TEXTURE_HEIGHT get-texture-int ] 2bi
 268     2array ; inline
 269
 270 M:: texture-3d-data-target texture-dim ( tdt level -- dim )
 271     tdt bind-tdt :> texture
 272     tdt texture-data-gl-target level
 273     [ GL_TEXTURE_WIDTH get-texture-int ]
 274     [ GL_TEXTURE_HEIGHT get-texture-int ]
 275     [ GL_TEXTURE_DEPTH get-texture-int ] 2tri
 276     3array ; inline
 277
 278 : compressed-texture-data-size ( tdt level -- size )
 279     [ [ bind-tdt drop ] [ texture-data-gl-target ] bi ] dip
 280     GL_TEXTURE_COMPRESSED_IMAGE_SIZE get-texture-int ; inline
 281
 282 : texture-data-size ( tdt level -- size )
 283     [ texture-dim ?product ] [ drop texture-object bytes-per-pixel ] 2bi * ; inline
 284
 285 TYPED:: read-texture-to ( tdt: texture-data-target level: integer gpu-data-ptr -- )
 286     tdt bind-tdt :> texture
 287     tdt texture-data-gl-target level
 288     texture [ component-order>> ] [ component-type>> ] bi image-data-format
 289     gpu-data-ptr pixel-pack-buffer [ glGetTexImage ] with-gpu-data-ptr ;
 290
 291 TYPED: read-texture ( tdt: texture-data-target level: integer -- byte-array: byte-array )
 292     2dup texture-data-size (byte-array)
 293     [ read-texture-to ] keep ;
 294
 295 TYPED:: read-compressed-texture-to ( tdt: texture-data-target level: integer gpu-data-ptr -- )
 296     tdt bind-tdt :> texture
 297     tdt texture-data-gl-target level
 298     gpu-data-ptr pixel-pack-buffer [ glGetCompressedTexImage ] with-gpu-data-ptr ;
 299
 300 TYPED: read-compressed-texture ( tdt: texture-data-target level: integer -- byte-array: byte-array )
 301     2dup compressed-texture-data-size (byte-array)
 302     [ read-compressed-texture-to ] keep ;
 303
 304 : allocate-texture-image ( tdt level image -- )
 305     image>texture-data allocate-texture ; inline
 306
 307 : update-texture-image ( tdt level loc image -- )
 308     image>texture-data update-texture ; inline
 309
 310 : read-texture-image ( tdt level -- image )
 311     [ texture-dim ]
 312     [ drop texture-object [ component-order>> ] [ component-type>> ] bi f f ]
 313     [ read-texture ] 2tri
 314     image boa ; inline
 315
 316 <PRIVATE
 317 : bind-texture ( texture -- gl-target )
 318     [ texture-gl-target dup ] [ handle>> ] bi glBindTexture ; inline
 319 PRIVATE>
 320
 321 : generate-mipmaps ( texture -- )
 322     bind-texture glGenerateMipmap ; inline
 323
 324 TYPED: set-texture-parameters ( texture: texture parameters: texture-parameters -- )
 325     [ bind-texture ] dip {
 326         [ wrap>> set-texture-gl-wrap ]
 327         [
 328             [ GL_TEXTURE_MIN_FILTER ] dip
 329             [ min-filter>> ] [ min-mipmap-filter>> ] bi gl-min-filter glTexParameteri
 330         ] [
 331             [ GL_TEXTURE_MAG_FILTER ] dip
 332             mag-filter>> gl-mag-filter glTexParameteri
 333         ]
 334         [ [ GL_TEXTURE_MIN_LOD ] dip min-lod>> glTexParameteri ]
 335         [ [ GL_TEXTURE_MAX_LOD ] dip max-lod>> glTexParameteri ]
 336         [ [ GL_TEXTURE_LOD_BIAS ] dip lod-bias>> glTexParameteri ]
 337         [ [ GL_TEXTURE_BASE_LEVEL ] dip base-level>> glTexParameteri ]
 338         [ [ GL_TEXTURE_MAX_LEVEL ] dip max-level>> glTexParameteri ]
 339     } 2cleave ;
 340
 341 <PRIVATE
 342
 343 : <texture> ( component-order component-type parameters class -- texture )
 344     '[ [ gen-texture ] 2dip _ boa dup window-resource ] dip
 345     [ T{ texture-parameters } clone ] unless* set-texture-parameters ; inline
 346
 347 PRIVATE>
 348
 349 : <texture-1d> ( component-order component-type parameters -- texture )
 350     texture-1d <texture> ; inline
 351 : <texture-2d> ( component-order component-type parameters -- texture )
 352     texture-2d <texture> ; inline
 353 : <texture-3d> ( component-order component-type parameters -- texture )
 354     texture-3d <texture> ; inline
 355 : <texture-cube-map> ( component-order component-type parameters -- texture )
 356     texture-cube-map <texture> ; inline
 357 : <texture-rectangle> ( component-order component-type parameters -- texture )
 358     texture-rectangle <texture> ; inline
 359 : <texture-1d-array> ( component-order component-type parameters -- texture )
 360     texture-1d-array <texture> ; inline
 361 : <texture-2d-array> ( component-order component-type parameters -- texture )
 362     texture-2d-array <texture> ; inline
 363