extra/jamshred/tunnel/tunnel.factor

   1 ! Copyright (C) 2007, 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays colors combinators fry jamshred.oint
   4 kernel literals locals math math.constants math.matrices
   5 math.order math.quadratic math.ranges math.vectors random
   6 sequences specialized-arrays vectors ;
   7 FROM: jamshred.oint => distance ;
   8 SPECIALIZED-ARRAY: float
   9 IN: jamshred.tunnel
  10
  11 CONSTANT: n-segments 5000
  12
  13 TUPLE: segment < oint number color radius ;
  14 C: <segment> segment
  15
  16 : segment-number++ ( segment -- )
  17     [ number>> 1 + ] keep (>>number) ;
  18
  19 : clamp-length ( n seq -- n' )
  20     0 swap length clamp ;
  21
  22 : random-color ( -- color )
  23     { 100 100 100 } [ random 100 / >float ] map first3 1.0 <rgba> ;
  24
  25 CONSTANT: tunnel-segment-distance 0.4
  26 CONSTANT: random-rotation-angle $[ pi 20 / ]
  27
  28 : random-segment ( previous-segment -- segment )
  29     clone dup random-rotation-angle random-turn
  30     tunnel-segment-distance over go-forward
  31     random-color >>color dup segment-number++ ;
  32
  33 : (random-segments) ( segments n -- segments )
  34     dup 0 > [
  35         [ dup last random-segment over push ] dip 1 - (random-segments)
  36     ] [ drop ] if ;
  37
  38 CONSTANT: default-segment-radius 1
  39
  40 : initial-segment ( -- segment )
  41     float-array{ 0 0 0 } float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 }
  42     0 random-color default-segment-radius <segment> ;
  43
  44 : random-segments ( n -- segments )
  45     initial-segment 1vector swap (random-segments) ;
  46
  47 : simple-segment ( n -- segment )
  48     [ float-array{ 0 0 -1 } n*v float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 } ] keep
  49     random-color default-segment-radius <segment> ;
  50
  51 : simple-segments ( n -- segments )
  52     [ simple-segment ] map ;
  53
  54 : <random-tunnel> ( -- segments )
  55     n-segments random-segments ;
  56
  57 : <straight-tunnel> ( -- segments )
  58     n-segments simple-segments ;
  59
  60 : sub-tunnel ( from to segments -- segments )
  61     #! return segments between from and to, after clamping from and to to
  62     #! valid values
  63     [ '[ _ clamp-length ] bi@ ] keep <slice> ;
  64
  65 : nearer-segment ( segment segment oint -- segment )
  66     #! return whichever of the two segments is nearer to the oint
  67     [ 2dup ] dip tuck distance [ distance ] dip < -rot ? ;
  68
  69 : (find-nearest-segment) ( nearest next oint -- nearest ? )
  70     #! find the nearest of 'next' and 'nearest' to 'oint', and return
  71     #! t if the nearest hasn't changed
  72     pick [ nearer-segment dup ] dip = ;
  73
  74 : find-nearest-segment ( oint segments -- segment )
  75     dup first swap rest-slice rot [ (find-nearest-segment) ] curry
  76     find 2drop ;
  77
  78 : nearest-segment-forward ( segments oint start -- segment )
  79     rot dup length swap <slice> find-nearest-segment ;
  80
  81 : nearest-segment-backward ( segments oint start -- segment )
  82     swapd 1 + 0 spin <slice> <reversed> find-nearest-segment ;
  83
  84 : nearest-segment ( segments oint start-segment -- segment )
  85     #! find the segment nearest to 'oint', and return it.
  86     #! start looking at segment 'start-segment'
  87     number>> over [
  88         [ nearest-segment-forward ] 3keep nearest-segment-backward
  89     ] dip nearer-segment ;
  90
  91 : get-segment ( segments n -- segment )
  92     over clamp-length swap nth ;
  93
  94 : next-segment ( segments current-segment -- segment )
  95     number>> 1 + get-segment ;
  96
  97 : previous-segment ( segments current-segment -- segment )
  98     number>> 1 - get-segment ;
  99
 100 : heading-segment ( segments current-segment heading -- segment )
 101     #! the next segment on the given heading
 102     over forward>> v. 0 <=> {
 103         { +gt+ [ next-segment ] }
 104         { +lt+ [ previous-segment ] }
 105         { +eq+ [ nip ] } ! current segment
 106     } case ;
 107
 108 :: distance-to-next-segment ( current next location heading -- distance )
 109     [let | cf [ current forward>> ] |
 110         cf next location>> v. cf location v. - cf heading v. / ] ;
 111
 112 :: distance-to-next-segment-area ( current next location heading -- distance )
 113     [let | cf [ current forward>> ]
 114            h [ next current half-way-between-oints ] |
 115         cf h v. cf location v. - cf heading v. / ] ;
 116
 117 : vector-to-centre ( seg loc -- v )
 118     over location>> swap v- swap forward>> proj-perp ;
 119
 120 : distance-from-centre ( seg loc -- distance )
 121     vector-to-centre norm ;
 122
 123 : wall-normal ( seg oint -- n )
 124     location>> vector-to-centre normalize ;
 125
 126 CONSTANT: distant 1000
 127
 128 : max-real ( a b -- c )
 129     #! sometimes collision-coefficient yields complex roots, so we ignore these (hack)
 130     dup real? [
 131         over real? [ max ] [ nip ] if
 132     ] [
 133         drop dup real? [ drop distant ] unless
 134     ] if ;
 135
 136 :: collision-coefficient ( v w r -- c )
 137     v norm 0 = [
 138         distant
 139     ] [
 140         [let* | a [ v dup v. ]
 141                 b [ v w v. 2 * ]
 142                 c [ w dup v. r sq - ] |
 143             c b a quadratic max-real ]
 144     ] if ;
 145
 146 : sideways-heading ( oint segment -- v )
 147     [ forward>> ] bi@ proj-perp ;
 148
 149 : sideways-relative-location ( oint segment -- loc )
 150     [ [ location>> ] bi@ v- ] keep forward>> proj-perp ;
 151
 152 : (distance-to-collision) ( oint segment -- distance )
 153     [ sideways-heading ] [ sideways-relative-location ]
 154     [ nip radius>> ] 2tri collision-coefficient ;
 155
 156 : collision-vector ( oint segment -- v )
 157     dupd (distance-to-collision) swap forward>> n*v ;
 158
 159 : bounce-forward ( segment oint -- )
 160     [ wall-normal ] [ forward>> swap reflect ] [ (>>forward) ] tri ;
 161
 162 : bounce-left ( segment oint -- )
 163     #! must be done after forward
 164     [ forward>> vneg ] dip [ left>> swap reflect ]
 165     [ forward>> proj-perp normalize ] [ (>>left) ] tri ;
 166
 167 : bounce-up ( segment oint -- )
 168     #! must be done after forward and left!
 169     nip [ forward>> ] [ left>> cross ] [ (>>up) ] tri ;
 170
 171 : bounce-off-wall ( oint segment -- )
 172     swap [ bounce-forward ] [ bounce-left ] [ bounce-up ] 2tri ;
 173