extra/morse/morse.factor

   1 ! Copyright (C) 2007, 2008, 2009 Alex Chapman, 2009 Diego Martinelli
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors ascii assocs biassocs combinators hashtables kernel lists literals math namespaces make multiline openal parser sequences splitting strings synth synth.buffers ;
   4 IN: morse
   5
   6 ERROR: no-morse-code ch ;
   7
   8 <PRIVATE
   9
  10 CONSTANT: dot-char CHAR: .
  11 CONSTANT: dash-char CHAR: -
  12 CONSTANT: char-gap-char CHAR: \s
  13 CONSTANT: word-gap-char CHAR: /
  14 CONSTANT: unknown-char "?"
  15
  16 PRIVATE>
  17
  18 CONSTANT: morse-code-table $[
  19     H{
  20         { CHAR: a ".-"    }
  21         { CHAR: b "-..."  }
  22         { CHAR: c "-.-."  }
  23         { CHAR: d "-.."   }
  24         { CHAR: e "."     }
  25         { CHAR: f "..-."  }
  26         { CHAR: g "--."   }
  27         { CHAR: h "...."  }
  28         { CHAR: i ".."    }
  29         { CHAR: j ".---"  }
  30         { CHAR: k "-.-"   }
  31         { CHAR: l ".-.."  }
  32         { CHAR: m "--"    }
  33         { CHAR: n "-."    }
  34         { CHAR: o "---"   }
  35         { CHAR: p ".--."  }
  36         { CHAR: q "--.-"  }
  37         { CHAR: r ".-."   }
  38         { CHAR: s "..."   }
  39         { CHAR: t "-"     }
  40         { CHAR: u "..-"   }
  41         { CHAR: v "...-"  }
  42         { CHAR: w ".--"   }
  43         { CHAR: x "-..-"  }
  44         { CHAR: y "-.--"  }
  45         { CHAR: z "--.."  }
  46         { CHAR: 1 ".----" }
  47         { CHAR: 2 "..---" }
  48         { CHAR: 3 "...--" }
  49         { CHAR: 4 "....-" }
  50         { CHAR: 5 "....." }
  51         { CHAR: 6 "-...." }
  52         { CHAR: 7 "--..." }
  53         { CHAR: 8 "---.." }
  54         { CHAR: 9 "----." }
  55         { CHAR: 0 "-----" }
  56         { CHAR: . ".-.-.-" }
  57         { CHAR: , "--..--" }
  58         { CHAR: ? "..--.." }
  59         { CHAR: ' ".----." }
  60         { CHAR: ! "-.-.--" }
  61         { CHAR: / "-..-."  }
  62         { CHAR: ( "-.--."  }
  63         { CHAR: ) "-.--.-" }
  64         { CHAR: & ".-..."  }
  65         { CHAR: : "---..." }
  66         { CHAR: ; "-.-.-." }
  67         { CHAR: = "-...- " }
  68         { CHAR: + ".-.-."  }
  69         { CHAR: - "-....-" }
  70         { CHAR: _ "..--.-" }
  71         { CHAR: " ".-..-." }
  72         { CHAR: $ "...-..-" }
  73         { CHAR: @ ".--.-." }
  74         { CHAR: \s "/" }
  75     } >biassoc
  76 ]
  77
  78 : ch>morse ( ch -- morse )
  79     ch>lower morse-code-table at unknown-char or ;
  80
  81 : morse>ch ( str -- ch )
  82     morse-code-table value-at char-gap-char or ;
  83
  84 <PRIVATE
  85
  86 : word>morse ( str -- morse )
  87     [ ch>morse ] { } map-as " " join ;
  88
  89 : sentence>morse ( str -- morse )
  90     " " split [ word>morse ] map " / " join ;
  91
  92 : trim-blanks ( str -- newstr )
  93     [ blank? ] trim ; inline
  94
  95 : morse>word ( morse -- str )
  96     " " split [ morse>ch ] "" map-as ;
  97
  98 : morse>sentence ( morse -- sentence )
  99     "/" split [ trim-blanks morse>word ] map " " join ;
 100
 101 : replace-underscores ( str -- str' )
 102     [ dup CHAR: _ = [ drop CHAR: - ] when ] map ;
 103
 104 PRIVATE>
 105
 106 : >morse ( str -- newstr )
 107     trim-blanks sentence>morse ;
 108
 109 : morse> ( morse -- plain )
 110     replace-underscores morse>sentence ;
 111
 112 SYNTAX: [MORSE "MORSE]" parse-multiline-string morse> parsed ;
 113
 114 <PRIVATE
 115
 116 SYMBOLS: source dot-buffer dash-buffer intra-char-gap-buffer letter-gap-buffer ;
 117
 118 : queue ( symbol -- )
 119     get source get swap queue-buffer ;
 120
 121 : dot ( -- ) dot-buffer queue ;
 122 : dash ( -- ) dash-buffer queue ;
 123 : intra-char-gap ( -- ) intra-char-gap-buffer queue ;
 124 : letter-gap ( -- ) letter-gap-buffer queue ;
 125
 126 CONSTANT: beep-freq 880
 127
 128 : <morse-buffer> ( -- buffer )
 129     half-sample-freq <8bit-mono-buffer> ;
 130
 131 : sine-buffer ( seconds -- id )
 132     beep-freq swap <morse-buffer> >sine-wave-buffer
 133     send-buffer id>> ;
 134
 135 : silent-buffer ( seconds -- id )
 136     <morse-buffer> >silent-buffer send-buffer id>> ;
 137
 138 : make-buffers ( unit-length -- )
 139     {
 140         [ sine-buffer dot-buffer set ]
 141         [ 3 * sine-buffer dash-buffer set ]
 142         [ silent-buffer intra-char-gap-buffer set ]
 143         [ 3 * silent-buffer letter-gap-buffer set ]
 144     } cleave ;
 145
 146 : playing-morse ( quot unit-length -- )
 147     [
 148         init-openal 1 gen-sources first source set make-buffers
 149         call
 150         source get source-play
 151     ] with-scope ; inline
 152
 153 : play-char ( string -- )
 154     [ intra-char-gap ] [
 155         {
 156             { dot-char [ dot ] }
 157             { dash-char [ dash ] }
 158             { word-gap-char [ intra-char-gap ] }
 159             [ drop intra-char-gap ]
 160         } case
 161     ] interleave ;
 162
 163 PRIVATE>
 164
 165 : play-as-morse* ( str unit-length -- )
 166     [
 167         [ letter-gap ] [ ch>morse play-char ] interleave
 168     ] swap playing-morse ; inline
 169
 170 : play-as-morse ( str -- )
 171     0.05 play-as-morse* ; inline