extra/project-euler/038/038.factor

   1 ! Copyright (c) 2008 Aaron Schaefer.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: kernel math ranges project-euler.common sequences ;
   4 IN: project-euler.038
   5
   6 ! https://projecteuler.net/problem=38
   7
   8 ! DESCRIPTION
   9 ! -----------
  10
  11 ! Take the number 192 and multiply it by each of 1, 2, and 3:
  12
  13 !     192 × 1 = 192
  14 !     192 × 2 = 384
  15 !     192 × 3 = 576
  16
  17 ! By concatenating each product we get the 1 to 9 pandigital,
  18 ! 192384576. We will call 192384576 the concatenated product of
  19 ! 192 and (1,2,3)
  20
  21 ! The same can be achieved by starting with 9 and multiplying by
  22 ! 1, 2, 3, 4, and 5, giving the pandigital, 918273645, which is
  23 ! the concatenated product of 9 and (1,2,3,4,5).
  24
  25 ! What is the largest 1 to 9 pandigital 9-digit number that can
  26 ! be formed as the concatenated product of an integer with
  27 ! (1,2, ..., n) where n > 1?
  28
  29
  30 ! SOLUTION
  31 ! --------
  32
  33 ! Only need to search 4-digit numbers starting with 9 since a
  34 ! 2-digit number starting with 9 would produce 8 or 11 digits,
  35 ! and a 3-digit number starting with 9 would produce 7 or 11
  36 ! digits.
  37
  38 <PRIVATE
  39
  40 : (concat-product) ( accum n multiplier -- m )
  41     pick length 8 > [
  42         2drop digits>number
  43     ] [
  44         [ * number>digits append! ] 2keep 1 + (concat-product)
  45     ] if ;
  46
  47 : concat-product ( n -- m )
  48     V{ } clone swap 1 (concat-product) ;
  49
  50 PRIVATE>
  51
  52 : euler038 ( -- answer )
  53     9123 9876 [a..b] [ concat-product ] map [ pandigital? ] filter supremum ;
  54
  55 ! [ euler038 ] 100 ave-time
  56 ! 11 ms ave run time - 1.5 SD (100 trials)
  57
  58 SOLUTION: euler038