extra/quadtrees/quadtrees.factor

   1 ! (c) 2009 Joe Groff, see BSD license
   2 USING: assocs kernel math.geometry.rect combinators accessors
   3 math.vectors vectors sequences math math.points math.geometry
   4 combinators.short-circuit arrays fry ;
   5 IN: quadtrees
   6
   7 TUPLE: quadtree { bounds rect } point value ll lr ul ur leaf? ;
   8
   9 : <quadtree> ( bounds -- quadtree )
  10     quadtree new
  11         swap >>bounds
  12         t >>leaf? ;
  13
  14 : rect-ll ( rect -- point ) loc>> ;
  15 : rect-lr ( rect -- point ) [ loc>> ] [ width  ] bi v+x ;
  16 : rect-ul ( rect -- point ) [ loc>> ] [ height ] bi v+y ;
  17 : rect-ur ( rect -- point ) [ loc>> ] [ dim>>  ] bi v+  ;
  18
  19 : rect-center ( rect -- point ) [ loc>> ] [ dim>> 0.5 v*n ] bi v+ ; inline
  20
  21 : (quadrant) ( pt node -- quadrant )
  22     swap [ first 0.0 < ] [ second 0.0 < ] bi
  23     [ [ ll>> ] [ lr>> ] if ]
  24     [ [ ul>> ] [ ur>> ] if ] if ;
  25
  26 : quadrant ( pt node -- quadrant )
  27     [ bounds>> rect-center v- ] keep (quadrant) ;
  28
  29 : descend ( pt node -- pt subnode )
  30     [ drop ] [ quadrant ] 2bi ; inline
  31
  32 : each-quadrant ( node quot -- )
  33     {
  34         [ [ ll>> ] [ call ] bi* ]
  35         [ [ lr>> ] [ call ] bi* ]
  36         [ [ ul>> ] [ call ] bi* ]
  37         [ [ ur>> ] [ call ] bi* ]
  38     } 2cleave ; inline
  39 : map-quadrant ( node quot: ( child-node -- x ) -- array )
  40     each-quadrant 4array ; inline
  41
  42 <PRIVATE
  43
  44 DEFER: (prune)
  45 DEFER: insert
  46 DEFER: erase
  47 DEFER: at-point
  48 DEFER: quadtree>alist
  49 DEFER: quadtree-size
  50 DEFER: node-insert
  51 DEFER: in-rect*
  52
  53 : child-dim ( rect -- dim/2 ) dim>> 0.5 v*n ; inline
  54 : ll-bounds ( rect -- rect' )
  55     [   loc>>                                  ] [ child-dim ] bi <rect> ;
  56 : lr-bounds ( rect -- rect' )
  57     [ [ loc>> ] [ dim>> { 0.5 0.0 } v* ] bi v+ ] [ child-dim ] bi <rect> ;
  58 : ul-bounds ( rect -- rect' )
  59     [ [ loc>> ] [ dim>> { 0.0 0.5 } v* ] bi v+ ] [ child-dim ] bi <rect> ;
  60 : ur-bounds ( rect -- rect' )
  61     [ [ loc>> ] [ dim>> { 0.5 0.5 } v* ] bi v+ ] [ child-dim ] bi <rect> ;
  62
  63 : {quadrants} ( node -- quadrants )
  64     { [ ll>> ] [ lr>> ] [ ul>> ] [ ur>> ] } cleave 4array ;
  65
  66 : add-subnodes ( node -- node )
  67     dup bounds>> {
  68         [ ll-bounds <quadtree> >>ll ]
  69         [ lr-bounds <quadtree> >>lr ]
  70         [ ul-bounds <quadtree> >>ul ]
  71         [ ur-bounds <quadtree> >>ur ]
  72     } cleave
  73     f >>leaf? ;
  74
  75 : split-leaf ( value point leaf -- )
  76     add-subnodes
  77     [ value>> ] [ point>> ] [ ] tri
  78     [ node-insert ] [ node-insert ] bi ;
  79
  80 : leaf-replaceable? ( pt leaf -- ? ) point>> { [ nip not ] [ = ] } 2|| ;
  81
  82 : leaf-insert ( value point leaf -- )
  83     2dup leaf-replaceable?
  84     [ [ (>>point) ] [ (>>value) ] bi ]
  85     [ split-leaf ] if ;
  86
  87 : node-insert ( value point node -- )
  88     descend insert ;
  89
  90 : insert ( value point tree -- )
  91     dup leaf?>> [ leaf-insert ] [ node-insert ] if ;
  92
  93 : leaf-at-point ( point leaf -- value/f ? )
  94     tuck point>> = [ value>> t ] [ drop f f ] if ;
  95
  96 : node-at-point ( point node -- value/f ? )
  97     descend at-point ;
  98
  99 : at-point ( point tree -- value/f ? )
 100     dup leaf?>> [ leaf-at-point ] [ node-at-point ] if ;
 101
 102 : (node-in-rect*) ( values rect node -- values )
 103     2dup bounds>> intersects? [ in-rect* ] [ 2drop ] if ;
 104 : node-in-rect* ( values rect node -- values )
 105     [ (node-in-rect*) ] with each-quadrant ;
 106
 107 : leaf-in-rect* ( values rect leaf -- values )
 108     tuck { [ nip point>> ] [ point>> swap intersects? ] } 2&&
 109     [ value>> over push ] [ drop ] if ;
 110
 111 : in-rect* ( values rect tree -- values )
 112     dup leaf?>> [ leaf-in-rect* ] [ node-in-rect* ] if ;
 113
 114 : leaf-erase ( point leaf -- )
 115     tuck point>> = [ f >>point f >>value ] when drop ;
 116
 117 : node-erase ( point node -- )
 118     descend erase ;
 119
 120 : erase ( point tree -- )
 121     dup leaf?>> [ leaf-erase ] [ node-erase ] if ;
 122
 123 : (?leaf) ( quadrant -- {point,value}/f )
 124     dup point>> [ swap value>> 2array ] [ drop f ] if* ;
 125 : ?leaf ( quadrants -- {point,value}/f )
 126     [ (?leaf) ] map sift dup length {
 127         { 1 [ first ] }
 128         { 0 [ drop { f f } ] }
 129         [ 2drop f ]
 130     } case ;
 131
 132 : collapseable? ( node -- {point,value}/f )
 133     {quadrants} { [ [ leaf?>> ] all? ] [ ?leaf ] } 1&& ;
 134
 135 : remove-subnodes ( node -- leaf ) f >>ll f >>lr f >>ul f >>ur t >>leaf? ;
 136
 137 : collapse ( node {point,value} -- )
 138     first2 [ >>point ] [ >>value ] bi* remove-subnodes drop ;
 139
 140 : node-prune ( node -- )
 141     [ [ (prune) ] each-quadrant ] [ ] [ collapseable? ] tri
 142     [ collapse ] [ drop ] if* ;
 143
 144 : (prune) ( tree -- )
 145     dup leaf?>> [ drop ] [ node-prune ] if ;
 146
 147 : leaf>alist ( leaf -- alist )
 148     dup point>> [ [ point>> ] [ value>> ] bi 2array 1array ] [ drop { } ] if ;
 149
 150 : node>alist ( node -- alist ) [ quadtree>alist ] map-quadrant concat ;
 151
 152 : quadtree>alist ( tree -- assoc )
 153     dup leaf?>> [ leaf>alist ] [ node>alist ] if ;
 154
 155 : leaf-size ( leaf -- count )
 156     point>> [ 1 ] [ 0 ] if ;
 157 : node-size ( node -- count )
 158     0 swap [ quadtree-size + ] each-quadrant ;
 159
 160 : quadtree-size ( tree -- count )
 161     dup leaf?>> [ leaf-size ] [ node-size ] if ;
 162
 163 : leaf= ( a b -- ? ) [ [ point>> ] [ value>> ] bi 2array ] bi@ = ;
 164
 165 : node= ( a b -- ? ) [ {quadrants} ] bi@ = ;
 166
 167 : (tree=) ( a b -- ? ) dup leaf?>> [ leaf= ] [ node= ] if ;
 168
 169 : tree= ( a b -- ? )
 170     2dup [ leaf?>> ] bi@ = [ (tree=) ] [ 2drop f ] if ;
 171
 172 PRIVATE>
 173
 174 : prune-quadtree ( tree -- tree ) [ (prune) ] keep ;
 175
 176 : in-rect ( tree rect -- values )
 177     [ 16 <vector> ] 2dip in-rect* ;
 178
 179 M: quadtree equal? ( a b -- ? )
 180     over quadtree? [ tree= ] [ 2drop f ] if ;
 181
 182 INSTANCE: quadtree assoc
 183
 184 M: quadtree at* ( key assoc -- value/f ? ) at-point ;
 185 M: quadtree assoc-size ( assoc -- n ) quadtree-size ;
 186 M: quadtree >alist ( assoc -- alist ) quadtree>alist ;
 187 M: quadtree set-at ( value key assoc -- ) insert ;
 188 M: quadtree delete-at ( key assoc -- ) erase ;
 189 M: quadtree clear-assoc ( assoc -- )
 190     t >>leaf?
 191     f >>point
 192     f >>value
 193     drop ;
 194
 195 : swizzle ( sequence quot -- sequence' )
 196     [ dup ] dip map
 197     [ zip ] [ rect-containing <quadtree> ] bi
 198     [ '[ first2 _ set-at ] each ] [ values ] bi ;
 199