extra/irc/messages/parser/parser.factor

   1 ! Copyright (C) 2009 Bruno Deferrari
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel fry splitting ascii accessors combinators
   4        arrays classes.tuple math.order words assocs
   5        irc.messages.base sequences ;
   6 IN: irc.messages.parser
   7
   8 <PRIVATE
   9 : split-at-first ( seq separators -- before after )
  10     dupd '[ _ member? ] find [ cut rest ] [ swap ] if ;
  11
  12 : split-trailing ( string -- string string/f ) ":" split1 ;
  13 : remove-heading-: ( seq -- seq ) ":" ?head drop ;
  14
  15 : split-prefix ( string -- string/f string )
  16     dup ":" head? [
  17         remove-heading-: " " split1
  18     ] [ f swap ] if ;
  19
  20 : split-message ( string -- prefix command parameters trailing )
  21     split-prefix split-trailing
  22     [ [ blank? ] trim " " split unclip swap ] dip ;
  23
  24 : sender ( irc-message -- sender )
  25     prefix>> [ remove-heading-: "!" split-at-first drop ] [ f ] if* ;
  26 PRIVATE>
  27
  28 : string>irc-message ( string -- irc-message )
  29     dup split-message
  30     [ [ irc>type new ] [ >>command ] bi ]
  31     [ >>parameters ]
  32     [ >>trailing ]
  33     tri*
  34     [ prefix<< ] [ fill-irc-message-slots ] [ swap >>line ] tri
  35     dup sender >>sender ;