extra/mason/version/files/files.factor

   1 ! Copyright (C) 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors fry kernel make mason.config mason.platform
   4 mason.release.archive namespaces sequences ;
   5 IN: mason.version.files
   6
   7 : release-directory ( string version -- string )
   8     [ "releases/" % % "/" % % ] "" make ;
   9
  10 : remote-directory ( string -- string' )
  11     [ upload-directory get ] dip "/" glue ;
  12
  13 : remote ( string version -- string )
  14     remote-directory swap "/" glue ;
  15
  16 : platform ( builder -- string )
  17     [ os>> ] [ cpu>> ] bi (platform) ;
  18
  19 : binary-package-name ( builder -- string )
  20     [ [ platform % "/" % ] [ last-release>> % ] bi ] "" make
  21     remote-directory ;
  22
  23 : binary-release-name ( version builder -- string )
  24     [
  25         [
  26             [ "factor-" % platform % "-" % % ]
  27             [ os>> extension % ]
  28             bi
  29         ] "" make
  30     ] [ drop ] 2bi release-directory ;
  31
  32 : remote-binary-release-name ( version builder -- string )
  33     [ binary-release-name ] [ drop ] 2bi remote ;
  34
  35 : source-release-name ( version -- string )
  36     [ "factor-src-" ".zip" surround ] keep release-directory ;
  37
  38 : remote-source-release-name ( version -- string )
  39     [ source-release-name ] keep remote ;