extra/reports/noise/noise.factor

   1 ! Copyright (C) 2008 Slava Pestov.\r
   2 ! See http://factorcode.org/license.txt for BSD license.\r
   3 USING: accessors assocs math kernel shuffle generalizations\r
   4 words quotations arrays combinators sequences math.vectors\r
   5 io.styles prettyprint vocabs sorting io generic\r
   6 math.statistics math.order locals.types\r
   7 locals.definitions ;\r
   8 IN: reports.noise\r
   9 \r
  10 : badness ( word -- n )\r
  11     H{\r
  12         { -nrot 5 }\r
  13         { -roll 4 }\r
  14         { -rot 3 }\r
  15         { bi@ 1 }\r
  16         { 2curry 1 }\r
  17         { 2drop 1 }\r
  18         { 2dup 1 }\r
  19         { 2keep 1 }\r
  20         { 2nip 2 }\r
  21         { 2over 4 }\r
  22         { 2slip 2 }\r
  23         { 2swap 3 }\r
  24         { 3curry 2 }\r
  25         { 3drop 1 }\r
  26         { 3dup 2 }\r
  27         { 3keep 3 }\r
  28         { 3slip 3 }\r
  29         { 4drop 2 }\r
  30         { 4dup 3 }\r
  31         { compose 1/2 }\r
  32         { curry 1/3 }\r
  33         { dip 1 }\r
  34         { 2dip 2 }\r
  35         { drop 1/3 }\r
  36         { dup 1/3 }\r
  37         { if 1/3 }\r
  38         { when 1/4 }\r
  39         { unless 1/4 }\r
  40         { when* 1/3 }\r
  41         { unless* 1/3 }\r
  42         { ?if 1/2 }\r
  43         { cond 1/2 }\r
  44         { case 1/2 }\r
  45         { keep 1 }\r
  46         { napply 2 }\r
  47         { ncurry 3 }\r
  48         { ndip 5 }\r
  49         { ndrop 2 }\r
  50         { ndup 3 }\r
  51         { nip 2 }\r
  52         { nkeep 5 }\r
  53         { npick 6 }\r
  54         { nrot 5 }\r
  55         { nslip 5 }\r
  56         { ntuck 6 }\r
  57         { nwith 4 }\r
  58         { over 2 }\r
  59         { pick 4 }\r
  60         { roll 4 }\r
  61         { rot 3 }\r
  62         { slip 1 }\r
  63         { spin 3 }\r
  64         { swap 1 }\r
  65         { swapd 3 }\r
  66         { tuck 2 }\r
  67         { with 1/2 }\r
  68 \r
  69         { bi 1/2 }\r
  70         { tri 1 }\r
  71         { bi* 1/2 }\r
  72         { tri* 1 }\r
  73 \r
  74         { cleave 2 }\r
  75         { spread 2 }\r
  76     } at 0 or ;\r
  77 \r
  78 : vsum ( pairs -- pair ) { 0 0 } [ v+ ] reduce ;\r
  79 \r
  80 GENERIC: noise ( obj -- pair )\r
  81 \r
  82 M: word noise badness 1 2array ;\r
  83 \r
  84 M: wrapper noise wrapped>> noise ;\r
  85 \r
  86 M: let noise body>> noise ;\r
  87 \r
  88 M: wlet noise body>> noise ;\r
  89 \r
  90 M: lambda noise body>> noise ;\r
  91 \r
  92 M: object noise drop { 0 0 } ;\r
  93 \r
  94 M: quotation noise [ noise ] map vsum { 1/4 1/2 } v+ ;\r
  95 \r
  96 M: array noise [ noise ] map vsum ;\r
  97 \r
  98 : noise-factor ( x y -- z ) / 100 * >integer ;\r
  99 \r
 100 : quot-noise-factor ( quot -- n )\r
 101     #! For very short words, noise doesn't count so much\r
 102     #! (so dup foo swap bar isn't penalized as badly).\r
 103     noise first2 {\r
 104         { [ over 4 <= ] [ [ drop 0 ] dip ] }\r
 105         { [ over 15 >= ] [ [ 2 * ] dip ] }\r
 106         [ ]\r
 107     } cond\r
 108     {\r
 109         ! short words are easier to read\r
 110         { [ dup 10 <= ] [ [ 2 / ] dip ] }\r
 111         { [ dup 5 <= ] [ [ 3 / ] dip ] }\r
 112         ! long words are penalized even more\r
 113         { [ dup 25 >= ] [ [ 2 * ] dip 20 max ] }\r
 114         { [ dup 20 >= ] [ [ 5/3 * ] dip ] }\r
 115         { [ dup 15 >= ] [ [ 3/2 * ] dip ] }\r
 116         [ ]\r
 117     } cond noise-factor ;\r
 118 \r
 119 GENERIC: word-noise-factor ( word -- factor )\r
 120 \r
 121 M: word word-noise-factor\r
 122     def>> quot-noise-factor ;\r
 123 \r
 124 M: lambda-word word-noise-factor\r
 125     "lambda" word-prop quot-noise-factor ;\r
 126 \r
 127 : flatten-generics ( words -- words' )\r
 128     [\r
 129         dup generic? [ "methods" word-prop values ] [ 1array ] if\r
 130     ] map concat ;\r
 131 \r
 132 : noisy-words ( -- alist )\r
 133     all-words flatten-generics\r
 134     [ dup word-noise-factor ] { } map>assoc\r
 135     sort-values reverse ;\r
 136 \r
 137 : noise. ( alist -- )\r
 138     standard-table-style [\r
 139         [\r
 140             [ [ pprint-cell ] [ pprint-cell ] bi* ] with-row\r
 141         ] assoc-each\r
 142     ] tabular-output ;\r
 143 \r
 144 : vocab-noise-factor ( vocab -- factor )\r
 145     words flatten-generics\r
 146     [ word-noise-factor dup 20 < [ drop 0 ] when ] map\r
 147     [ 0 ] [\r
 148         [ [ sum ] [ length 5 max ] bi /i ]\r
 149         [ supremum ]\r
 150         bi +\r
 151     ] if-empty ;\r
 152 \r
 153 : noisy-vocabs ( -- alist )\r
 154     vocabs [ dup vocab-noise-factor ] { } map>assoc\r
 155     sort-values reverse ;\r
 156 \r
 157 : noise-report ( -- )\r
 158     "NOISY WORDS:" print\r
 159     noisy-words 80 head noise.\r
 160     nl\r
 161     "NOISY VOCABS:" print\r
 162     noisy-vocabs 80 head noise. ;\r
 163 \r
 164 MAIN: noise-report\r