extra/project-euler/038/038.factor

   1 ! Copyright (c) 2008 Aaron Schaefer.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math ranges project-euler.common sequences ;
   4 IN: project-euler.038
   5
   6 ! http://projecteuler.net/index.php?section=problems&id=38
   7
   8 ! DESCRIPTION
   9 ! -----------
  10
  11 ! Take the number 192 and multiply it by each of 1, 2, and 3:
  12
  13 !     192 × 1 = 192
  14 !     192 × 2 = 384
  15 !     192 × 3 = 576
  16
  17 ! By concatenating each product we get the 1 to 9 pandigital, 192384576. We
  18 ! will call 192384576 the concatenated product of 192 and (1,2,3)
  19
  20 ! The same can be achieved by starting with 9 and multiplying by 1, 2, 3, 4,
  21 ! and 5, giving the pandigital, 918273645, which is the concatenated product of
  22 ! 9 and (1,2,3,4,5).
  23
  24 ! What is the largest 1 to 9 pandigital 9-digit number that can be formed as
  25 ! the concatenated product of an integer with (1,2, ... , n) where n > 1?
  26
  27
  28 ! SOLUTION
  29 ! --------
  30
  31 ! Only need to search 4-digit numbers starting with 9 since a 2-digit number
  32 ! starting with 9 would produce 8 or 11 digits, and a 3-digit number starting
  33 ! with 9 would produce 7 or 11 digits.
  34
  35 <PRIVATE
  36
  37 : (concat-product) ( accum n multiplier -- m )
  38     pick length 8 > [
  39         2drop digits>number
  40     ] [
  41         [ * number>digits append! ] 2keep 1 + (concat-product)
  42     ] if ;
  43
  44 : concat-product ( n -- m )
  45     V{ } clone swap 1 (concat-product) ;
  46
  47 PRIVATE>
  48
  49 : euler038 ( -- answer )
  50     9123 9876 [a..b] [ concat-product ] map [ pandigital? ] filter supremum ;
  51
  52 ! [ euler038 ] 100 ave-time
  53 ! 11 ms ave run time - 1.5 SD (100 trials)
  54
  55 SOLUTION: euler038