extra/jamshred/tunnel/tunnel.factor

   1 ! Copyright (C) 2007, 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays colors combinators fry jamshred.oint
   4 kernel literals locals math math.constants math.matrices
   5 math.order math.quadratic math.ranges math.vectors random
   6 sequences specialized-arrays vectors ;
   7 FROM: jamshred.oint => distance ;
   8 FROM: alien.c-types => float ;
   9 SPECIALIZED-ARRAY: float
  10 IN: jamshred.tunnel
  11
  12 CONSTANT: n-segments 5000
  13
  14 TUPLE: segment < oint number color radius ;
  15 C: <segment> segment
  16
  17 : segment-number++ ( segment -- )
  18     [ number>> 1 + ] keep (>>number) ;
  19
  20 : clamp-length ( n seq -- n' )
  21     0 swap length clamp ;
  22
  23 : random-color ( -- color )
  24     { 100 100 100 } [ random 100 / >float ] map first3 1.0 <rgba> ;
  25
  26 CONSTANT: tunnel-segment-distance 0.4
  27 CONSTANT: random-rotation-angle $[ pi 20 / ]
  28
  29 : random-segment ( previous-segment -- segment )
  30     clone dup random-rotation-angle random-turn
  31     tunnel-segment-distance over go-forward
  32     random-color >>color dup segment-number++ ;
  33
  34 : (random-segments) ( segments n -- segments )
  35     dup 0 > [
  36         [ dup last random-segment over push ] dip 1 - (random-segments)
  37     ] [ drop ] if ;
  38
  39 CONSTANT: default-segment-radius 1
  40
  41 : initial-segment ( -- segment )
  42     float-array{ 0 0 0 } float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 }
  43     0 random-color default-segment-radius <segment> ;
  44
  45 : random-segments ( n -- segments )
  46     initial-segment 1vector swap (random-segments) ;
  47
  48 : simple-segment ( n -- segment )
  49     [ float-array{ 0 0 -1 } n*v float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 } ] keep
  50     random-color default-segment-radius <segment> ;
  51
  52 : simple-segments ( n -- segments )
  53     [ simple-segment ] map ;
  54
  55 : <random-tunnel> ( -- segments )
  56     n-segments random-segments ;
  57
  58 : <straight-tunnel> ( -- segments )
  59     n-segments simple-segments ;
  60
  61 : sub-tunnel ( from to segments -- segments )
  62     #! return segments between from and to, after clamping from and to to
  63     #! valid values
  64     [ '[ _ clamp-length ] bi@ ] keep <slice> ;
  65
  66 : get-segment ( segments n -- segment )
  67     over clamp-length swap nth ;
  68
  69 : next-segment ( segments current-segment -- segment )
  70     number>> 1 + get-segment ;
  71
  72 : previous-segment ( segments current-segment -- segment )
  73     number>> 1 - get-segment ;
  74
  75 : heading-segment ( segments current-segment heading -- segment )
  76     #! the next segment on the given heading
  77     over forward>> v. 0 <=> {
  78         { +gt+ [ next-segment ] }
  79         { +lt+ [ previous-segment ] }
  80         { +eq+ [ nip ] } ! current segment
  81     } case ;
  82
  83 :: distance-to-next-segment ( current next location heading -- distance )
  84     current forward>> :> cf
  85     cf next location>> v. cf location v. - cf heading v. / ;
  86
  87 :: distance-to-next-segment-area ( current next location heading -- distance )
  88     current forward>> :> cf
  89     next current half-way-between-oints :> h
  90     cf h v. cf location v. - cf heading v. / ;
  91
  92 : vector-to-centre ( seg loc -- v )
  93     over location>> swap v- swap forward>> proj-perp ;
  94
  95 : distance-from-centre ( seg loc -- distance )
  96     vector-to-centre norm ;
  97
  98 : wall-normal ( seg oint -- n )
  99     location>> vector-to-centre normalize ;
 100
 101 CONSTANT: distant 1000
 102
 103 : max-real ( a b -- c )
 104     #! sometimes collision-coefficient yields complex roots, so we ignore these (hack)
 105     dup real? [
 106         over real? [ max ] [ nip ] if
 107     ] [
 108         drop dup real? [ drop distant ] unless
 109     ] if ;
 110
 111 :: collision-coefficient ( v w r -- c )
 112     v norm 0 = [
 113         distant
 114     ] [
 115         v dup v. :> a
 116         v w v. 2 * :> b
 117         w dup v. r sq - :> c
 118         c b a quadratic max-real
 119     ] if ;
 120
 121 : sideways-heading ( oint segment -- v )
 122     [ forward>> ] bi@ proj-perp ;
 123
 124 : sideways-relative-location ( oint segment -- loc )
 125     [ [ location>> ] bi@ v- ] keep forward>> proj-perp ;
 126
 127 : (distance-to-collision) ( oint segment -- distance )
 128     [ sideways-heading ] [ sideways-relative-location ]
 129     [ nip radius>> ] 2tri collision-coefficient ;
 130
 131 : collision-vector ( oint segment -- v )
 132     dupd (distance-to-collision) swap forward>> n*v ;
 133
 134 : bounce-forward ( segment oint -- )
 135     [ wall-normal ] [ forward>> swap reflect ] [ (>>forward) ] tri ;
 136
 137 : bounce-left ( segment oint -- )
 138     #! must be done after forward
 139     [ forward>> vneg ] dip [ left>> swap reflect ]
 140     [ forward>> proj-perp normalize ] [ (>>left) ] tri ;
 141
 142 : bounce-up ( segment oint -- )
 143     #! must be done after forward and left!
 144     nip [ forward>> ] [ left>> cross ] [ (>>up) ] tri ;
 145
 146 : bounce-off-wall ( oint segment -- )
 147     swap [ bounce-forward ] [ bounce-left ] [ bounce-up ] 2tri ;
 148