extra/jamshred/tunnel/tunnel.factor

   1 ! Copyright (C) 2007, 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays colors combinators fry jamshred.oint
   4 kernel literals locals math math.constants math.matrices
   5 math.order math.quadratic math.ranges math.vectors random
   6 sequences specialized-arrays vectors ;
   7 FROM: jamshred.oint => distance ;
   8 FROM: alien.c-types => float ;
   9 SPECIALIZED-ARRAY: float
  10 IN: jamshred.tunnel
  11
  12 CONSTANT: n-segments 5000
  13
  14 TUPLE: segment < oint number color radius ;
  15 C: <segment> segment
  16
  17 : segment-number++ ( segment -- )
  18     [ number>> 1 + ] keep (>>number) ;
  19
  20 : clamp-length ( n seq -- n' )
  21     0 swap length clamp ;
  22
  23 : random-color ( -- color )
  24     { 100 100 100 } [ random 100 / >float ] map first3 1.0 <rgba> ;
  25
  26 CONSTANT: tunnel-segment-distance 0.4
  27 CONSTANT: random-rotation-angle $[ pi 20 / ]
  28
  29 : random-segment ( previous-segment -- segment )
  30     clone dup random-rotation-angle random-turn
  31     tunnel-segment-distance over go-forward
  32     random-color >>color dup segment-number++ ;
  33
  34 : (random-segments) ( segments n -- segments )
  35     dup 0 > [
  36         [ dup last random-segment over push ] dip 1 - (random-segments)
  37     ] [ drop ] if ;
  38
  39 CONSTANT: default-segment-radius 1
  40
  41 : initial-segment ( -- segment )
  42     float-array{ 0 0 0 } float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 }
  43     0 random-color default-segment-radius <segment> ;
  44
  45 : random-segments ( n -- segments )
  46     initial-segment 1vector swap (random-segments) ;
  47
  48 : simple-segment ( n -- segment )
  49     [ float-array{ 0 0 -1 } n*v float-array{ 0 0 -1 } float-array{ 0 1 0 } float-array{ -1 0 0 } ] keep
  50     random-color default-segment-radius <segment> ;
  51
  52 : simple-segments ( n -- segments )
  53     [ simple-segment ] map ;
  54
  55 : <random-tunnel> ( -- segments )
  56     n-segments random-segments ;
  57
  58 : <straight-tunnel> ( -- segments )
  59     n-segments simple-segments ;
  60
  61 : sub-tunnel ( from to segments -- segments )
  62     #! return segments between from and to, after clamping from and to to
  63     #! valid values
  64     [ '[ _ clamp-length ] bi@ ] keep <slice> ;
  65
  66 : nearer-segment ( segment segment oint -- segment )
  67     #! return whichever of the two segments is nearer to the oint
  68     [ 2dup ] dip tuck distance [ distance ] dip < -rot ? ;
  69
  70 : (find-nearest-segment) ( nearest next oint -- nearest ? )
  71     #! find the nearest of 'next' and 'nearest' to 'oint', and return
  72     #! t if the nearest hasn't changed
  73     pick [ nearer-segment dup ] dip = ;
  74
  75 : find-nearest-segment ( oint segments -- segment )
  76     dup first swap rest-slice rot [ (find-nearest-segment) ] curry
  77     find 2drop ;
  78
  79 : nearest-segment-forward ( segments oint start -- segment )
  80     rot dup length swap <slice> find-nearest-segment ;
  81
  82 : nearest-segment-backward ( segments oint start -- segment )
  83     swapd 1 + 0 spin <slice> <reversed> find-nearest-segment ;
  84
  85 : nearest-segment ( segments oint start-segment -- segment )
  86     #! find the segment nearest to 'oint', and return it.
  87     #! start looking at segment 'start-segment'
  88     number>> over [
  89         [ nearest-segment-forward ] 3keep nearest-segment-backward
  90     ] dip nearer-segment ;
  91
  92 : get-segment ( segments n -- segment )
  93     over clamp-length swap nth ;
  94
  95 : next-segment ( segments current-segment -- segment )
  96     number>> 1 + get-segment ;
  97
  98 : previous-segment ( segments current-segment -- segment )
  99     number>> 1 - get-segment ;
 100
 101 : heading-segment ( segments current-segment heading -- segment )
 102     #! the next segment on the given heading
 103     over forward>> v. 0 <=> {
 104         { +gt+ [ next-segment ] }
 105         { +lt+ [ previous-segment ] }
 106         { +eq+ [ nip ] } ! current segment
 107     } case ;
 108
 109 :: distance-to-next-segment ( current next location heading -- distance )
 110     current forward>> :> cf
 111     cf next location>> v. cf location v. - cf heading v. / ;
 112
 113 :: distance-to-next-segment-area ( current next location heading -- distance )
 114     current forward>> :> cf
 115     next current half-way-between-oints :> h
 116     cf h v. cf location v. - cf heading v. / ;
 117
 118 : vector-to-centre ( seg loc -- v )
 119     over location>> swap v- swap forward>> proj-perp ;
 120
 121 : distance-from-centre ( seg loc -- distance )
 122     vector-to-centre norm ;
 123
 124 : wall-normal ( seg oint -- n )
 125     location>> vector-to-centre normalize ;
 126
 127 CONSTANT: distant 1000
 128
 129 : max-real ( a b -- c )
 130     #! sometimes collision-coefficient yields complex roots, so we ignore these (hack)
 131     dup real? [
 132         over real? [ max ] [ nip ] if
 133     ] [
 134         drop dup real? [ drop distant ] unless
 135     ] if ;
 136
 137 :: collision-coefficient ( v w r -- c )
 138     v norm 0 = [
 139         distant
 140     ] [
 141         v dup v. :> a
 142         v w v. 2 * :> b
 143         w dup v. r sq - :> c
 144         c b a quadratic max-real
 145     ] if ;
 146
 147 : sideways-heading ( oint segment -- v )
 148     [ forward>> ] bi@ proj-perp ;
 149
 150 : sideways-relative-location ( oint segment -- loc )
 151     [ [ location>> ] bi@ v- ] keep forward>> proj-perp ;
 152
 153 : (distance-to-collision) ( oint segment -- distance )
 154     [ sideways-heading ] [ sideways-relative-location ]
 155     [ nip radius>> ] 2tri collision-coefficient ;
 156
 157 : collision-vector ( oint segment -- v )
 158     dupd (distance-to-collision) swap forward>> n*v ;
 159
 160 : bounce-forward ( segment oint -- )
 161     [ wall-normal ] [ forward>> swap reflect ] [ (>>forward) ] tri ;
 162
 163 : bounce-left ( segment oint -- )
 164     #! must be done after forward
 165     [ forward>> vneg ] dip [ left>> swap reflect ]
 166     [ forward>> proj-perp normalize ] [ (>>left) ] tri ;
 167
 168 : bounce-up ( segment oint -- )
 169     #! must be done after forward and left!
 170     nip [ forward>> ] [ left>> cross ] [ (>>up) ] tri ;
 171
 172 : bounce-off-wall ( oint segment -- )
 173     swap [ bounce-forward ] [ bounce-left ] [ bounce-up ] 2tri ;
 174