extra/morse/morse.factor

   1 ! Copyright (C) 2007, 2008, 2009 Alex Chapman, 2009 Diego Martinelli
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors ascii assocs biassocs combinators hashtables kernel lists literals math namespaces make multiline openal parser sequences splitting strings synth synth.buffers ;
   4 IN: morse
   5
   6 <PRIVATE
   7
   8 CONSTANT: dot-char CHAR: .
   9 CONSTANT: dash-char CHAR: -
  10 CONSTANT: char-gap-char CHAR: \s
  11 CONSTANT: word-gap-char CHAR: /
  12 CONSTANT: unknown-char CHAR: ?
  13
  14 PRIVATE>
  15
  16 CONSTANT: morse-code-table $[
  17     H{
  18         { CHAR: a ".-"    }
  19         { CHAR: b "-..."  }
  20         { CHAR: c "-.-."  }
  21         { CHAR: d "-.."   }
  22         { CHAR: e "."     }
  23         { CHAR: f "..-."  }
  24         { CHAR: g "--."   }
  25         { CHAR: h "...."  }
  26         { CHAR: i ".."    }
  27         { CHAR: j ".---"  }
  28         { CHAR: k "-.-"   }
  29         { CHAR: l ".-.."  }
  30         { CHAR: m "--"    }
  31         { CHAR: n "-."    }
  32         { CHAR: o "---"   }
  33         { CHAR: p ".--."  }
  34         { CHAR: q "--.-"  }
  35         { CHAR: r ".-."   }
  36         { CHAR: s "..."   }
  37         { CHAR: t "-"     }
  38         { CHAR: u "..-"   }
  39         { CHAR: v "...-"  }
  40         { CHAR: w ".--"   }
  41         { CHAR: x "-..-"  }
  42         { CHAR: y "-.--"  }
  43         { CHAR: z "--.."  }
  44         { CHAR: 1 ".----" }
  45         { CHAR: 2 "..---" }
  46         { CHAR: 3 "...--" }
  47         { CHAR: 4 "....-" }
  48         { CHAR: 5 "....." }
  49         { CHAR: 6 "-...." }
  50         { CHAR: 7 "--..." }
  51         { CHAR: 8 "---.." }
  52         { CHAR: 9 "----." }
  53         { CHAR: 0 "-----" }
  54         { CHAR: . ".-.-.-" }
  55         { CHAR: , "--..--" }
  56         { CHAR: ? "..--.." }
  57         { CHAR: ' ".----." }
  58         { CHAR: ! "-.-.--" }
  59         { CHAR: / "-..-."  }
  60         { CHAR: ( "-.--."  }
  61         { CHAR: ) "-.--.-" }
  62         { CHAR: & ".-..."  }
  63         { CHAR: : "---..." }
  64         { CHAR: ; "-.-.-." }
  65         { CHAR: = "-...- " }
  66         { CHAR: + ".-.-."  }
  67         { CHAR: - "-....-" }
  68         { CHAR: _ "..--.-" }
  69         { CHAR: " ".-..-." }
  70         { CHAR: $ "...-..-" }
  71         { CHAR: @ ".--.-." }
  72         { CHAR: \s "/" }
  73     } >biassoc
  74 ]
  75
  76 : ch>morse ( ch -- morse )
  77     ch>lower morse-code-table at [ unknown-char ] unless* ;
  78
  79 : morse>ch ( str -- ch )
  80     morse-code-table value-at [ char-gap-char ] unless* ;
  81
  82 <PRIVATE
  83
  84 : word>morse ( str -- morse )
  85     [ ch>morse ] { } map-as " " join ;
  86
  87 : sentence>morse ( str -- morse )
  88     " " split [ word>morse ] map " / " join ;
  89
  90 : trim-blanks ( str -- newstr )
  91     [ blank? ] trim ; inline
  92
  93 : morse>word ( morse -- str )
  94     " " split [ morse>ch ] "" map-as ;
  95
  96 : morse>sentence ( morse -- sentence )
  97     "/" split [ trim-blanks morse>word ] map " " join ;
  98
  99 : replace-underscores ( str -- str' )
 100     [ dup CHAR: _ = [ drop CHAR: - ] when ] map ;
 101
 102 PRIVATE>
 103
 104 : >morse ( str -- newstr )
 105     trim-blanks sentence>morse ;
 106
 107 : morse> ( morse -- plain )
 108     replace-underscores morse>sentence ;
 109
 110 SYNTAX: [MORSE "MORSE]" parse-multiline-string morse> parsed ;
 111
 112 <PRIVATE
 113
 114 SYMBOLS: source dot-buffer dash-buffer intra-char-gap-buffer letter-gap-buffer ;
 115
 116 : queue ( symbol -- )
 117     get source get swap queue-buffer ;
 118
 119 : dot ( -- ) dot-buffer queue ;
 120 : dash ( -- ) dash-buffer queue ;
 121 : intra-char-gap ( -- ) intra-char-gap-buffer queue ;
 122 : letter-gap ( -- ) letter-gap-buffer queue ;
 123
 124 CONSTANT: beep-freq 880
 125
 126 : <morse-buffer> ( -- buffer )
 127     half-sample-freq <8bit-mono-buffer> ;
 128
 129 : sine-buffer ( seconds -- id )
 130     beep-freq swap <morse-buffer> >sine-wave-buffer
 131     send-buffer id>> ;
 132
 133 : silent-buffer ( seconds -- id )
 134     <morse-buffer> >silent-buffer send-buffer id>> ;
 135
 136 : make-buffers ( unit-length -- )
 137     {
 138         [ sine-buffer dot-buffer set ]
 139         [ 3 * sine-buffer dash-buffer set ]
 140         [ silent-buffer intra-char-gap-buffer set ]
 141         [ 3 * silent-buffer letter-gap-buffer set ]
 142     } cleave ;
 143
 144 : playing-morse ( quot unit-length -- )
 145     [
 146         init-openal 1 gen-sources first source set make-buffers
 147         call
 148         source get source-play
 149     ] with-scope ; inline
 150
 151 : play-char ( ch -- )
 152     [ intra-char-gap ] [
 153         {
 154             { dot-char [ dot ] }
 155             { dash-char [ dash ] }
 156             { word-gap-char [ intra-char-gap ] }
 157         } case
 158     ] interleave ;
 159
 160 PRIVATE>
 161
 162 : play-as-morse* ( str unit-length -- )
 163     [
 164         [ letter-gap ] [ ch>morse play-char ] interleave
 165     ] swap playing-morse ; inline
 166
 167 : play-as-morse ( str -- )
 168     0.05 play-as-morse* ; inline