extra/mason/release/sign/sign.factor

   1 ! Copyright (C) 2016 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: io.backend io.pathnames kernel literals mason.common
   4 sequences system ;
   5 IN: mason.release.sign
   6
   7 <<
   8 ! Two cases to allow signing in mason or in the UI
   9 : make-factor-path ( path -- path )
  10     build-dir [
  11         ! In a build, make dir: "build-dir/factor/factor.com"
  12         [ "factor/" prepend-path ] dip prepend-path
  13     ] [
  14         ! Not in build, make dir: "resource:factor.com"
  15         "resource:" prepend-path
  16     ] if* normalize-path ;
  17
  18 HOOK: cert-path os ( -- path/f )
  19
  20 M: object cert-path f ;
  21
  22 M: macosx cert-path "~/config/mac_app.cer" ;
  23
  24 M: windows cert-path "~/config/FactorSPC.pfx" ;
  25 >>
  26
  27 HOOK: sign-factor-app os ( -- )
  28
  29 M: object sign-factor-app ;
  30
  31 M:: macosx sign-factor-app ( -- )
  32     ${
  33         "codesign" "--force" "--sign"
  34         "Developer ID Application"
  35         cert-path normalize-path
  36     }
  37     "Factor.app/" make-factor-path suffix
  38     short-running-process ;
  39
  40 M:: windows sign-factor-app ( -- )
  41     { "factor.com" "factor.exe" } [
  42         [
  43             ${
  44                 "signtool" "sign"
  45                 "/v"
  46                 "/f" cert-path normalize-path
  47             }
  48         ] dip make-factor-path suffix short-running-process
  49     ] each ;
  50
  51 HOOK: sign-archive os ( path -- )
  52
  53 M: object sign-archive drop ;
  54
  55 ! Sign the .dmg on macOS as well to avoid Gatekeeper marking
  56 ! the xattrs as quarantined.
  57 ! https://github.com/factor/factor/issues/1896
  58 M: macosx sign-archive ( path -- )
  59     ${
  60         "codesign" "--force" "--sign"
  61         "Developer ID Application"
  62         cert-path
  63     } swap suffix
  64     short-running-process ;