extra/math/text/english/english.factor

   1 ! Copyright (c) 2007 Aaron Schaefer.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: combinators.lib kernel math math.functions math.parser namespaces
   4 sequences splitting grouping combinators.short-circuit ;
   5 IN: math.text.english
   6
   7 <PRIVATE
   8
   9 : small-numbers ( n -- str )
  10     { "Zero" "One" "Two" "Three" "Four" "Five" "Six" "Seven" "Eight" "Nine"
  11     "Ten" "Eleven" "Twelve" "Thirteen" "Fourteen" "Fifteen" "Sixteen"
  12     "Seventeen" "Eighteen" "Nineteen" } nth ;
  13
  14 : tens ( n -- str )
  15     { f f "Twenty" "Thirty" "Forty" "Fifty" "Sixty" "Seventy" "Eighty" "Ninety" } nth ;
  16
  17 : scale-numbers ( n -- str )  ! up to 10^99
  18     { f "Thousand" "Million" "Billion" "Trillion" "Quadrillion" "Quintillion"
  19     "Sextillion" "Septillion" "Octillion" "Nonillion" "Decillion" "Undecillion"
  20     "Duodecillion" "Tredecillion" "Quattuordecillion" "Quindecillion"
  21     "Sexdecillion" "Septendecillion" "Octodecillion" "Novemdecillion"
  22     "Vigintillion" "Unvigintillion" "Duovigintillion" "Trevigintillion"
  23     "Quattuorvigintillion" "Quinvigintillion" "Sexvigintillion"
  24     "Septvigintillion" "Octovigintillion" "Novemvigintillion" "Trigintillion"
  25     "Untrigintillion" "Duotrigintillion" } nth ;
  26
  27 SYMBOL: and-needed?
  28 : set-conjunction ( seq -- )
  29     first { [ dup 100 < ] [ dup 0 > ] } 0&& and-needed? set drop ;
  30
  31 : negative-text ( n -- str )
  32     0 < "Negative " "" ? ;
  33
  34 : 3digit-groups ( n -- seq )
  35     number>string <reversed> 3 <groups>
  36     [ reverse string>number ] map ;
  37
  38 : hundreds-place ( n -- str )
  39     100 /mod swap dup zero? [
  40         2drop ""
  41     ] [
  42         small-numbers " Hundred" append
  43         swap zero? [ " and " append ] unless
  44     ] if ;
  45
  46 : tens-place ( n -- str )
  47     100 mod dup 20 >= [
  48         10 /mod [ tens ] dip
  49         dup zero? [ drop ] [ "-" swap small-numbers 3append ] if
  50     ] [
  51         dup zero? [ drop "" ] [ small-numbers ] if
  52     ] if ;
  53
  54 : 3digits>text ( n -- str )
  55     dup hundreds-place swap tens-place append ;
  56
  57 : text-with-scale ( index seq -- str )
  58     dupd nth 3digits>text swap
  59     scale-numbers [
  60         " " swap 3append
  61     ] unless-empty ;
  62
  63 : append-with-conjunction ( str1 str2 -- newstr )
  64     over length zero? [
  65         nip
  66     ] [
  67         and-needed? get " and " ", " ? rot 3append
  68         and-needed? off
  69     ] if ;
  70
  71 : (recombine) ( str index seq -- newstr seq )
  72     2dup nth zero? [
  73         nip
  74     ] [
  75         [ text-with-scale ] keep
  76         -rot append-with-conjunction swap
  77     ] if ;
  78
  79 : recombine ( seq -- str )
  80     dup length 1 = [
  81         first 3digits>text
  82     ] [
  83         dup set-conjunction "" swap
  84         dup length [ swap (recombine) ] each drop
  85     ] if ;
  86
  87 : (number>text) ( n -- str )
  88     [ negative-text ] [ abs 3digit-groups recombine ] bi append ;
  89
  90 PRIVATE>
  91
  92 : number>text ( n -- str )
  93     dup zero? [ small-numbers ] [ [ (number>text) ] with-scope ] if ;
  94