extra/managed-server/chat/chat.factor

   1 ! Copyright (C) 2009 Doug Coleman.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs calendar calendar.format
   4 combinators.smart io io.crlf io.encodings.utf8 kernel
   5 managed-server namespaces sequences sorting splitting unicode ;
   6 IN: managed-server.chat
   7
   8 TUPLE: chat-server < managed-server ;
   9
  10 SYMBOL: commands
  11 commands [ H{ } clone ] initialize
  12
  13 SYMBOL: chat-docs
  14 chat-docs [ H{ } clone ] initialize
  15
  16 CONSTANT: line-beginning "-!- "
  17
  18 : send-line ( string -- )
  19     write crlf flush ;
  20
  21 : handle-me ( string -- )
  22     [
  23         [ "* " username " " ] dip
  24     ] "" append-outputs-as send-everyone ;
  25
  26 : handle-quit ( string -- )
  27     client [ object<< ] [ t >>quit? drop ] bi ;
  28
  29 : handle-help ( string -- )
  30     [
  31         "Commands: "
  32         commands get keys sort ", " join append send-line
  33     ] [
  34         chat-docs get ?at
  35         [ send-line ]
  36         [ "Unknown command: " prepend send-line ] if
  37     ] if-empty ;
  38
  39 : usage ( string -- )
  40     chat-docs get at send-line ;
  41
  42 : username-taken-string ( username -- string )
  43     "The username ``" "'' is already in use; try again." surround ;
  44
  45 : warn-name-changed ( old new -- )
  46     [
  47         [ line-beginning "``" ] 2dip
  48         [ "'' is now known as ``" ] dip "''"
  49     ] "" append-outputs-as send-everyone ;
  50
  51 : handle-nick ( string -- )
  52     [
  53         "nick" usage
  54     ] [
  55         dup clients key? [
  56             username-taken-string send-line
  57         ] [
  58             [ username swap warn-name-changed ]
  59             [ username clients rename-at ]
  60             [ client username<< ] tri
  61         ] if
  62     ] if-empty ;
  63
  64 :: add-command ( quot docs key -- )
  65     quot key commands get set-at
  66     docs key chat-docs get set-at ;
  67
  68 [ handle-help ]
  69 "Syntax: /help [command]
  70 Displays the documentation for a command."
  71 "help" add-command
  72
  73 [ drop clients keys [ "``" "''" surround ] map ", " join send-line ]
  74 "Syntax: /who
  75 Shows the list of connected users."
  76 "who" add-command
  77
  78 [ drop now-gmt timestamp>rfc822 send-line ]
  79 "Syntax: /time
  80 Returns the current GMT time." "time" add-command
  81
  82 [ handle-nick ]
  83 "Syntax: /nick nickname
  84 Changes your nickname."
  85 "nick" add-command
  86
  87 [ handle-me ]
  88 "Syntax: /me action"
  89 "me" add-command
  90
  91 [ handle-quit ]
  92 "Syntax: /quit [message]
  93 Disconnects a user from the chat server." "quit" add-command
  94
  95 : handle-command ( string -- )
  96     dup " " split1 swap >lower commands get at* [
  97         call( string -- ) drop
  98     ] [
  99         2drop "Unknown command: " prepend send-line
 100     ] if ;
 101
 102 : <chat-server> ( port -- managed-server )
 103     "chat-server" utf8 chat-server new-managed-server ;
 104
 105 : handle-chat ( string -- )
 106     [
 107         [ username ": " ] dip
 108     ] "" append-outputs-as send-everyone ;
 109
 110 M: chat-server handle-login
 111     "Username: " write flush
 112     readln ;
 113
 114 M: chat-server handle-client-join
 115     [
 116         line-beginning username " has joined"
 117     ] "" append-outputs-as send-everyone ;
 118
 119 M: chat-server handle-client-disconnect
 120     [
 121         line-beginning username " has quit  "
 122         client object>> dup [ "\"" 1surround ] when
 123     ] "" append-outputs-as send-everyone ;
 124
 125 M: chat-server handle-already-logged-in
 126     username username-taken-string send-line
 127     t client quit?<< ;
 128
 129 M: chat-server handle-managed-client*
 130     readln dup f = [ t client quit?<< ] when
 131     [
 132         "/" ?head [ handle-command ] [ handle-chat ] if
 133     ] unless-empty ;