extra/macho/macho.factor

   1 ! Copyright (C) 2010 Erik Charlebois.
   2 ! See http:// factorcode.org/license.txt for BSD license.
   3 USING: accessors alien alien.c-types alien.data alien.strings
   4 alien.syntax classes classes.struct combinators
   5 combinators.short-circuit io.encodings.ascii io.encodings.string
   6 kernel literals make math sequences specialized-arrays typed
   7 io.mmap formatting splitting endian ;
   8 IN: macho
   9
  10 ! FFI data
  11 TYPEDEF: int       integer_t
  12 TYPEDEF: int       vm_prot_t
  13 TYPEDEF: integer_t cpu_type_t
  14 TYPEDEF: integer_t cpu_subtype_t
  15 TYPEDEF: integer_t cpu_threadtype_t
  16
  17 CONSTANT: VM_PROT_NONE        0x00
  18 CONSTANT: VM_PROT_READ        0x01
  19 CONSTANT: VM_PROT_WRITE       0x02
  20 CONSTANT: VM_PROT_EXECUTE     0x04
  21 CONSTANT: VM_PROT_DEFAULT     0x03
  22 CONSTANT: VM_PROT_ALL         0x07
  23 CONSTANT: VM_PROT_NO_CHANGE   0x08
  24 CONSTANT: VM_PROT_COPY        0x10
  25 CONSTANT: VM_PROT_WANTS_COPY  0x10
  26
  27 ! loader.h
  28 STRUCT: mach_header
  29     { magic         uint          }
  30     { cputype       cpu_type_t    }
  31     { cpusubtype    cpu_subtype_t }
  32     { filetype      uint          }
  33     { ncmds         uint          }
  34     { sizeofcmds    uint          }
  35     { flags         uint          } ;
  36
  37 CONSTANT: MH_MAGIC    0xfeedface
  38 CONSTANT: MH_CIGAM    0xcefaedfe
  39
  40 STRUCT: mach_header_64
  41     { magic         uint          }
  42     { cputype       cpu_type_t    }
  43     { cpusubtype    cpu_subtype_t }
  44     { filetype      uint          }
  45     { ncmds         uint          }
  46     { sizeofcmds    uint          }
  47     { flags         uint          }
  48     { reserved      uint          } ;
  49
  50 CONSTANT: MH_MAGIC_64 0xfeedfacf
  51 CONSTANT: MH_CIGAM_64 0xcffaedfe
  52
  53 CONSTANT: MH_OBJECT       0x1
  54 CONSTANT: MH_EXECUTE      0x2
  55 CONSTANT: MH_FVMLIB       0x3
  56 CONSTANT: MH_CORE         0x4
  57 CONSTANT: MH_PRELOAD      0x5
  58 CONSTANT: MH_DYLIB        0x6
  59 CONSTANT: MH_DYLINKER     0x7
  60 CONSTANT: MH_BUNDLE       0x8
  61 CONSTANT: MH_DYLIB_STUB   0x9
  62 CONSTANT: MH_DSYM         0xa
  63 CONSTANT: MH_KEXT_BUNDLE  0xb
  64
  65 CONSTANT: MH_NOUNDEFS                0x1
  66 CONSTANT: MH_INCRLINK                0x2
  67 CONSTANT: MH_DYLDLINK                0x4
  68 CONSTANT: MH_BINDATLOAD              0x8
  69 CONSTANT: MH_PREBOUND                0x10
  70 CONSTANT: MH_SPLIT_SEGS              0x20
  71 CONSTANT: MH_LAZY_INIT               0x40
  72 CONSTANT: MH_TWOLEVEL                0x80
  73 CONSTANT: MH_FORCE_FLAT              0x100
  74 CONSTANT: MH_NOMULTIDEFS             0x200
  75 CONSTANT: MH_NOFIXPREBINDING         0x400
  76 CONSTANT: MH_PREBINDABLE             0x800
  77 CONSTANT: MH_ALLMODSBOUND            0x1000
  78 CONSTANT: MH_SUBSECTIONS_VIA_SYMBOLS 0x2000
  79 CONSTANT: MH_CANONICAL               0x4000
  80 CONSTANT: MH_WEAK_DEFINES            0x8000
  81 CONSTANT: MH_BINDS_TO_WEAK           0x10000
  82 CONSTANT: MH_ALLOW_STACK_EXECUTION   0x20000
  83 CONSTANT: MH_DEAD_STRIPPABLE_DYLIB   0x400000
  84 CONSTANT: MH_ROOT_SAFE               0x40000
  85 CONSTANT: MH_SETUID_SAFE             0x80000
  86 CONSTANT: MH_NO_REEXPORTED_DYLIBS    0x100000
  87 CONSTANT: MH_PIE                     0x200000
  88
  89 STRUCT: load_command
  90     { cmd     uint }
  91     { cmdsize uint } ;
  92
  93 CONSTANT: LC_REQ_DYLD 0x80000000
  94
  95 CONSTANT: LC_SEGMENT            0x1
  96 CONSTANT: LC_SYMTAB             0x2
  97 CONSTANT: LC_SYMSEG             0x3
  98 CONSTANT: LC_THREAD             0x4
  99 CONSTANT: LC_UNIXTHREAD         0x5
 100 CONSTANT: LC_LOADFVMLIB         0x6
 101 CONSTANT: LC_IDFVMLIB           0x7
 102 CONSTANT: LC_IDENT              0x8
 103 CONSTANT: LC_FVMFILE            0x9
 104 CONSTANT: LC_PREPAGE            0xa
 105 CONSTANT: LC_DYSYMTAB           0xb
 106 CONSTANT: LC_LOAD_DYLIB         0xc
 107 CONSTANT: LC_ID_DYLIB           0xd
 108 CONSTANT: LC_LOAD_DYLINKER      0xe
 109 CONSTANT: LC_ID_DYLINKER        0xf
 110 CONSTANT: LC_PREBOUND_DYLIB     0x10
 111 CONSTANT: LC_ROUTINES           0x11
 112 CONSTANT: LC_SUB_FRAMEWORK      0x12
 113 CONSTANT: LC_SUB_UMBRELLA       0x13
 114 CONSTANT: LC_SUB_CLIENT         0x14
 115 CONSTANT: LC_SUB_LIBRARY        0x15
 116 CONSTANT: LC_TWOLEVEL_HINTS     0x16
 117 CONSTANT: LC_PREBIND_CKSUM      0x17
 118 CONSTANT: LC_LOAD_WEAK_DYLIB    0x80000018
 119 CONSTANT: LC_SEGMENT_64         0x19
 120 CONSTANT: LC_ROUTINES_64        0x1a
 121 CONSTANT: LC_UUID               0x1b
 122 CONSTANT: LC_RPATH              0x8000001c
 123 CONSTANT: LC_CODE_SIGNATURE     0x1d
 124 CONSTANT: LC_SEGMENT_SPLIT_INFO 0x1e
 125 CONSTANT: LC_REEXPORT_DYLIB     0x8000001f
 126 CONSTANT: LC_LAZY_LOAD_DYLIB    0x20
 127 CONSTANT: LC_ENCRYPTION_INFO    0x21
 128 CONSTANT: LC_DYLD_INFO          0x22
 129 CONSTANT: LC_DYLD_INFO_ONLY     0x80000022
 130 CONSTANT: LC_LOAD_UPWARD_DYLIB 0x80000023
 131 CONSTANT: LC_VERSION_MIN_MACOSX 0x24
 132 CONSTANT: LC_VERSION_MIN_IPHONEOS 0x25
 133 CONSTANT: LC_FUNCTION_STARTS 0x26
 134 CONSTANT: LC_DYLD_ENVIRONMENT 0x27
 135 CONSTANT: LC_MAIN 0x80000028
 136 CONSTANT: LC_DATA_IN_CODE 0x29
 137 CONSTANT: LC_SOURCE_VERSION 0x2A
 138 CONSTANT: LC_DYLIB_CODE_SIGN_DRS 0x2B
 139
 140 UNION-STRUCT: lc_str
 141     { offset    uint     }
 142     { ptr       char*    } ;
 143
 144 STRUCT: segment_command
 145     { cmd            uint      }
 146     { cmdsize        uint      }
 147     { segname        char[16]  }
 148     { vmaddr         uint      }
 149     { vmsize         uint      }
 150     { fileoff        uint      }
 151     { filesize       uint      }
 152     { maxprot        vm_prot_t }
 153     { initprot       vm_prot_t }
 154     { nsects         uint      }
 155     { flags          uint      } ;
 156
 157 STRUCT: segment_command_64
 158     { cmd            uint       }
 159     { cmdsize        uint       }
 160     { segname        char[16]   }
 161     { vmaddr         ulonglong  }
 162     { vmsize         ulonglong  }
 163     { fileoff        ulonglong  }
 164     { filesize       ulonglong  }
 165     { maxprot        vm_prot_t  }
 166     { initprot       vm_prot_t  }
 167     { nsects         uint       }
 168     { flags          uint       } ;
 169
 170 CONSTANT: SG_HIGHVM               0x1
 171 CONSTANT: SG_FVMLIB               0x2
 172 CONSTANT: SG_NORELOC              0x4
 173 CONSTANT: SG_PROTECTED_VERSION_1  0x8
 174
 175 STRUCT: section
 176     { sectname        char[16] }
 177     { segname         char[16] }
 178     { addr            uint     }
 179     { size            uint     }
 180     { offset          uint     }
 181     { align           uint     }
 182     { reloff          uint     }
 183     { nreloc          uint     }
 184     { flags           uint     }
 185     { reserved1       uint     }
 186     { reserved2       uint     } ;
 187
 188 STRUCT: section_64
 189     { sectname        char[16]  }
 190     { segname         char[16]  }
 191     { addr            ulonglong }
 192     { size            ulonglong }
 193     { offset          uint      }
 194     { align           uint      }
 195     { reloff          uint      }
 196     { nreloc          uint      }
 197     { flags           uint      }
 198     { reserved1       uint      }
 199     { reserved2       uint      }
 200     { reserved3       uint      } ;
 201
 202 CONSTANT: SECTION_TYPE         0x000000ff
 203 CONSTANT: SECTION_ATTRIBUTES   0xffffff00
 204
 205 CONSTANT: S_REGULAR                       0x0
 206 CONSTANT: S_ZEROFILL                      0x1
 207 CONSTANT: S_CSTRING_LITERALS              0x2
 208 CONSTANT: S_4BYTE_LITERALS                0x3
 209 CONSTANT: S_8BYTE_LITERALS                0x4
 210 CONSTANT: S_LITERAL_POINTERS              0x5
 211 CONSTANT: S_NON_LAZY_SYMBOL_POINTERS      0x6
 212 CONSTANT: S_LAZY_SYMBOL_POINTERS          0x7
 213 CONSTANT: S_SYMBOL_STUBS                  0x8
 214 CONSTANT: S_MOD_INIT_FUNC_POINTERS        0x9
 215 CONSTANT: S_MOD_TERM_FUNC_POINTERS        0xa
 216 CONSTANT: S_COALESCED                     0xb
 217 CONSTANT: S_GB_ZEROFILL                   0xc
 218 CONSTANT: S_INTERPOSING                   0xd
 219 CONSTANT: S_16BYTE_LITERALS               0xe
 220 CONSTANT: S_DTRACE_DOF                    0xf
 221 CONSTANT: S_LAZY_DYLIB_SYMBOL_POINTERS    0x10
 222
 223 CONSTANT: SECTION_ATTRIBUTES_USR     0xff000000
 224 CONSTANT: S_ATTR_PURE_INSTRUCTIONS   0x80000000
 225 CONSTANT: S_ATTR_NO_TOC              0x40000000
 226 CONSTANT: S_ATTR_STRIP_STATIC_SYMS   0x20000000
 227 CONSTANT: S_ATTR_NO_DEAD_STRIP       0x10000000
 228 CONSTANT: S_ATTR_LIVE_SUPPORT        0x08000000
 229 CONSTANT: S_ATTR_SELF_MODIFYING_CODE 0x04000000
 230 CONSTANT: S_ATTR_DEBUG               0x02000000
 231 CONSTANT: SECTION_ATTRIBUTES_SYS     0x00ffff00
 232 CONSTANT: S_ATTR_SOME_INSTRUCTIONS   0x00000400
 233 CONSTANT: S_ATTR_EXT_RELOC           0x00000200
 234 CONSTANT: S_ATTR_LOC_RELOC           0x00000100
 235
 236 CONSTANT: SEG_PAGEZERO      "__PAGEZERO"
 237 CONSTANT: SEG_TEXT          "__TEXT"
 238 CONSTANT: SECT_TEXT         "__text"
 239 CONSTANT: SECT_FVMLIB_INIT0 "__fvmlib_init0"
 240 CONSTANT: SECT_FVMLIB_INIT1 "__fvmlib_init1"
 241 CONSTANT: SEG_DATA          "__DATA"
 242 CONSTANT: SECT_DATA         "__data"
 243 CONSTANT: SECT_BSS          "__bss"
 244 CONSTANT: SECT_COMMON       "__common"
 245 CONSTANT: SEG_OBJC          "__OBJC"
 246 CONSTANT: SECT_OBJC_SYMBOLS "__symbol_table"
 247 CONSTANT: SECT_OBJC_MODULES "__module_info"
 248 CONSTANT: SECT_OBJC_STRINGS "__selector_strs"
 249 CONSTANT: SECT_OBJC_REFS    "__selector_refs"
 250 CONSTANT: SEG_ICON          "__ICON"
 251 CONSTANT: SECT_ICON_HEADER  "__header"
 252 CONSTANT: SECT_ICON_TIFF    "__tiff"
 253 CONSTANT: SEG_LINKEDIT      "__LINKEDIT"
 254 CONSTANT: SEG_UNIXSTACK     "__UNIXSTACK"
 255 CONSTANT: SEG_IMPORT        "__IMPORT"
 256
 257 STRUCT: fvmlib
 258     { name             lc_str   }
 259     { minor_version    uint     }
 260     { header_addr      uint     } ;
 261
 262 STRUCT: fvmlib_command
 263     { cmd        uint     }
 264     { cmdsize    uint     }
 265     { fvmlib     fvmlib   } ;
 266
 267 STRUCT: dylib
 268     { name                  lc_str   }
 269     { timestamp             uint     }
 270     { current_version       uint     }
 271     { compatibility_version uint     } ;
 272
 273 STRUCT: dylib_command
 274     { cmd        uint     }
 275     { cmdsize    uint     }
 276     { dylib      dylib    } ;
 277
 278 STRUCT: sub_framework_command
 279     { cmd         uint     }
 280     { cmdsize     uint     }
 281     { umbrella    lc_str   } ;
 282
 283 STRUCT: sub_client_command
 284     { cmd        uint     }
 285     { cmdsize    uint     }
 286     { client     lc_str   } ;
 287
 288 STRUCT: sub_umbrella_command
 289     { cmd             uint     }
 290     { cmdsize         uint     }
 291     { sub_umbrella    lc_str   } ;
 292
 293 STRUCT: sub_library_command
 294     { cmd            uint     }
 295     { cmdsize        uint     }
 296     { sub_library    lc_str   } ;
 297
 298 STRUCT: prebound_dylib_command
 299     { cmd               uint     }
 300     { cmdsize           uint     }
 301     { name              lc_str   }
 302     { nmodules          uint     }
 303     { linked_modules    lc_str   } ;
 304
 305 STRUCT: dylinker_command
 306     { cmd        uint     }
 307     { cmdsize    uint     }
 308     { name       lc_str   } ;
 309
 310 STRUCT: thread_command
 311     { cmd        uint }
 312     { cmdsize    uint } ;
 313
 314 STRUCT: routines_command
 315     { cmd             uint }
 316     { cmdsize         uint }
 317     { init_address    uint }
 318     { init_module     uint }
 319     { reserved1       uint }
 320     { reserved2       uint }
 321     { reserved3       uint }
 322     { reserved4       uint }
 323     { reserved5       uint }
 324     { reserved6       uint } ;
 325
 326 STRUCT: routines_command_64
 327     { cmd             uint      }
 328     { cmdsize         uint      }
 329     { init_address    ulonglong }
 330     { init_module     ulonglong }
 331     { reserved1       ulonglong }
 332     { reserved2       ulonglong }
 333     { reserved3       ulonglong }
 334     { reserved4       ulonglong }
 335     { reserved5       ulonglong }
 336     { reserved6       ulonglong } ;
 337
 338 STRUCT: symtab_command
 339     { cmd        uint }
 340     { cmdsize    uint }
 341     { symoff     uint }
 342     { nsyms      uint }
 343     { stroff     uint }
 344     { strsize    uint } ;
 345
 346 STRUCT: dysymtab_command
 347     { cmd            uint }
 348     { cmdsize        uint }
 349     { ilocalsym      uint }
 350     { nlocalsym      uint }
 351     { iextdefsym     uint }
 352     { nextdefsym     uint }
 353     { iundefsym      uint }
 354     { nundefsym      uint }
 355     { tocoff         uint }
 356     { ntoc           uint }
 357     { modtaboff      uint }
 358     { nmodtab        uint }
 359     { extrefsymoff   uint }
 360     { nextrefsyms    uint }
 361     { indirectsymoff uint }
 362     { nindirectsyms  uint }
 363     { extreloff      uint }
 364     { nextrel        uint }
 365     { locreloff      uint }
 366     { nlocrel        uint } ;
 367
 368 CONSTANT: INDIRECT_SYMBOL_LOCAL 0x80000000
 369 CONSTANT: INDIRECT_SYMBOL_ABS   0x40000000
 370
 371 STRUCT: dylib_table_of_contents
 372     { symbol_index uint }
 373     { module_index uint } ;
 374
 375 STRUCT: dylib_module
 376     { module_name           uint }
 377     { iextdefsym            uint }
 378     { nextdefsym            uint }
 379     { irefsym               uint }
 380     { nrefsym               uint }
 381     { ilocalsym             uint }
 382     { nlocalsym             uint }
 383     { iextrel               uint }
 384     { nextrel               uint }
 385     { iinit_iterm           uint }
 386     { ninit_nterm           uint }
 387     { objc_module_info_addr uint }
 388     { objc_module_info_size uint } ;
 389
 390 STRUCT: dylib_module_64
 391     { module_name           uint      }
 392     { iextdefsym            uint      }
 393     { nextdefsym            uint      }
 394     { irefsym               uint      }
 395     { nrefsym               uint      }
 396     { ilocalsym             uint      }
 397     { nlocalsym             uint      }
 398     { iextrel               uint      }
 399     { nextrel               uint      }
 400     { iinit_iterm           uint      }
 401     { ninit_nterm           uint      }
 402     { objc_module_info_size uint      }
 403     { objc_module_info_addr ulonglong } ;
 404
 405 STRUCT: dylib_reference
 406     { isym_flags uint } ;
 407
 408 STRUCT: twolevel_hints_command
 409     { cmd     uint }
 410     { cmdsize uint }
 411     { offset  uint }
 412     { nhints  uint } ;
 413
 414 STRUCT: twolevel_hint
 415     { isub_image_itoc uint } ;
 416
 417 STRUCT: prebind_cksum_command
 418     { cmd     uint }
 419     { cmdsize uint }
 420     { cksum   uint } ;
 421
 422 STRUCT: uuid_command
 423     { cmd        uint        }
 424     { cmdsize    uint        }
 425     { uuid       uchar[16]   } ;
 426
 427 STRUCT: rpath_command
 428     { cmd         uint     }
 429     { cmdsize     uint     }
 430     { path        lc_str   } ;
 431
 432 STRUCT: linkedit_data_command
 433     { cmd         uint }
 434     { cmdsize     uint }
 435     { dataoff     uint }
 436     { datasize    uint } ;
 437
 438 STRUCT: encryption_info_command
 439     { cmd       uint }
 440     { cmdsize   uint }
 441     { cryptoff  uint }
 442     { cryptsize uint }
 443     { cryptid   uint } ;
 444
 445 STRUCT: dyld_info_command
 446     { cmd              uint }
 447     { cmdsize          uint }
 448     { rebase_off       uint }
 449     { rebase_size      uint }
 450     { bind_off         uint }
 451     { bind_size        uint }
 452     { weak_bind_off    uint }
 453     { weak_bind_size   uint }
 454     { lazy_bind_off    uint }
 455     { lazy_bind_size   uint }
 456     { export_off       uint }
 457     { export_size      uint } ;
 458
 459 STRUCT: version_min_command
 460     { cmd uint32_t }
 461     { cmdsize uint32_t }
 462     { version uint32_t }
 463     { sdk uint32_t } ;
 464
 465 CONSTANT: REBASE_TYPE_POINTER                     1
 466 CONSTANT: REBASE_TYPE_TEXT_ABSOLUTE32             2
 467 CONSTANT: REBASE_TYPE_TEXT_PCREL32                3
 468
 469 CONSTANT: REBASE_OPCODE_MASK                                  0xF0
 470 CONSTANT: REBASE_IMMEDIATE_MASK                               0x0F
 471 CONSTANT: REBASE_OPCODE_DONE                                  0x00
 472 CONSTANT: REBASE_OPCODE_SET_TYPE_IMM                          0x10
 473 CONSTANT: REBASE_OPCODE_SET_SEGMENT_AND_OFFSET_ULEB           0x20
 474 CONSTANT: REBASE_OPCODE_ADD_ADDR_ULEB                         0x30
 475 CONSTANT: REBASE_OPCODE_ADD_ADDR_IMM_SCALED                   0x40
 476 CONSTANT: REBASE_OPCODE_DO_REBASE_IMM_TIMES                   0x50
 477 CONSTANT: REBASE_OPCODE_DO_REBASE_ULEB_TIMES                  0x60
 478 CONSTANT: REBASE_OPCODE_DO_REBASE_ADD_ADDR_ULEB               0x70
 479 CONSTANT: REBASE_OPCODE_DO_REBASE_ULEB_TIMES_SKIPPING_ULEB    0x80
 480
 481 CONSTANT: BIND_TYPE_POINTER                       1
 482 CONSTANT: BIND_TYPE_TEXT_ABSOLUTE32               2
 483 CONSTANT: BIND_TYPE_TEXT_PCREL32                  3
 484
 485 CONSTANT: BIND_SPECIAL_DYLIB_SELF                     0
 486 CONSTANT: BIND_SPECIAL_DYLIB_MAIN_EXECUTABLE          -1
 487 CONSTANT: BIND_SPECIAL_DYLIB_FLAT_LOOKUP              -2
 488
 489 CONSTANT: BIND_SYMBOL_FLAGS_WEAK_IMPORT                   0x1
 490 CONSTANT: BIND_SYMBOL_FLAGS_NON_WEAK_DEFINITION           0x8
 491
 492 CONSTANT: BIND_OPCODE_MASK                                    0xF0
 493 CONSTANT: BIND_IMMEDIATE_MASK                                 0x0F
 494 CONSTANT: BIND_OPCODE_DONE                                    0x00
 495 CONSTANT: BIND_OPCODE_SET_DYLIB_ORDINAL_IMM                   0x10
 496 CONSTANT: BIND_OPCODE_SET_DYLIB_ORDINAL_ULEB                  0x20
 497 CONSTANT: BIND_OPCODE_SET_DYLIB_SPECIAL_IMM                   0x30
 498 CONSTANT: BIND_OPCODE_SET_SYMBOL_TRAILING_FLAGS_IMM           0x40
 499 CONSTANT: BIND_OPCODE_SET_TYPE_IMM                            0x50
 500 CONSTANT: BIND_OPCODE_SET_ADDEND_SLEB                         0x60
 501 CONSTANT: BIND_OPCODE_SET_SEGMENT_AND_OFFSET_ULEB             0x70
 502 CONSTANT: BIND_OPCODE_ADD_ADDR_ULEB                           0x80
 503 CONSTANT: BIND_OPCODE_DO_BIND                                 0x90
 504 CONSTANT: BIND_OPCODE_DO_BIND_ADD_ADDR_ULEB                   0xA0
 505 CONSTANT: BIND_OPCODE_DO_BIND_ADD_ADDR_IMM_SCALED             0xB0
 506 CONSTANT: BIND_OPCODE_DO_BIND_ULEB_TIMES_SKIPPING_ULEB        0xC0
 507
 508 CONSTANT: EXPORT_SYMBOL_FLAGS_KIND_MASK                   0x03
 509 CONSTANT: EXPORT_SYMBOL_FLAGS_KIND_REGULAR                0x00
 510 CONSTANT: EXPORT_SYMBOL_FLAGS_KIND_THREAD_LOCAL           0x01
 511 CONSTANT: EXPORT_SYMBOL_FLAGS_WEAK_DEFINITION             0x04
 512 CONSTANT: EXPORT_SYMBOL_FLAGS_INDIRECT_DEFINITION         0x08
 513 CONSTANT: EXPORT_SYMBOL_FLAGS_HAS_SPECIALIZATIONS         0x10
 514
 515 STRUCT: symseg_command
 516     { cmd        uint }
 517     { cmdsize    uint }
 518     { offset     uint }
 519     { size       uint } ;
 520
 521 STRUCT: ident_command
 522     { cmd     uint }
 523     { cmdsize uint } ;
 524
 525 STRUCT: fvmfile_command
 526     { cmd            uint     }
 527     { cmdsize        uint     }
 528     { name           lc_str   }
 529     { header_addr    uint     } ;
 530
 531 STRUCT: entry_point_command
 532     { cmd uint32_t }
 533     { cmdsize uint32_t }
 534     { entryoff uint64_t }
 535     { stacksize uint64_t } ;
 536
 537 STRUCT: source_version_command
 538     { cmd uint32_t }
 539     { cmdsize uint32_t }
 540     { version uint64_t } ;
 541
 542 STRUCT: data_in_code_entry
 543     { offset uint32_t }
 544     { length uint16_t }
 545     { kind uint16_t } ;
 546
 547 ! machine.h
 548 CONSTANT: CPU_STATE_MAX       4
 549 CONSTANT: CPU_STATE_USER      0
 550 CONSTANT: CPU_STATE_SYSTEM    1
 551 CONSTANT: CPU_STATE_IDLE      2
 552 CONSTANT: CPU_STATE_NICE      3
 553
 554 CONSTANT: CPU_ARCH_MASK   0xff000000
 555 CONSTANT: CPU_ARCH_ABI64  0x01000000
 556
 557 CONSTANT: CPU_TYPE_ANY            -1
 558 CONSTANT: CPU_TYPE_VAX            1
 559 CONSTANT: CPU_TYPE_MC680x0        6
 560 CONSTANT: CPU_TYPE_X86            7
 561 ALIAS: CPU_TYPE_I386              CPU_TYPE_X86
 562 CONSTANT: CPU_TYPE_X86_64         flags{ CPU_TYPE_X86 CPU_ARCH_ABI64 }
 563 CONSTANT: CPU_TYPE_MC98000        10
 564 CONSTANT: CPU_TYPE_HPPA           11
 565 CONSTANT: CPU_TYPE_ARM            12
 566 CONSTANT: CPU_TYPE_MC88000        13
 567 CONSTANT: CPU_TYPE_SPARC          14
 568 CONSTANT: CPU_TYPE_I860           15
 569 CONSTANT: CPU_TYPE_POWERPC        18
 570 CONSTANT: CPU_TYPE_POWERPC64      flags{ CPU_TYPE_POWERPC CPU_ARCH_ABI64 }
 571
 572 CONSTANT: CPU_SUBTYPE_MASK    0xff000000
 573 CONSTANT: CPU_SUBTYPE_LIB64   0x80000000
 574
 575 CONSTANT: CPU_SUBTYPE_MULTIPLE        -1
 576 CONSTANT: CPU_SUBTYPE_LITTLE_ENDIAN   0
 577 CONSTANT: CPU_SUBTYPE_BIG_ENDIAN      1
 578
 579 CONSTANT: CPU_THREADTYPE_NONE     0
 580
 581 CONSTANT: CPU_SUBTYPE_VAX_ALL 0
 582 CONSTANT: CPU_SUBTYPE_VAX780  1
 583 CONSTANT: CPU_SUBTYPE_VAX785  2
 584 CONSTANT: CPU_SUBTYPE_VAX750  3
 585 CONSTANT: CPU_SUBTYPE_VAX730  4
 586 CONSTANT: CPU_SUBTYPE_UVAXI   5
 587 CONSTANT: CPU_SUBTYPE_UVAXII  6
 588 CONSTANT: CPU_SUBTYPE_VAX8200 7
 589 CONSTANT: CPU_SUBTYPE_VAX8500 8
 590 CONSTANT: CPU_SUBTYPE_VAX8600 9
 591 CONSTANT: CPU_SUBTYPE_VAX8650 10
 592 CONSTANT: CPU_SUBTYPE_VAX8800 11
 593 CONSTANT: CPU_SUBTYPE_UVAXIII 12
 594
 595 CONSTANT: CPU_SUBTYPE_MC680x0_ALL     1
 596 CONSTANT: CPU_SUBTYPE_MC68030     1
 597 CONSTANT: CPU_SUBTYPE_MC68040     2
 598 CONSTANT: CPU_SUBTYPE_MC68030_ONLY    3
 599
 600 : CPU_SUBTYPE_INTEL ( f m -- subtype ) 4 shift + ; inline
 601
 602 CONSTANT: CPU_SUBTYPE_I386_ALL              3
 603 CONSTANT: CPU_SUBTYPE_386                   3
 604 CONSTANT: CPU_SUBTYPE_486                   4
 605 CONSTANT: CPU_SUBTYPE_486SX                 132
 606 CONSTANT: CPU_SUBTYPE_586                   5
 607 CONSTANT: CPU_SUBTYPE_PENT                  5
 608 CONSTANT: CPU_SUBTYPE_PENTPRO               22
 609 CONSTANT: CPU_SUBTYPE_PENTII_M3             54
 610 CONSTANT: CPU_SUBTYPE_PENTII_M5             86
 611 CONSTANT: CPU_SUBTYPE_CELERON               103
 612 CONSTANT: CPU_SUBTYPE_CELERON_MOBILE        119
 613 CONSTANT: CPU_SUBTYPE_PENTIUM_3             8
 614 CONSTANT: CPU_SUBTYPE_PENTIUM_3_M           24
 615 CONSTANT: CPU_SUBTYPE_PENTIUM_3_XEON        40
 616 CONSTANT: CPU_SUBTYPE_PENTIUM_M             9
 617 CONSTANT: CPU_SUBTYPE_PENTIUM_4             10
 618 CONSTANT: CPU_SUBTYPE_PENTIUM_4_M           26
 619 CONSTANT: CPU_SUBTYPE_ITANIUM               11
 620 CONSTANT: CPU_SUBTYPE_ITANIUM_2             27
 621 CONSTANT: CPU_SUBTYPE_XEON                  12
 622 CONSTANT: CPU_SUBTYPE_XEON_MP               28
 623
 624 : CPU_SUBTYPE_INTEL_FAMILY ( x -- family ) 15 bitand ; inline
 625
 626 CONSTANT: CPU_SUBTYPE_INTEL_FAMILY_MAX    15
 627
 628 : CPU_SUBTYPE_INTEL_MODEL ( x -- model ) -4 shift ; inline
 629
 630 CONSTANT: CPU_SUBTYPE_INTEL_MODEL_ALL 0
 631 CONSTANT: CPU_SUBTYPE_X86_ALL         3
 632 CONSTANT: CPU_SUBTYPE_X86_64_ALL      3
 633 CONSTANT: CPU_SUBTYPE_X86_ARCH1       4
 634 CONSTANT: CPU_THREADTYPE_INTEL_HTT    1
 635
 636 CONSTANT: CPU_SUBTYPE_MIPS_ALL    0
 637 CONSTANT: CPU_SUBTYPE_MIPS_R2300  1
 638 CONSTANT: CPU_SUBTYPE_MIPS_R2600  2
 639 CONSTANT: CPU_SUBTYPE_MIPS_R2800  3
 640 CONSTANT: CPU_SUBTYPE_MIPS_R2000a 4
 641 CONSTANT: CPU_SUBTYPE_MIPS_R2000  5
 642 CONSTANT: CPU_SUBTYPE_MIPS_R3000a 6
 643 CONSTANT: CPU_SUBTYPE_MIPS_R3000  7
 644
 645 CONSTANT: CPU_SUBTYPE_MC98000_ALL 0
 646 CONSTANT: CPU_SUBTYPE_MC98601     1
 647
 648 CONSTANT: CPU_SUBTYPE_HPPA_ALL        0
 649 CONSTANT: CPU_SUBTYPE_HPPA_7100       0
 650 CONSTANT: CPU_SUBTYPE_HPPA_7100LC     1
 651
 652 CONSTANT: CPU_SUBTYPE_MC88000_ALL 0
 653 CONSTANT: CPU_SUBTYPE_MC88100     1
 654 CONSTANT: CPU_SUBTYPE_MC88110     2
 655
 656 CONSTANT: CPU_SUBTYPE_SPARC_ALL       0
 657
 658 CONSTANT: CPU_SUBTYPE_I860_ALL    0
 659 CONSTANT: CPU_SUBTYPE_I860_860    1
 660
 661 CONSTANT: CPU_SUBTYPE_POWERPC_ALL     0
 662 CONSTANT: CPU_SUBTYPE_POWERPC_601     1
 663 CONSTANT: CPU_SUBTYPE_POWERPC_602     2
 664 CONSTANT: CPU_SUBTYPE_POWERPC_603     3
 665 CONSTANT: CPU_SUBTYPE_POWERPC_603e    4
 666 CONSTANT: CPU_SUBTYPE_POWERPC_603ev   5
 667 CONSTANT: CPU_SUBTYPE_POWERPC_604     6
 668 CONSTANT: CPU_SUBTYPE_POWERPC_604e    7
 669 CONSTANT: CPU_SUBTYPE_POWERPC_620     8
 670 CONSTANT: CPU_SUBTYPE_POWERPC_750     9
 671 CONSTANT: CPU_SUBTYPE_POWERPC_7400    10
 672 CONSTANT: CPU_SUBTYPE_POWERPC_7450    11
 673 CONSTANT: CPU_SUBTYPE_POWERPC_970     100
 674
 675 CONSTANT: CPU_SUBTYPE_ARM_ALL             0
 676 CONSTANT: CPU_SUBTYPE_ARM_V4T             5
 677 CONSTANT: CPU_SUBTYPE_ARM_V6              6
 678 CONSTANT: CPU_SUBTYPE_ARM_V5TEJ           7
 679 CONSTANT: CPU_SUBTYPE_ARM_XSCALE          8
 680 CONSTANT: CPU_SUBTYPE_ARM_V7              9
 681
 682 CONSTANT: CPUFAMILY_UNKNOWN    0
 683 CONSTANT: CPUFAMILY_POWERPC_G3 0xcee41549
 684 CONSTANT: CPUFAMILY_POWERPC_G4 0x77c184ae
 685 CONSTANT: CPUFAMILY_POWERPC_G5 0xed76d8aa
 686 CONSTANT: CPUFAMILY_INTEL_6_13 0xaa33392b
 687 CONSTANT: CPUFAMILY_INTEL_6_14 0x73d67300
 688 CONSTANT: CPUFAMILY_INTEL_6_15 0x426f69ef
 689 CONSTANT: CPUFAMILY_INTEL_6_23 0x78ea4fbc
 690 CONSTANT: CPUFAMILY_INTEL_6_26 0x6b5a4cd2
 691 CONSTANT: CPUFAMILY_ARM_9      0xe73283ae
 692 CONSTANT: CPUFAMILY_ARM_11     0x8ff620d8
 693 CONSTANT: CPUFAMILY_ARM_XSCALE 0x53b005f5
 694 CONSTANT: CPUFAMILY_ARM_13     0x0cc90e64
 695
 696 ALIAS: CPUFAMILY_INTEL_YONAH   CPUFAMILY_INTEL_6_14
 697 ALIAS: CPUFAMILY_INTEL_MEROM   CPUFAMILY_INTEL_6_15
 698 ALIAS: CPUFAMILY_INTEL_PENRYN  CPUFAMILY_INTEL_6_23
 699 ALIAS: CPUFAMILY_INTEL_NEHALEM CPUFAMILY_INTEL_6_26
 700
 701 ALIAS: CPUFAMILY_INTEL_CORE    CPUFAMILY_INTEL_6_14
 702 ALIAS: CPUFAMILY_INTEL_CORE2   CPUFAMILY_INTEL_6_15
 703
 704 ! fat.h
 705 CONSTANT: FAT_MAGIC 0xcafebabe
 706 CONSTANT: FAT_CIGAM 0xbebafeca
 707
 708 STRUCT: fat_header
 709     { magic        uint }
 710     { nfat_arch    uint } ;
 711
 712 STRUCT: fat_arch
 713     { cputype      cpu_type_t    }
 714     { cpusubtype   cpu_subtype_t }
 715     { offset       uint          }
 716     { size         uint          }
 717     { align        uint          } ;
 718
 719 ! nlist.h
 720 STRUCT: nlist
 721     { n_strx  int      }
 722     { n_type  uchar    }
 723     { n_sect  uchar    }
 724     { n_desc  short    }
 725     { n_value uint     } ;
 726
 727 STRUCT: nlist_64
 728     { n_strx  uint      }
 729     { n_type  uchar     }
 730     { n_sect  uchar     }
 731     { n_desc  ushort    }
 732     { n_value ulonglong } ;
 733
 734 CONSTANT: N_STAB  0xe0
 735 CONSTANT: N_PEXT  0x10
 736 CONSTANT: N_TYPE  0x0e
 737 CONSTANT: N_EXT   0x01
 738
 739 CONSTANT: N_UNDF  0x0
 740 CONSTANT: N_ABS   0x2
 741 CONSTANT: N_SECT  0xe
 742 CONSTANT: N_PBUD  0xc
 743 CONSTANT: N_INDR  0xa
 744
 745 CONSTANT: NO_SECT     0
 746 CONSTANT: MAX_SECT    255
 747
 748 : GET_COMM_ALIGN ( n_desc -- align )
 749     -8 shift 0x0f bitand ; inline
 750
 751 : SET_COMM_ALIGN ( n_desc align -- n_desc )
 752     [ 0xf0ff bitand ]
 753     [ 0x000f bitand 8 shift ] bi* bitor ; inline
 754
 755 CONSTANT: REFERENCE_TYPE                              7
 756 CONSTANT: REFERENCE_FLAG_UNDEFINED_NON_LAZY           0
 757 CONSTANT: REFERENCE_FLAG_UNDEFINED_LAZY               1
 758 CONSTANT: REFERENCE_FLAG_DEFINED                      2
 759 CONSTANT: REFERENCE_FLAG_PRIVATE_DEFINED              3
 760 CONSTANT: REFERENCE_FLAG_PRIVATE_UNDEFINED_NON_LAZY   4
 761 CONSTANT: REFERENCE_FLAG_PRIVATE_UNDEFINED_LAZY       5
 762
 763 CONSTANT: REFERENCED_DYNAMICALLY  0x0010
 764
 765 : GET_LIBRARY_ORDINAL ( n_desc -- ordinal )
 766     -8 shift 0xff bitand ; inline
 767
 768 : SET_LIBRARY_ORDINAL ( n_desc ordinal -- n_desc )
 769     [ 0x00ff bitand ]
 770     [ 0x00ff bitand 8 shift ] bi* bitor ; inline
 771
 772 CONSTANT: SELF_LIBRARY_ORDINAL   0x0
 773 CONSTANT: MAX_LIBRARY_ORDINAL    0xfd
 774 CONSTANT: DYNAMIC_LOOKUP_ORDINAL 0xfe
 775 CONSTANT: EXECUTABLE_ORDINAL     0xff
 776
 777 CONSTANT: N_NO_DEAD_STRIP  0x0020
 778 CONSTANT: N_DESC_DISCARDED 0x0020
 779 CONSTANT: N_WEAK_REF       0x0040
 780 CONSTANT: N_WEAK_DEF       0x0080
 781 CONSTANT: N_REF_TO_WEAK    0x0080
 782 CONSTANT: N_ARM_THUMB_DEF  0x0008
 783
 784 ! ranlib.h
 785 CONSTANT: SYMDEF        "__.SYMDEF"
 786 CONSTANT: SYMDEF_SORTED "__.SYMDEF SORTED"
 787
 788 STRUCT: ranlib
 789     { ran_strx uint }
 790     { ran_off  uint } ;
 791
 792 ! reloc.h
 793 STRUCT: relocation_info
 794     { r_address                            int  }
 795     { r_symbolnum_pcrel_length_extern_type uint } ;
 796
 797 CONSTANT: R_ABS   0
 798 CONSTANT: R_SCATTERED 0x80000000
 799
 800 STRUCT: scattered_relocation_info_big_endian
 801     { r_scattered_pcrel_length_type_address  uint }
 802     { r_value                                int  } ;
 803
 804 STRUCT: scattered_relocation_info_little_endian
 805     { r_address_type_length_pcrel_scattered uint }
 806     { r_value                               int  } ;
 807
 808 ENUM: reloc_type_generic
 809     GENERIC_RELOC_VANILLA
 810     GENERIC_RELOC_PAIR
 811     GENERIC_RELOC_SECTDIFF
 812     GENERIC_RELOC_PB_LA_PTR
 813     GENERIC_RELOC_LOCAL_SECTDIFF ;
 814
 815 ENUM: reloc_type_x86_64
 816     X86_64_RELOC_UNSIGNED
 817     X86_64_RELOC_SIGNED
 818     X86_64_RELOC_BRANCH
 819     X86_64_RELOC_GOT_LOAD
 820     X86_64_RELOC_GOT
 821     X86_64_RELOC_SUBTRACTOR
 822     X86_64_RELOC_SIGNED_1
 823     X86_64_RELOC_SIGNED_2
 824     X86_64_RELOC_SIGNED_4 ;
 825
 826 ENUM: reloc_type_ppc
 827     PPC_RELOC_VANILLA
 828     PPC_RELOC_PAIR
 829     PPC_RELOC_BR14
 830     PPC_RELOC_BR24
 831     PPC_RELOC_HI16
 832     PPC_RELOC_LO16
 833     PPC_RELOC_HA16
 834     PPC_RELOC_LO14
 835     PPC_RELOC_SECTDIFF
 836     PPC_RELOC_PB_LA_PTR
 837     PPC_RELOC_HI16_SECTDIFF
 838     PPC_RELOC_LO16_SECTDIFF
 839     PPC_RELOC_HA16_SECTDIFF
 840     PPC_RELOC_JBSR
 841     PPC_RELOC_LO14_SECTDIFF
 842     PPC_RELOC_LOCAL_SECTDIFF ;
 843
 844 ! Low-level interface
 845 SPECIALIZED-ARRAYS: section section_64 nlist nlist_64 fat_arch uchar ;
 846 UNION: mach_header_32/64 mach_header mach_header_64 ;
 847 UNION: segment_command_32/64 segment_command segment_command_64 ;
 848 UNION: load-command segment_command segment_command_64
 849     dylib_command sub_framework_command
 850     sub_client_command sub_umbrella_command sub_library_command
 851     prebound_dylib_command dylinker_command thread_command
 852     routines_command routines_command_64 symtab_command
 853     dysymtab_command twolevel_hints_command uuid_command ;
 854 UNION: section_32/64 section section_64 ;
 855 UNION: section_32/64-array section-array section_64-array ;
 856 UNION: nlist_32/64 nlist nlist_64 ;
 857 UNION: nlist_32/64-array nlist-array nlist_64-array ;
 858
 859 TUPLE: fat-binary-member cpu-type cpu-subtype data ;
 860 ERROR: not-fat-binary ;
 861
 862 : fat-binary-members ( >c-ptr -- fat-binary-members )
 863     fat_header memory>struct dup magic>> {
 864         { FAT_MAGIC [ ] }
 865         { FAT_CIGAM [ ] }
 866         [ 2drop not-fat-binary ]
 867     } case dup
 868     [ >c-ptr fat_header heap-size swap <displaced-alien> ]
 869     [ nfat_arch>> 4 >be le> ] bi
 870     fat_arch <c-direct-array> [
 871         {
 872             [ nip cputype>> 4 >be le> ]
 873             [ nip cpusubtype>> 4 >be le> ]
 874             [ offset>> 4 >be le> swap >c-ptr <displaced-alien> ]
 875             [ nip size>> 4 >be le> uchar <c-direct-array> ]
 876         } 2cleave fat-binary-member boa
 877     ] with { } map-as ;
 878
 879 TYPED: 64-bit? ( macho: mach_header_32/64 -- ? )
 880     magic>> {
 881         { MH_MAGIC_64 [ t ] }
 882         { MH_CIGAM_64 [ t ] }
 883         [ drop f ]
 884     } case ;
 885
 886 : macho-header ( c-ptr -- macho: mach_header_32/64 )
 887     dup mach_header_64 memory>struct 64-bit?
 888     [ mach_header_64 memory>struct ]
 889     [ mach_header memory>struct ] if ;
 890
 891 : cmd>load-command ( cmd -- load-command )
 892     {
 893         { LC_UUID           [ uuid_command           ] }
 894         { LC_SEGMENT        [ segment_command        ] }
 895         { LC_SEGMENT_64     [ segment_command_64     ] }
 896         { LC_SYMTAB         [ symtab_command         ] }
 897         { LC_DYSYMTAB       [ dysymtab_command       ] }
 898         { LC_THREAD         [ thread_command         ] }
 899         { LC_UNIXTHREAD     [ thread_command         ] }
 900         { LC_LOAD_DYLIB     [ dylib_command          ] }
 901         { LC_ID_DYLIB       [ dylib_command          ] }
 902         { LC_PREBOUND_DYLIB [ prebound_dylib_command ] }
 903         { LC_LOAD_DYLINKER  [ dylinker_command       ] }
 904         { LC_ID_DYLINKER    [ dylinker_command       ] }
 905         { LC_ROUTINES       [ routines_command       ] }
 906         { LC_ROUTINES_64    [ routines_command_64    ] }
 907         { LC_TWOLEVEL_HINTS [ twolevel_hints_command ] }
 908         { LC_SUB_FRAMEWORK  [ sub_framework_command  ] }
 909         { LC_SUB_UMBRELLA   [ sub_umbrella_command   ] }
 910         { LC_SUB_LIBRARY    [ sub_library_command    ] }
 911         { LC_SUB_CLIENT     [ sub_client_command     ] }
 912         { LC_DYLD_INFO      [ dyld_info_command      ] }
 913         { LC_DYLD_INFO_ONLY [ dyld_info_command      ] }
 914         { LC_LOAD_UPWARD_DYLIB [ dylib_command ] }
 915         { LC_VERSION_MIN_MACOSX [ version_min_command ] }
 916         { LC_VERSION_MIN_IPHONEOS [ version_min_command ] }
 917         { LC_FUNCTION_STARTS [ linkedit_data_command ] }
 918         { LC_DYLD_ENVIRONMENT [ dylinker_command ] }
 919         { LC_MAIN [ entry_point_command ] }
 920         { LC_DATA_IN_CODE [ data_in_code_entry ] }
 921         { LC_SOURCE_VERSION [ source_version_command ] }
 922         { LC_DYLIB_CODE_SIGN_DRS [ linkedit_data_command ] }
 923     } case ;
 924
 925 : read-command ( cmd -- next-cmd )
 926     dup load_command memory>struct
 927     [ cmd>> cmd>load-command memory>struct , ]
 928     [ cmdsize>> swap <displaced-alien> ] 2bi ;
 929
 930 TYPED: load-commands ( macho: mach_header_32/64 -- load-commands )
 931     [
 932         [ class-of heap-size ]
 933         [ >c-ptr <displaced-alien> ]
 934         [ ncmds>> ] tri <iota> [
 935             drop read-command
 936         ] each drop
 937     ] { } make ;
 938
 939 : segment-commands ( load-commands -- segment-commands )
 940     [ segment_command_32/64? ] filter ; inline
 941
 942 : symtab-commands ( load-commands -- segment-commands )
 943     [ symtab_command? ] filter ; inline
 944
 945 : read-array-string ( uchar-array -- string )
 946     ascii decode 0 swap remove ;
 947
 948 : segment-sections ( segment-command -- sections )
 949     {
 950         [ class-of heap-size ]
 951         [ >c-ptr <displaced-alien> ]
 952         [ nsects>> ]
 953         [ segment_command_64? ]
 954     } cleave
 955     [ section_64 <c-direct-array> ]
 956     [ section <c-direct-array> ] if ;
 957
 958 : sections-array ( segment-commands -- sections-array )
 959     [
 960         dup first segment_command_64?
 961         [ section_64 ] [ section ] if new ,
 962         segment-commands [ segment-sections [ , ] each ] each
 963     ] { } make ;
 964
 965 : symbols ( mach-header symtab-command -- symbols string-table )
 966     [ symoff>> swap >c-ptr <displaced-alien> ]
 967     [ nsyms>> swap 64-bit?
 968       [ nlist_64 <c-direct-array> ]
 969       [ nlist <c-direct-array> ] if ]
 970     [ stroff>> swap >c-ptr <displaced-alien> ] 2tri ;
 971
 972 : symbol-name ( symbol string-table -- name )
 973     [ n_strx>> ] dip <displaced-alien> ascii alien>string ;
 974
 975 : c-symbol-name ( symbol string-table -- name )
 976     symbol-name "_" ?head drop ;
 977
 978 : with-mapped-macho ( path quot -- )
 979     '[
 980         address>> macho-header @
 981     ] with-mapped-file-reader ; inline
 982
 983 : macho-nm ( path -- )
 984     [| macho |
 985         macho load-commands segment-commands sections-array :> sections
 986         macho load-commands symtab-commands [| symtab |
 987             macho symtab symbols [
 988                 [ drop n_value>> "%016x " printf ]
 989                 [
 990                     drop n_sect>> sections nth sectname>>
 991                     read-array-string "%-16s" printf
 992                 ]
 993                 [ symbol-name "%s\n" printf ] 2tri
 994             ] curry each
 995         ] each
 996     ] with-mapped-macho ;
 997
 998 : dylib-export? ( symtab-entry -- ? )
 999     n_type>> {
1000         [ N_EXT bitand zero? not ]
1001         [ N_TYPE bitand N_UNDF = not ]
1002     } 1&& ;
1003
1004 : dylib-exports ( path -- symbol-names )
1005     [| macho |
1006         macho load-commands symtab-commands [| symtab |
1007             macho symtab symbols
1008             [ [ dylib-export? ] filter ]
1009             [ [ c-symbol-name ] curry { } map-as ] bi*
1010         ] { } map-as concat
1011     ] with-mapped-macho ;