extra/project-euler/001/001.factor

   1 ! Copyright (c) 2007-2009 Aaron Schaefer, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math math.functions math.ranges project-euler.common sequences
   4     sets ;
   5 IN: project-euler.001
   6
   7 ! http://projecteuler.net/index.php?section=problems&id=1
   8
   9 ! DESCRIPTION
  10 ! -----------
  11
  12 ! If we list all the natural numbers below 10 that are multiples of 3 or 5, we
  13 ! get 3, 5, 6 and 9. The sum of these multiples is 23.
  14
  15 ! Find the sum of all the multiples of 3 or 5 below 1000.
  16
  17
  18 ! SOLUTION
  19 ! --------
  20
  21 ! Inclusion-exclusion principle
  22
  23 <PRIVATE
  24
  25 : sum-divisible-by ( target n -- m )
  26     [ /i dup 1 + * ] keep * 2 /i ;
  27
  28 PRIVATE>
  29
  30 : euler001 ( -- answer )
  31     999 3 sum-divisible-by
  32     999 5 sum-divisible-by +
  33     999 15 sum-divisible-by - ;
  34
  35 ! [ euler001 ] 100 ave-time
  36 ! 0 ms ave run time - 0.0 SD (100 trials)
  37
  38
  39 ! ALTERNATE SOLUTIONS
  40 ! -------------------
  41
  42 : euler001a ( -- answer )
  43     0 999 3 <range> sum 0 999 5 <range> sum + 0 999 15 <range> sum - ;
  44
  45 ! [ euler001a ] 100 ave-time
  46 ! 0 ms ave run time - 0.03 SD (100 trials)
  47
  48
  49 : euler001b ( -- answer )
  50     1000 [0,b) [ [ 5 mod ] [ 3 mod ] bi [ 0 = ] either? ] filter sum ;
  51
  52 ! [ euler001b ] 100 ave-time
  53 ! 0 ms ave run time - 0.06 SD (100 trials)
  54
  55
  56 : euler001c ( -- answer )
  57     1000 [0,b) [ { 3 5 } [ divisor? ] with any? ] filter sum ;
  58
  59 ! [ euler001c ] 100 ave-time
  60 ! 0 ms ave run time - 0.06 SD (100 trials)
  61
  62
  63 : euler001d ( -- answer )
  64     { 3 5 } [ [ 999 ] keep <range> ] gather sum ;
  65
  66 ! [ euler001d ] 100 ave-time
  67 ! 0 ms ave run time - 0.08 SD (100 trials)
  68
  69 SOLUTION: euler001