extra/reports/noise/noise.factor

   1 ! Copyright (C) 2008 Slava Pestov.\r
   2 ! See http://factorcode.org/license.txt for BSD license.\r
   3 USING: accessors assocs math kernel shuffle generalizations\r
   4 words quotations arrays combinators sequences math.vectors\r
   5 io.styles prettyprint vocabs sorting io generic\r
   6 math.statistics math.order combinators.lib locals.types\r
   7 locals.definitions ;\r
   8 IN: reports.noise\r
   9 \r
  10 : badness ( word -- n )\r
  11     H{\r
  12         { -nrot 5 }\r
  13         { -roll 4 }\r
  14         { -rot 3 }\r
  15         { bi@ 1 }\r
  16         { 2curry 1 }\r
  17         { 2drop 1 }\r
  18         { 2dup 1 }\r
  19         { 2keep 1 }\r
  20         { 2nip 2 }\r
  21         { 2over 4 }\r
  22         { 2slip 2 }\r
  23         { 2swap 3 }\r
  24         { 2with 2 }\r
  25         { 2with* 3 }\r
  26         { 3curry 2 }\r
  27         { 3drop 1 }\r
  28         { 3dup 2 }\r
  29         { 3keep 3 }\r
  30         { 3nip 4 }\r
  31         { 3slip 3 }\r
  32         { 3with 3 }\r
  33         { 3with* 4 }\r
  34         { 4drop 2 }\r
  35         { 4dup 3 }\r
  36         { 4slip 4 }\r
  37         { compose 1/2 }\r
  38         { curry 1/3 }\r
  39         { dip 1 }\r
  40         { 2dip 2 }\r
  41         { drop 1/3 }\r
  42         { dup 1/3 }\r
  43         { if 1/3 }\r
  44         { when 1/4 }\r
  45         { unless 1/4 }\r
  46         { when* 1/3 }\r
  47         { unless* 1/3 }\r
  48         { ?if 1/2 }\r
  49         { cond 1/2 }\r
  50         { case 1/2 }\r
  51         { keep 1 }\r
  52         { napply 2 }\r
  53         { ncurry 3 }\r
  54         { ndip 5 }\r
  55         { ndrop 2 }\r
  56         { ndup 3 }\r
  57         { nip 2 }\r
  58         { nipd 3 }\r
  59         { nkeep 5 }\r
  60         { npick 6 }\r
  61         { nrev 5 }\r
  62         { nrot 5 }\r
  63         { nslip 5 }\r
  64         { ntuck 6 }\r
  65         { nwith 4 }\r
  66         { over 2 }\r
  67         { pick 4 }\r
  68         { roll 4 }\r
  69         { rot 3 }\r
  70         { slip 1 }\r
  71         { spin 3 }\r
  72         { swap 1 }\r
  73         { swapd 3 }\r
  74         { tuck 2 }\r
  75         { tuckd 4 }\r
  76         { with 1/2 }\r
  77         { with* 2 }\r
  78         { r> 1 }\r
  79         { >r 1 }\r
  80 \r
  81         { bi 1/2 }\r
  82         { tri 1 }\r
  83         { bi* 1/2 }\r
  84         { tri* 1 }\r
  85 \r
  86         { cleave 2 }\r
  87         { spread 2 }\r
  88     } at 0 or ;\r
  89 \r
  90 : vsum ( pairs -- pair ) { 0 0 } [ v+ ] reduce ;\r
  91 \r
  92 GENERIC: noise ( obj -- pair )\r
  93 \r
  94 M: word noise badness 1 2array ;\r
  95 \r
  96 M: wrapper noise wrapped>> noise ;\r
  97 \r
  98 M: let noise body>> noise ;\r
  99 \r
 100 M: wlet noise body>> noise ;\r
 101 \r
 102 M: lambda noise body>> noise ;\r
 103 \r
 104 M: object noise drop { 0 0 } ;\r
 105 \r
 106 M: quotation noise [ noise ] map vsum { 1/4 1/2 } v+ ;\r
 107 \r
 108 M: array noise [ noise ] map vsum ;\r
 109 \r
 110 : noise-factor ( x y -- z ) / 100 * >integer ;\r
 111 \r
 112 : quot-noise-factor ( quot -- n )\r
 113     #! For very short words, noise doesn't count so much\r
 114     #! (so dup foo swap bar isn't penalized as badly).\r
 115     noise first2 {\r
 116         { [ over 4 <= ] [ >r drop 0 r> ] }\r
 117         { [ over 15 >= ] [ >r 2 * r> ] }\r
 118         [ ]\r
 119     } cond\r
 120     {\r
 121         ! short words are easier to read\r
 122         { [ dup 10 <= ] [ >r 2 / r> ] }\r
 123         { [ dup 5 <= ] [ >r 3 / r> ] }\r
 124         ! long words are penalized even more\r
 125         { [ dup 25 >= ] [ >r 2 * r> 20 max ] }\r
 126         { [ dup 20 >= ] [ >r 5/3 * r> ] }\r
 127         { [ dup 15 >= ] [ >r 3/2 * r> ] }\r
 128         [ ]\r
 129     } cond noise-factor ;\r
 130 \r
 131 GENERIC: word-noise-factor ( word -- factor )\r
 132 \r
 133 M: word word-noise-factor\r
 134     def>> quot-noise-factor ;\r
 135 \r
 136 M: lambda-word word-noise-factor\r
 137     "lambda" word-prop quot-noise-factor ;\r
 138 \r
 139 : flatten-generics ( words -- words' )\r
 140     [\r
 141         dup generic? [ "methods" word-prop values ] [ 1array ] if\r
 142     ] map concat ;\r
 143 \r
 144 : noisy-words ( -- alist )\r
 145     all-words flatten-generics\r
 146     [ dup word-noise-factor ] { } map>assoc\r
 147     sort-values reverse ;\r
 148 \r
 149 : noise. ( alist -- )\r
 150     standard-table-style [\r
 151         [\r
 152             [ [ pprint-cell ] [ pprint-cell ] bi* ] with-row\r
 153         ] assoc-each\r
 154     ] tabular-output ;\r
 155 \r
 156 : vocab-noise-factor ( vocab -- factor )\r
 157     words flatten-generics\r
 158     [ word-noise-factor dup 20 < [ drop 0 ] when ] map\r
 159     [ 0 ] [\r
 160         [ [ sum ] [ length 5 max ] bi /i ]\r
 161         [ supremum ]\r
 162         bi +\r
 163     ] if-empty ;\r
 164 \r
 165 : noisy-vocabs ( -- alist )\r
 166     vocabs [ dup vocab-noise-factor ] { } map>assoc\r
 167     sort-values reverse ;\r
 168 \r
 169 : noise-report ( -- )\r
 170     "NOISY WORDS:" print\r
 171     noisy-words 80 head noise.\r
 172     nl\r
 173     "NOISY VOCABS:" print\r
 174     noisy-vocabs 80 head noise. ;\r
 175 \r
 176 MAIN: noise-report\r