extra/reports/noise/noise.factor

   1 ! Copyright (C) 2008 Slava Pestov.\r
   2 ! See http://factorcode.org/license.txt for BSD license.\r
   3 USING: accessors assocs math kernel shuffle generalizations\r
   4 words quotations arrays combinators sequences math.vectors\r
   5 io.styles prettyprint vocabs sorting io generic\r
   6 math.statistics math.order locals.types\r
   7 locals.definitions ;\r
   8 IN: reports.noise\r
   9 \r
  10 : badness ( word -- n )\r
  11     H{\r
  12         { -nrot 5 }\r
  13         { -rot 3 }\r
  14         { bi@ 1 }\r
  15         { 2curry 1 }\r
  16         { 2drop 1 }\r
  17         { 2dup 1 }\r
  18         { 2keep 1 }\r
  19         { 2nip 2 }\r
  20         { 2over 4 }\r
  21         { 2swap 3 }\r
  22         { 3curry 2 }\r
  23         { 3drop 1 }\r
  24         { 3dup 2 }\r
  25         { 3keep 3 }\r
  26         { 4drop 2 }\r
  27         { 4dup 3 }\r
  28         { compose 1/2 }\r
  29         { curry 1/3 }\r
  30         { dip 1 }\r
  31         { 2dip 2 }\r
  32         { drop 1/3 }\r
  33         { dup 1/3 }\r
  34         { if 1/3 }\r
  35         { when 1/4 }\r
  36         { unless 1/4 }\r
  37         { when* 1/3 }\r
  38         { unless* 1/3 }\r
  39         { ?if 1/2 }\r
  40         { cond 1/2 }\r
  41         { case 1/2 }\r
  42         { keep 1 }\r
  43         { napply 2 }\r
  44         { ncurry 3 }\r
  45         { ndip 5 }\r
  46         { ndrop 2 }\r
  47         { ndup 3 }\r
  48         { nip 2 }\r
  49         { nkeep 5 }\r
  50         { npick 6 }\r
  51         { nrot 5 }\r
  52         { ntuck 6 }\r
  53         { nwith 4 }\r
  54         { over 2 }\r
  55         { pick 4 }\r
  56         { rot 3 }\r
  57         { swap 1 }\r
  58         { swapd 3 }\r
  59         { tuck 2 }\r
  60         { with 1/2 }\r
  61 \r
  62         { bi 1/2 }\r
  63         { tri 1 }\r
  64         { bi* 1/2 }\r
  65         { tri* 1 }\r
  66 \r
  67         { cleave 2 }\r
  68         { spread 2 }\r
  69     } at 0 or ;\r
  70 \r
  71 : vsum ( pairs -- pair ) { 0 0 } [ v+ ] reduce ;\r
  72 \r
  73 GENERIC: noise ( obj -- pair )\r
  74 \r
  75 M: word noise badness 1 2array ;\r
  76 \r
  77 M: wrapper noise wrapped>> noise ;\r
  78 \r
  79 M: let noise body>> noise ;\r
  80 \r
  81 M: lambda noise body>> noise ;\r
  82 \r
  83 M: object noise drop { 0 0 } ;\r
  84 \r
  85 M: quotation noise [ noise ] map vsum { 1/4 1/2 } v+ ;\r
  86 \r
  87 M: array noise [ noise ] map vsum ;\r
  88 \r
  89 : noise-factor ( x y -- z ) / 100 * >integer ;\r
  90 \r
  91 : quot-noise-factor ( quot -- n )\r
  92     #! For very short words, noise doesn't count so much\r
  93     #! (so dup foo swap bar isn't penalized as badly).\r
  94     noise first2 {\r
  95         { [ over 4 <= ] [ [ drop 0 ] dip ] }\r
  96         { [ over 15 >= ] [ [ 2 * ] dip ] }\r
  97         [ ]\r
  98     } cond\r
  99     {\r
 100         ! short words are easier to read\r
 101         { [ dup 10 <= ] [ [ 2 / ] dip ] }\r
 102         { [ dup 5 <= ] [ [ 3 / ] dip ] }\r
 103         ! long words are penalized even more\r
 104         { [ dup 25 >= ] [ [ 2 * ] dip 20 max ] }\r
 105         { [ dup 20 >= ] [ [ 5/3 * ] dip ] }\r
 106         { [ dup 15 >= ] [ [ 3/2 * ] dip ] }\r
 107         [ ]\r
 108     } cond noise-factor ;\r
 109 \r
 110 GENERIC: word-noise-factor ( word -- factor )\r
 111 \r
 112 M: word word-noise-factor\r
 113     def>> quot-noise-factor ;\r
 114 \r
 115 M: lambda-word word-noise-factor\r
 116     "lambda" word-prop quot-noise-factor ;\r
 117 \r
 118 : flatten-generics ( words -- words' )\r
 119     [\r
 120         dup generic? [ "methods" word-prop values ] [ 1array ] if\r
 121     ] map concat ;\r
 122 \r
 123 : noisy-words ( -- alist )\r
 124     all-words flatten-generics\r
 125     [ dup word-noise-factor ] { } map>assoc\r
 126     sort-values reverse ;\r
 127 \r
 128 : noise. ( alist -- )\r
 129     standard-table-style [\r
 130         [\r
 131             [ [ pprint-cell ] [ pprint-cell ] bi* ] with-row\r
 132         ] assoc-each\r
 133     ] tabular-output ;\r
 134 \r
 135 : vocab-noise-factor ( vocab -- factor )\r
 136     words flatten-generics\r
 137     [ word-noise-factor dup 20 < [ drop 0 ] when ] map\r
 138     [ 0 ] [\r
 139         [ [ sum ] [ length 5 max ] bi /i ]\r
 140         [ supremum ]\r
 141         bi +\r
 142     ] if-empty ;\r
 143 \r
 144 : noisy-vocabs ( -- alist )\r
 145     vocabs [ dup vocab-noise-factor ] { } map>assoc\r
 146     sort-values reverse ;\r
 147 \r
 148 : noise-report ( -- )\r
 149     "NOISY WORDS:" print\r
 150     noisy-words 80 head noise.\r
 151     nl\r
 152     "NOISY VOCABS:" print\r
 153     noisy-vocabs 80 head noise. ;\r
 154 \r
 155 MAIN: noise-report\r