extra/python/python-docs.factor

   1 USING: alien destructors help.markup help.syntax quotations ;
   2 IN: python
   3
   4 HELP: py-initialize
   5 { $description "Initializes the python binding. This word must be called before any other words in the api can be used" } ;
   6
   7 HELP: py-finalize
   8 { $description "Finalizes the python binding. After this word is called the api must not be used anymore." } ;
   9
  10 HELP: >py
  11 { $values { "obj" "a factor object" } { "py-obj" "a python object" } }
  12 { $description "Converts a factor objects to its most fitting python representation." }
  13 { $examples
  14   { $unchecked-example
  15     "USING: arrays prettyprint python sequences ;"
  16     "10 <iota> >array >py py> ."
  17     "{ 0 1 2 3 4 5 6 7 8 9 }"
  18   }
  19 }
  20 { $see-also py> } ;
  21
  22 HELP: quot>py-callback
  23 { $values { "quot" { $quotation ( args kw -- ret ) } } { "alien" alien } }
  24 { $description "Creates a python-compatible alien callback from a quotation." }
  25 { $examples
  26   "This is how you create a callback which returns the double of its first positional parameter:"
  27   { $unchecked-example
  28     "USING: python ;"
  29     ": double-fun ( -- alien ) [ drop first 2 * ] quot>py-callback ;"
  30   }
  31 } ;
  32
  33 HELP: with-quot>py-cfunction
  34 { $values { "alien" alien } { "quot" quotation } }
  35 { $description "Wrapper for " { $link with-callback } " to be used when passing functions as arguments to Python functions. It should be used in conjunction with " { $link quot>py-callback } " which creates the callbacks this word consumes." } ;
  36
  37 HELP: python-error
  38 { $error-description "When Python throws an exception, it is translated to this Factor error. " { $slot "type" } " is the class name of the python exception object, " { $slot "message" } " its string and " { $slot "traceback" } " a sequence of traceback lines, if the error has one, or " { $link f } " otherwise." } ;
  39
  40 ARTICLE: "python" "Python binding"
  41 "The " { $vocab-link "python" } " vocab and its subvocabs implements a simple binding for libpython, allowing factor code to call native python."
  42 $nl
  43 "Converting to and from Python:"
  44 { $subsections >py py> quot>py-callback }
  45 "Error handling:"
  46 { $subsections python-error }
  47 "Initialization and finalization:"
  48 { $subsections py-initialize py-finalize }
  49 "Module management:"
  50 { $subsections py-import }
  51 "The vocab " { $vocab-link "python.syntax" } " implements a higher level factorific interface on top of the lower-level constructs in this vocab. Prefer to use that vocab most of the time."
  52 { $notes "Sometimes the embedded python interpreter can't find or finds the wrong load path to it's module library. To counteract that problem it is recommended that the " { $snippet "PYTHONHOME" } " environment variable is set before " { $link py-initialize } " is called. E.g:" }
  53 { $code "\"C:/python27-64bit/\" \"PYTHONHOME\" set-os-env" }
  54 { $warning "All code that calls Python words should always be wrapped in a " { $link with-destructors } " context. The reason is that the words add references to Pythons internal memory heap which are removed when the destructors trigger." } ;
  55
  56 ABOUT: "python"