extra/irc/client/internals/internals-tests.factor

   1 ! Copyright (C) 2009 Bruno Deferrari
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel tools.test accessors arrays sequences
   4 io io.streams.duplex namespaces threads destructors
   5 calendar concurrency.mailboxes classes assocs combinators
   6 irc.messages.parser irc.client.base irc.client.chats
   7 irc.client.participants irc.client.internals ;
   8 EXCLUDE: irc.messages => join ;
   9 RENAME: join irc.messages => join_
  10 IN: irc.client.internals.tests
  11
  12 ! Streams for testing
  13 TUPLE: mb-writer lines last-line disposed ;
  14 TUPLE: mb-reader lines disposed ;
  15 : <mb-writer> ( -- mb-writer ) V{ } clone V{ } clone f mb-writer boa ;
  16 : <mb-reader> ( -- mb-reader ) <mailbox> f mb-reader boa ;
  17 : push-line ( line test-reader-stream -- ) lines>> mailbox-put ;
  18 : <test-stream> ( -- stream ) <mb-reader> <mb-writer> <duplex-stream> ;
  19 M: mb-writer stream-write ( line mb-writer -- ) last-line>> push ;
  20 M: mb-writer stream-flush ( mb-writer -- ) drop ;
  21 M: mb-reader stream-readln ( mb-reader -- str/f ) lines>> mailbox-get ;
  22 M: mb-writer stream-nl ( mb-writer -- )
  23     [ [ last-line>> concat ] [ lines>> ] bi push ] keep
  24     V{ } clone >>last-line drop ;
  25 M: mb-reader dispose f swap push-line ;
  26 M: mb-writer dispose drop ;
  27
  28 : spawn-client ( -- irc-client )
  29     "someserver" irc-port "factorbot" f <irc-profile>
  30     <irc-client>
  31         t >>is-ready
  32         t >>is-running
  33         <test-stream> >>stream
  34     dup [ spawn-irc yield ] with-irc ;
  35
  36 ! to be used inside with-irc quotations
  37 : %add-named-chat ( chat -- ) (attach-chat) ;
  38 : %push-line ( line -- ) irc> stream>> in>> push-line yield ;
  39 : %push-lines ( lines -- ) [ %push-line ] each ;
  40 : %join ( channel -- ) <irc-channel-chat> (attach-chat) ;
  41 : %pop-output-line ( -- string ) irc> stream>> out>> lines>> pop ;
  42
  43 : read-matching-message ( chat quot: ( msg -- ? ) -- irc-message )
  44     [ in-messages>> 0.1 seconds ] dip mailbox-get-timeout? ; inline
  45
  46 : spawning-irc ( quot: ( -- ) -- )
  47     [ spawn-client ] dip [ (terminate-irc) ] compose with-irc ; inline
  48
  49 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  50 !                       TESTS
  51 ! !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
  52
  53 [ { t } [ irc> nick>> me? ] unit-test
  54
  55   { "factorbot" } [ irc> nick>> ] unit-test
  56
  57   { "#factortest" } [ ":someuser!n=user@some.where PRIVMSG #factortest :hi"
  58                       string>irc-message chat-name ] unit-test
  59
  60   { "someuser" } [ ":someuser!n=user@some.where PRIVMSG factorbot :hi"
  61                    string>irc-message chat-name ] unit-test
  62 ] spawning-irc
  63
  64 { privmsg "#channel" "hello" } [
  65     "#channel" "hello" strings>privmsg
  66     [ class ] [ target>> ] [ trailing>> ] tri
  67 ] unit-test
  68
  69 ! Test login and nickname set
  70 [ { "factorbot2" } [
  71     ":some.where 001 factorbot2 :Welcome factorbot2" %push-line
  72     irc> nick>>
  73   ] unit-test
  74 ] spawning-irc
  75
  76 ! Test connect
  77 { V{ "NICK factorbot" "USER factorbot hostname servername :irc.factor" } } [
  78     "someserver" irc-port "factorbot" f <irc-profile> <irc-client>
  79     [ 2drop <test-stream> ] >>connect
  80     [
  81         (connect-irc)
  82         (do-login)
  83         irc> stream>> out>> lines>>
  84         (terminate-irc)
  85     ] with-irc
  86 ] unit-test
  87
  88 ! Test join
  89 [ { "JOIN #factortest" } [
  90       "#factortest" %join %pop-output-line
  91   ] unit-test
  92 ] spawning-irc
  93
  94 [ { join_ "#factortest"} [
  95       "#factortest" <irc-channel-chat> [ %add-named-chat ] keep
  96       { ":factorbot!n=factorbo@some.where JOIN :#factortest"
  97         ":ircserver.net 353 factorbot @ #factortest :@factorbot "
  98         ":ircserver.net 366 factorbot #factortest :End of /NAMES list."
  99         ":ircserver.net 477 factorbot #factortest :[ircserver-info] blah blah"
 100       } %push-lines
 101       [ join? ] read-matching-message
 102       [ class ] [ channel>> ] bi
 103   ] unit-test
 104 ] spawning-irc
 105
 106 [ { privmsg "#factortest" "hello" } [
 107       "#factortest" <irc-channel-chat> [ %add-named-chat ] keep
 108       ":somebody!n=somebody@some.where PRIVMSG #factortest :hello" %push-line
 109       [ privmsg? ] read-matching-message
 110       [ class ] [ target>> ] [ trailing>> ] tri
 111   ] unit-test
 112 ] spawning-irc
 113
 114 [ { privmsg "factorbot" "hello" } [
 115       "ircuser" <irc-nick-chat>  [ %add-named-chat ] keep
 116       ":ircuser!n=user@isp.net PRIVMSG factorbot :hello" %push-line
 117       [ privmsg? ] read-matching-message
 118       [ class ] [ target>> ] [ trailing>> ] tri
 119   ] unit-test
 120 ] spawning-irc
 121
 122 [ { mode "#factortest" "+ns" } [
 123       "#factortest" <irc-channel-chat>  [ %add-named-chat ] keep
 124       ":ircserver.net MODE #factortest +ns" %push-line
 125       [ mode? ] read-matching-message
 126       [ class ] [ name>> ] [ mode>> ] tri
 127   ] unit-test
 128 ] spawning-irc
 129
 130 ! Participant lists tests
 131 [ { { "ircuser" } } [
 132       "#factortest" <irc-channel-chat> [ %add-named-chat ] keep
 133       ":ircuser!n=user@isp.net JOIN :#factortest" %push-line
 134       participants>> keys
 135   ] unit-test
 136 ] spawning-irc
 137
 138 [ { { "ircuser2" } } [
 139       "#factortest" <irc-channel-chat>
 140       { "ircuser2" "ircuser" } [ over join-participant ] each
 141       [ %add-named-chat ] keep
 142       ":ircuser!n=user@isp.net PART #factortest" %push-line
 143       participants>> keys
 144   ] unit-test
 145 ] spawning-irc
 146
 147 [ { { "ircuser2" } } [
 148       "#factortest" <irc-channel-chat>
 149       { "ircuser2" "ircuser" } [ over join-participant ] each
 150       [ %add-named-chat ] keep
 151       ":ircuser!n=user@isp.net QUIT" %push-line
 152       participants>> keys
 153   ] unit-test
 154 ] spawning-irc
 155
 156 [ { { "ircuser2" } } [
 157       "#factortest" <irc-channel-chat>
 158       { "ircuser2" "ircuser" } [ over join-participant ] each
 159       [ %add-named-chat ] keep
 160       ":ircuser2!n=user2@isp.net KICK #factortest ircuser" %push-line
 161       participants>> keys
 162   ] unit-test
 163 ] spawning-irc
 164
 165 [ { H{ { "ircuser2" T{ participant { nick "ircuser2" } } } } } [
 166       "#factortest" <irc-channel-chat>
 167       "ircuser" over join-participant
 168       [ %add-named-chat ] keep
 169       ":ircuser!n=user2@isp.net NICK :ircuser2" %push-line
 170       participants>>
 171   ] unit-test
 172 ] spawning-irc
 173
 174 [ { H{ { "factorbot" T{ participant { nick "factorbot" } { operator t } } }
 175        { "ircuser" T{ participant { nick "ircuser" } } }
 176        { "voiced" T{ participant { nick "voiced" } { voice t } } } } } [
 177       "#factortest" <irc-channel-chat>
 178       "ircuser" over join-participant
 179       [ %add-named-chat ] keep
 180       { ":ircserver.net 353 factorbot @ #factortest :@factorbot "
 181         ":ircserver.net 353 factorbot @ #factortest :ircuser2 "
 182         ":ircserver.net 366 factorbot #factortest :End of /NAMES list."
 183         ":ircserver.net 353 factorbot @ #factortest :@factorbot +voiced "
 184         ":ircserver.net 353 factorbot @ #factortest :ircuser "
 185         ":ircserver.net 366 factorbot #factortest :End of /NAMES list."
 186       } %push-lines
 187       participants>>
 188   ] unit-test
 189 ] spawning-irc
 190
 191 [ { mode "#factortest" "+o" "ircuser" } [
 192       "#factortest" <irc-channel-chat> [ %add-named-chat ] keep
 193       "ircuser" over join-participant
 194       ":ircserver.net MODE #factortest +o ircuser" %push-line
 195       [ mode? ] read-matching-message
 196       { [ class ] [ name>> ] [ mode>> ] [ parameter>> ] } cleave
 197   ] unit-test
 198 ] spawning-irc
 199
 200 [ { T{ participant { nick "ircuser" } { operator t } } } [
 201       "#factortest" <irc-channel-chat> [ %add-named-chat ] keep
 202       "ircuser" over join-participant
 203       ":ircserver.net MODE #factortest +o ircuser" %push-line
 204       participants>> "ircuser" swap at
 205   ] unit-test
 206 ] spawning-irc
 207
 208 ! Send privmsg
 209 [ { "PRIVMSG #factortest :hello" } [
 210       "#factortest" <irc-channel-chat> [ %add-named-chat ] keep
 211       "hello" swap (speak) %pop-output-line
 212   ] unit-test
 213 ] spawning-irc