extra/project-euler/002/002.factor

   1 ! Copyright (c) 2007, 2008 Aaron Schaefer, Alexander Solovyov, Vishal Talwar.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: kernel math sequences project-euler.common ;
   4 IN: project-euler.002
   5
   6 ! https://projecteuler.net/problem=2
   7
   8 ! DESCRIPTION
   9 ! -----------
  10
  11 ! Each new term in the Fibonacci sequence is generated by adding
  12 ! the previous two terms. By starting with 1 and 2, the first 10
  13 ! terms will be:
  14
  15 !     1, 2, 3, 5, 8, 13, 21, 34, 55, 89, ...
  16
  17 ! Find the sum of all the even-valued terms in the sequence
  18 ! which do not exceed four million.
  19
  20
  21 ! SOLUTION
  22 ! --------
  23
  24 <PRIVATE
  25
  26 : (fib-upto) ( seq n limit -- seq )
  27     2dup <= [ [ suffix! dup 2 tail* sum ] dip (fib-upto) ] [ 2drop ] if ;
  28
  29 PRIVATE>
  30
  31 : fib-upto ( n -- seq )
  32     V{ 0 } clone 1 rot (fib-upto) ;
  33
  34 : euler002 ( -- answer )
  35     4,000,000 fib-upto [ even? ] filter sum ;
  36
  37 ! [ euler002 ] 100 ave-time
  38 ! 0 ms ave run time - 0.22 SD (100 trials)
  39
  40
  41 ! ALTERNATE SOLUTIONS
  42 ! -------------------
  43
  44 : fib-upto* ( n -- seq )
  45     [ 1 0 ] dip '[ [ + ] 2keep dup _ < ] [ ] produce 3nip ;
  46
  47 : euler002a ( -- answer )
  48     4,000,000 fib-upto* [ even? ] filter sum ;
  49
  50 ! [ euler002a ] 100 ave-time
  51 ! 0 ms ave run time - 0.2 SD (100 trials)
  52
  53
  54 <PRIVATE
  55
  56 : next-fibs ( x y -- y x+y )
  57     [ nip ] [ + ] 2bi ;
  58
  59 : ?retotal ( total fib- fib+ -- retotal fib- fib+ )
  60     dup even? [ [ nip + ] 2keep ] when ;
  61
  62 : (sum-even-fibs-below) ( partial fib- fib+ max -- total )
  63     2dup > [
  64         3drop
  65     ] [
  66         [ ?retotal next-fibs ] dip (sum-even-fibs-below)
  67     ] if ;
  68
  69 PRIVATE>
  70
  71 : sum-even-fibs-below ( max -- sum )
  72     [ 0 0 1 ] dip (sum-even-fibs-below) ;
  73
  74 : euler002b ( -- answer )
  75     4000000 sum-even-fibs-below ;
  76
  77 ! [ euler002b ] 100 ave-time
  78 ! 0 ms ave run time - 0.0 SD (100 trials)
  79
  80 SOLUTION: euler002b