extra/math/text/english/english.factor

   1 ! Copyright (c) 2007, 2008 Aaron Schaefer.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators.short-circuit grouping kernel math math.parser namespaces
   4     sequences ;
   5 IN: math.text.english
   6
   7 <PRIVATE
   8
   9 : small-numbers ( n -- str )
  10     { "Zero" "One" "Two" "Three" "Four" "Five" "Six" "Seven" "Eight" "Nine"
  11     "Ten" "Eleven" "Twelve" "Thirteen" "Fourteen" "Fifteen" "Sixteen"
  12     "Seventeen" "Eighteen" "Nineteen" } nth ;
  13
  14 : tens ( n -- str )
  15     { f f "Twenty" "Thirty" "Forty" "Fifty" "Sixty" "Seventy" "Eighty" "Ninety" } nth ;
  16
  17 : scale-numbers ( n -- str )  ! up to 10^99
  18     { f "Thousand" "Million" "Billion" "Trillion" "Quadrillion" "Quintillion"
  19     "Sextillion" "Septillion" "Octillion" "Nonillion" "Decillion" "Undecillion"
  20     "Duodecillion" "Tredecillion" "Quattuordecillion" "Quindecillion"
  21     "Sexdecillion" "Septendecillion" "Octodecillion" "Novemdecillion"
  22     "Vigintillion" "Unvigintillion" "Duovigintillion" "Trevigintillion"
  23     "Quattuorvigintillion" "Quinvigintillion" "Sexvigintillion"
  24     "Septvigintillion" "Octovigintillion" "Novemvigintillion" "Trigintillion"
  25     "Untrigintillion" "Duotrigintillion" } nth ;
  26
  27 SYMBOL: and-needed?
  28 : set-conjunction ( seq -- )
  29     first { [ 100 < ] [ 0 > ] } 1&& and-needed? set ;
  30
  31 : negative-text ( n -- str )
  32     0 < "Negative " "" ? ;
  33
  34 : 3digit-groups ( n -- seq )
  35     number>string <reversed> 3 <groups>
  36     [ reverse string>number ] map ;
  37
  38 : hundreds-place ( n -- str )
  39     100 /mod swap dup zero? [
  40         2drop ""
  41     ] [
  42         small-numbers " Hundred" append
  43         swap zero? [ " and " append ] unless
  44     ] if ;
  45
  46 : tens-place ( n -- str )
  47     100 mod dup 20 >= [
  48         10 /mod [ tens ] dip
  49         dup zero? [ drop ] [ "-" swap small-numbers 3append ] if
  50     ] [
  51         dup zero? [ drop "" ] [ small-numbers ] if
  52     ] if ;
  53
  54 : 3digits>text ( n -- str )
  55     [ hundreds-place ] [ tens-place ] bi append ;
  56
  57 : text-with-scale ( index seq -- str )
  58     [ nth 3digits>text ] [ drop scale-numbers ] 2bi
  59     [ " " glue ] unless-empty ;
  60
  61 : append-with-conjunction ( str1 str2 -- newstr )
  62     over length zero? [
  63         nip
  64     ] [
  65         and-needed? get " and " ", " ? rot 3append
  66         and-needed? off
  67     ] if ;
  68
  69 : (recombine) ( str index seq -- newstr )
  70     2dup nth zero? [
  71         2drop
  72     ] [
  73         text-with-scale append-with-conjunction
  74     ] if ;
  75
  76 : recombine ( seq -- str )
  77     dup length 1 = [
  78         first 3digits>text
  79     ] [
  80         [ set-conjunction "" ] [ length ] [ ] tri
  81         [ (recombine) ] curry each
  82     ] if ;
  83
  84 : (number>text) ( n -- str )
  85     [ negative-text ] [ abs 3digit-groups recombine ] bi append ;
  86
  87 PRIVATE>
  88
  89 : number>text ( n -- str )
  90     dup zero? [ small-numbers ] [ [ (number>text) ] with-scope ] if ;
  91