extra/project-euler/001/001.factor

   1 ! Copyright (c) 2007-2009 Aaron Schaefer, Slava Pestov.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: kernel math math.functions ranges project-euler.common
   4 sequences sets ;
   5 IN: project-euler.001
   6
   7 ! https://projecteuler.net/problem=1
   8
   9 ! DESCRIPTION
  10 ! -----------
  11
  12 ! If we list all the natural numbers below 10 that are multiples
  13 ! of 3 or 5, we get 3, 5, 6 and 9. The sum of these multiples is
  14 ! 23.
  15
  16 ! Find the sum of all the multiples of 3 or 5 below 1000.
  17
  18
  19 ! SOLUTION
  20 ! --------
  21
  22 ! Inclusion-exclusion principle
  23
  24 <PRIVATE
  25
  26 : sum-divisible-by ( target n -- m )
  27     [ /i dup 1 + * ] keep * 2 /i ;
  28
  29 PRIVATE>
  30
  31 : euler001 ( -- answer )
  32     999 3 sum-divisible-by
  33     999 5 sum-divisible-by +
  34     999 15 sum-divisible-by - ;
  35
  36 ! [ euler001 ] 100 ave-time
  37 ! 0 ms ave run time - 0.0 SD (100 trials)
  38
  39
  40 ! ALTERNATE SOLUTIONS
  41 ! -------------------
  42
  43 : euler001a ( -- answer )
  44     0 999 3 <range> sum 0 999 5 <range> sum + 0 999 15 <range> sum - ;
  45
  46 ! [ euler001a ] 100 ave-time
  47 ! 0 ms ave run time - 0.03 SD (100 trials)
  48
  49
  50 : euler001b ( -- answer )
  51     1000 <iota> [ [ 5 mod ] [ 3 mod ] bi [ 0 = ] either? ] filter sum ;
  52
  53 ! [ euler001b ] 100 ave-time
  54 ! 0 ms ave run time - 0.06 SD (100 trials)
  55
  56
  57 : euler001c ( -- answer )
  58     1000 <iota> [ { 3 5 } [ divisor? ] with any? ] filter sum ;
  59
  60 ! [ euler001c ] 100 ave-time
  61 ! 0 ms ave run time - 0.06 SD (100 trials)
  62
  63
  64 : euler001d ( -- answer )
  65     { 3 5 } [ [ 999 ] keep <range> ] gather sum ;
  66
  67 ! [ euler001d ] 100 ave-time
  68 ! 0 ms ave run time - 0.08 SD (100 trials)
  69
  70 SOLUTION: euler001