extra/mongodb/tuple/tuple.factor

   1 USING: accessors assocs classes.mixin classes.tuple
   2 classes.tuple.parser compiler.units hashtables kernel
   3 mongodb.driver mongodb.msg mongodb.tuple.collection
   4 mongodb.tuple.persistent sequences ;
   5 FROM: mongodb.driver => update delete find count ;
   6 FROM: mongodb.tuple.persistent => assoc>tuple ;
   7
   8 IN: mongodb.tuple
   9
  10 SYNTAX: MDBTUPLE:
  11     parse-tuple-definition
  12     mdb-check-slots
  13     define-tuple-class ;
  14
  15 : define-persistent ( class collection slot-options index -- )
  16     [ [ <mdb-tuple-collection> dupd link-collection ] when* ] 2dip
  17     [ dup '[ _ mdb-persistent add-mixin-instance ] with-compilation-unit ] 2dip
  18     [ drop set-slot-map ]
  19     [ nip set-index-map ] 3bi ; inline
  20
  21 : ensure-table ( class -- )
  22     tuple-collection
  23     [ create-collection ]
  24     [ [ mdb-index-map values ] keep
  25       '[ _ name>> >>ns ensure-index ] each
  26     ] bi ;
  27
  28 : ensure-tables ( classes -- )
  29     [ ensure-table ] each ;
  30
  31 : drop-table ( class -- )
  32       tuple-collection
  33       [ [ mdb-index-map values ] keep
  34         '[ _ name>> swap name>> drop-index ] each ]
  35       [ name>> drop-collection ] bi ;
  36
  37 : recreate-table ( class -- )
  38     [ drop-table ]
  39     [ ensure-table ] bi ;
  40
  41 DEFER: tuple>query
  42
  43 <PRIVATE
  44
  45 GENERIC: id-selector ( object -- selector )
  46
  47 M: toid id-selector
  48    [ value>> ] [ key>> ] bi associate ; inline
  49
  50 M: mdb-persistent id-selector
  51    >toid id-selector ;
  52
  53 : (save-tuples) ( collection assoc -- )
  54    swap '[ [ _ ] 2dip
  55            [ id-selector ] dip
  56            <update> >upsert update ] assoc-each ; inline
  57
  58 : prepare-tuple-query ( tuple/query -- query )
  59     dup mdb-query-msg? [ tuple>query ] unless ;
  60
  61 PRIVATE>
  62
  63 : save-tuple-deep ( tuple -- )
  64     tuple>storable [ (save-tuples) ] assoc-each ;
  65
  66 : update-tuple ( tuple -- )
  67     [ tuple-collection name>> ]
  68     [ ensure-oid id-selector ]
  69     [ tuple>assoc ] tri
  70     <update> >upsert update ;
  71
  72 : save-tuple ( tuple -- )
  73     update-tuple ;
  74
  75 : insert-tuple ( tuple -- )
  76    [ tuple-collection name>> ]
  77    [ tuple>assoc ] bi
  78    save ;
  79
  80 : delete-tuple ( tuple -- )
  81    [ tuple-collection name>> ] keep
  82    id-selector <delete> delete ;
  83
  84 : delete-tuples ( seq -- )
  85     [ delete-tuple ] each ;
  86
  87 : tuple>query ( tuple -- query )
  88    [ tuple-collection name>> ] keep
  89    tuple>selector <query> ;
  90
  91 : select-tuple ( tuple/query -- tuple/f )
  92    prepare-tuple-query
  93    find-one [ assoc>tuple ] [ f ] if* ;
  94
  95 : select-tuples ( tuple/query -- cursor tuples/f )
  96    prepare-tuple-query
  97    find [ assoc>tuple ] map ;
  98
  99 : select-all-tuples ( tuple/query -- tuples )
 100    prepare-tuple-query
 101    find-all [ assoc>tuple ] map ;
 102
 103 : count-tuples ( tuple/query -- n )
 104    dup mdb-query-msg? [ tuple>query ] unless count ;