extra/jamshred/tunnel/tunnel.factor

   1 ! Copyright (C) 2007, 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays colors combinators kernel literals locals math math.constants math.matrices math.order math.ranges math.vectors math.quadratic random sequences specialized-arrays.float vectors jamshred.oint ;
   4 FROM: jamshred.oint => distance ;
   5 IN: jamshred.tunnel
   6
   7 CONSTANT: n-segments 5000
   8
   9 TUPLE: segment < oint number color radius ;
  10 C: <segment> segment
  11
  12 : segment-number++ ( segment -- )
  13     [ number>> 1+ ] keep (>>number) ;
  14
  15 : random-color ( -- color )
  16     { 100 100 100 } [ random 100 / >float ] map first3 1.0 <rgba> ;
  17
  18 CONSTANT: tunnel-segment-distance 0.4
  19 CONSTANT: random-rotation-angle $[ pi 20 / ]
  20
  21 : random-segment ( previous-segment -- segment )
  22     clone dup random-rotation-angle random-turn
  23     tunnel-segment-distance over go-forward
  24     random-color >>color dup segment-number++ ;
  25
  26 : (random-segments) ( segments n -- segments )
  27     dup 0 > [
  28         [ dup peek random-segment over push ] dip 1- (random-segments)
  29     ] [ drop ] if ;
  30
  31 CONSTANT: default-segment-radius 1
  32
  33 : initial-segment ( -- segment )
  34     float-array{ 0 0 0 } float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 }
  35     0 random-color default-segment-radius <segment> ;
  36
  37 : random-segments ( n -- segments )
  38     initial-segment 1vector swap (random-segments) ;
  39
  40 : simple-segment ( n -- segment )
  41     [ float-array{ 0 0 -1 } n*v float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 } ] keep
  42     random-color default-segment-radius <segment> ;
  43
  44 : simple-segments ( n -- segments )
  45     [ simple-segment ] map ;
  46
  47 : <random-tunnel> ( -- segments )
  48     n-segments random-segments ;
  49
  50 : <straight-tunnel> ( -- segments )
  51     n-segments simple-segments ;
  52
  53 : sub-tunnel ( from to segments -- segments )
  54     #! return segments between from and to, after clamping from and to to
  55     #! valid values
  56     [ sequence-index-range [ clamp-to-range ] curry bi@ ] keep <slice> ;
  57
  58 : nearer-segment ( segment segment oint -- segment )
  59     #! return whichever of the two segments is nearer to the oint
  60     [ 2dup ] dip tuck distance [ distance ] dip < -rot ? ;
  61
  62 : (find-nearest-segment) ( nearest next oint -- nearest ? )
  63     #! find the nearest of 'next' and 'nearest' to 'oint', and return
  64     #! t if the nearest hasn't changed
  65     pick [ nearer-segment dup ] dip = ;
  66
  67 : find-nearest-segment ( oint segments -- segment )
  68     dup first swap rest-slice rot [ (find-nearest-segment) ] curry
  69     find 2drop ;
  70
  71 : nearest-segment-forward ( segments oint start -- segment )
  72     rot dup length swap <slice> find-nearest-segment ;
  73
  74 : nearest-segment-backward ( segments oint start -- segment )
  75     swapd 1+ 0 spin <slice> <reversed> find-nearest-segment ;
  76
  77 : nearest-segment ( segments oint start-segment -- segment )
  78     #! find the segment nearest to 'oint', and return it.
  79     #! start looking at segment 'start-segment'
  80     number>> over [
  81         [ nearest-segment-forward ] 3keep nearest-segment-backward
  82     ] dip nearer-segment ;
  83
  84 : get-segment ( segments n -- segment )
  85     over sequence-index-range clamp-to-range swap nth ;
  86
  87 : next-segment ( segments current-segment -- segment )
  88     number>> 1+ get-segment ;
  89
  90 : previous-segment ( segments current-segment -- segment )
  91     number>> 1- get-segment ;
  92
  93 : heading-segment ( segments current-segment heading -- segment )
  94     #! the next segment on the given heading
  95     over forward>> v. 0 <=> {
  96         { +gt+ [ next-segment ] }
  97         { +lt+ [ previous-segment ] }
  98         { +eq+ [ nip ] } ! current segment
  99     } case ;
 100
 101 :: distance-to-next-segment ( current next location heading -- distance )
 102     [let | cf [ current forward>> ] |
 103         cf next location>> v. cf location v. - cf heading v. / ] ;
 104
 105 :: distance-to-next-segment-area ( current next location heading -- distance )
 106     [let | cf [ current forward>> ]
 107            h [ next current half-way-between-oints ] |
 108         cf h v. cf location v. - cf heading v. / ] ;
 109
 110 : vector-to-centre ( seg loc -- v )
 111     over location>> swap v- swap forward>> proj-perp ;
 112
 113 : distance-from-centre ( seg loc -- distance )
 114     vector-to-centre norm ;
 115
 116 : wall-normal ( seg oint -- n )
 117     location>> vector-to-centre normalize ;
 118
 119 CONSTANT: distant 1000
 120
 121 : max-real ( a b -- c )
 122     #! sometimes collision-coefficient yields complex roots, so we ignore these (hack)
 123     dup real? [
 124         over real? [ max ] [ nip ] if
 125     ] [
 126         drop dup real? [ drop distant ] unless
 127     ] if ;
 128
 129 :: collision-coefficient ( v w r -- c )
 130     v norm 0 = [
 131         distant
 132     ] [
 133         [let* | a [ v dup v. ]
 134                 b [ v w v. 2 * ]
 135                 c [ w dup v. r sq - ] |
 136             c b a quadratic max-real ]
 137     ] if ;
 138
 139 : sideways-heading ( oint segment -- v )
 140     [ forward>> ] bi@ proj-perp ;
 141
 142 : sideways-relative-location ( oint segment -- loc )
 143     [ [ location>> ] bi@ v- ] keep forward>> proj-perp ;
 144
 145 : (distance-to-collision) ( oint segment -- distance )
 146     [ sideways-heading ] [ sideways-relative-location ]
 147     [ nip radius>> ] 2tri collision-coefficient ;
 148
 149 : collision-vector ( oint segment -- v )
 150     dupd (distance-to-collision) swap forward>> n*v ;
 151
 152 : bounce-forward ( segment oint -- )
 153     [ wall-normal ] [ forward>> swap reflect ] [ (>>forward) ] tri ;
 154
 155 : bounce-left ( segment oint -- )
 156     #! must be done after forward
 157     [ forward>> vneg ] dip [ left>> swap reflect ]
 158     [ forward>> proj-perp normalize ] [ (>>left) ] tri ;
 159
 160 : bounce-up ( segment oint -- )
 161     #! must be done after forward and left!
 162     nip [ forward>> ] [ left>> cross ] [ (>>up) ] tri ;
 163
 164 : bounce-off-wall ( oint segment -- )
 165     swap [ bounce-forward ] [ bounce-left ] [ bounce-up ] 2tri ;
 166