extra/jamshred/player/player.factor

   1 ! Copyright (C) 2007, 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors colors.constants combinators jamshred.log
   4 jamshred.oint jamshred.sound jamshred.tunnel kernel locals math
   5 math.constants math.order math.ranges math.vectors math.matrices
   6 sequences shuffle specialized-arrays strings system ;
   7 SPECIALIZED-ARRAY: float
   8 IN: jamshred.player
   9
  10 TUPLE: player < oint
  11     { name string }
  12     { sounds sounds }
  13     tunnel
  14     nearest-segment
  15     { last-move integer }
  16     { speed float } ;
  17
  18 ! speeds are in GL units / second
  19 CONSTANT: default-speed 1.0
  20 CONSTANT: max-speed 30.0
  21
  22 : <player> ( name sounds -- player )
  23     [ float-array{ 0 0 5 } float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 } ] 2dip
  24     f f 0 default-speed player boa ;
  25
  26 : turn-player ( player x-radians y-radians -- )
  27     [ over ] dip left-pivot up-pivot ;
  28
  29 : roll-player ( player z-radians -- )
  30     forward-pivot ;
  31
  32 : to-tunnel-start ( player -- )
  33     [ tunnel>> first dup location>> ]
  34     [ tuck (>>location) (>>nearest-segment) ] bi ;
  35
  36 : play-in-tunnel ( player segments -- )
  37     >>tunnel to-tunnel-start ;
  38
  39 : update-nearest-segment ( player -- )
  40     [ tunnel>> ] [ dup nearest-segment>> nearest-segment ]
  41     [ (>>nearest-segment) ] tri ;
  42
  43 : update-time ( player -- seconds-passed )
  44     millis swap [ last-move>> - 1000 / ] [ (>>last-move) ] 2bi ;
  45
  46 : moved ( player -- ) millis swap (>>last-move) ;
  47
  48 : speed-range ( -- range )
  49     max-speed [0,b] ;
  50
  51 : change-player-speed ( inc player -- )
  52     [ + 0 max-speed clamp ] change-speed drop ;
  53
  54 : multiply-player-speed ( n player -- )
  55     [ * 0 max-speed clamp ] change-speed drop ;
  56
  57 : distance-to-move ( seconds-passed player -- distance )
  58     speed>> * ;
  59
  60 : bounce ( d-left player -- d-left' player )
  61     {
  62         [ dup nearest-segment>> bounce-off-wall ]
  63         [ sounds>> bang ]
  64         [ 3/4 swap multiply-player-speed ]
  65         [ ]
  66     } cleave ;
  67
  68 :: (distance) ( heading player -- current next location heading )
  69     player nearest-segment>>
  70     player [ tunnel>> ] [ nearest-segment>> ] bi heading heading-segment
  71     player location>> heading ;
  72
  73 : distance-to-heading-segment ( heading player -- distance )
  74     (distance) distance-to-next-segment ;
  75
  76 : distance-to-heading-segment-area ( heading player -- distance )
  77     (distance) distance-to-next-segment-area ;
  78
  79 : distance-to-collision ( player -- distance )
  80     dup nearest-segment>> (distance-to-collision) ;
  81
  82 : almost-to-collision ( player -- distance )
  83     distance-to-collision 0.1 - dup 0 < [ drop 0 ] when ;
  84
  85 : from ( player -- radius distance-from-centre )
  86     [ nearest-segment>> dup radius>> swap ] [ location>> ] bi
  87     distance-from-centre ;
  88
  89 : distance-from-wall ( player -- distance ) from - ;
  90 : fraction-from-centre ( player -- fraction ) from swap / ;
  91 : fraction-from-wall ( player -- fraction )
  92     fraction-from-centre 1 swap - ;
  93
  94 : update-nearest-segment2 ( heading player -- )
  95     2dup distance-to-heading-segment-area 0 <= [
  96         [ tunnel>> ] [ nearest-segment>> rot heading-segment ]
  97         [ (>>nearest-segment) ] tri
  98     ] [
  99         2drop
 100     ] if ;
 101
 102 :: move-player-on-heading ( d-left player distance heading -- d-left' player )
 103     [let* | d-to-move [ d-left distance min ]
 104             move-v [ d-to-move heading n*v ] |
 105         move-v player location+
 106         heading player update-nearest-segment2
 107         d-left d-to-move - player ] ;
 108
 109 : distance-to-move-freely ( player -- distance )
 110     [ almost-to-collision ]
 111     [ [ forward>> ] keep distance-to-heading-segment-area ] bi min ;
 112
 113 : ?move-player-freely ( d-left player -- d-left' player )
 114     over 0 > [
 115         ! must make sure we are moving a significant distance, otherwise
 116         ! we can recurse endlessly due to floating-point imprecision.
 117         ! (at least I /think/ that's what causes it...)
 118         dup distance-to-move-freely dup 0.1 > [
 119             over forward>> move-player-on-heading ?move-player-freely
 120         ] [ drop ] if
 121     ] when ;
 122
 123 : drag-heading ( player -- heading )
 124     [ forward>> ] [ nearest-segment>> forward>> proj ] bi ;
 125
 126 : drag-player ( d-left player -- d-left' player )
 127     dup [ [ drag-heading ] keep distance-to-heading-segment-area ]
 128     [ drag-heading move-player-on-heading ] bi ;
 129
 130 : (move-player) ( d-left player -- d-left' player )
 131     ?move-player-freely over 0 > [
 132         ! bounce
 133         drag-player
 134         (move-player)
 135     ] when ;
 136
 137 : move-player ( player -- )
 138     [ update-time ] [ distance-to-move ] [ (move-player) 2drop ] tri ;
 139
 140 : update-player ( player -- )
 141     [ move-player ] [ nearest-segment>> "white" named-color swap (>>color) ] bi ;