extra/project-euler/065/065.factor

   1 ! Copyright (c) 2009 Guillaume Nargeot.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math lists lists.lazy project-euler.common sequences ;
   4 IN: project-euler.065
   5
   6 ! http://projecteuler.net/index.php?section=problems&id=065
   7
   8 ! DESCRIPTION
   9 ! -----------
  10
  11 ! The square root of 2 can be written as an infinite continued fraction.
  12
  13 !                      1
  14 ! √2 = 1 + -------------------------
  15 !                        1
  16 !          2 + ---------------------
  17 !                          1
  18 !              2 + -----------------
  19 !                            1
  20 !                  2 + -------------
  21 !                      2 + ...
  22
  23 ! The infinite continued fraction can be written, √2 = [1;(2)], (2) indicates
  24 ! that 2 repeats ad infinitum. In a similar way, √23 = [4;(1,3,1,8)].
  25
  26 ! It turns out that the sequence of partial values of continued fractions for
  27 ! square roots provide the best rational approximations. Let us consider the
  28 ! convergents for √2.
  29
  30 !     1   3         1     7           1       17             1         41
  31 ! 1 + - = - ; 1 + ----- = - ; 1 + --------- = -- ; 1 + ------------- = --
  32 !     2   2           1   5             1     12               1       29
  33 !                 2 + -           2 + -----            2 + ---------
  34 !                     2                   1                      1
  35 !                                     2 + -                2 + -----
  36 !                                         2                        1
  37 !                                                              2 + -
  38 !                                                                  2
  39
  40 ! Hence the sequence of the first ten convergents for √2 are:
  41 ! 1, 3/2, 7/5, 17/12, 41/29, 99/70, 239/169, 577/408, 1393/985, 3363/2378, ...
  42
  43 ! What is most surprising is that the important mathematical constant,
  44 ! e = [2; 1,2,1, 1,4,1, 1,6,1 , ... , 1,2k,1, ...].
  45
  46 ! The first ten terms in the sequence of convergents for e are:
  47 ! 2, 3, 8/3, 11/4, 19/7, 87/32, 106/39, 193/71, 1264/465, 1457/536, ...
  48
  49 ! The sum of digits in the numerator of the 10th convergent is 1+4+5+7=17.
  50
  51 ! Find the sum of digits in the numerator of the 100th convergent of the
  52 ! continued fraction for e.
  53
  54
  55 ! SOLUTION
  56 ! --------
  57
  58 <PRIVATE
  59
  60 : (e-frac) ( -- seq )
  61     2 lfrom [
  62         dup 3 mod zero? [ 3 / 2 * ] [ drop 1 ] if
  63     ] lmap-lazy ;
  64
  65 : e-frac ( n -- n )
  66     1 - (e-frac) ltake list>array reverse 0
  67     [ + recip ] reduce 2 + ;
  68
  69 PRIVATE>
  70
  71 : euler065 ( -- answer )
  72     100 e-frac numerator number>digits sum ;
  73
  74 ! [ euler065 ] 100 ave-time
  75 ! 4 ms ave run time - 0.33 SD (100 trials)
  76
  77 SOLUTION: euler065