extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : maybe-push ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* drop ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : nth-index ( n obj seq -- i )
 302     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 303
 304 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 305     [
 306         pick length '[
 307             tuck [ @ over inc-at* drop ] 2dip swap nth-index _ or
 308         ] [ H{ } clone ] 3dip with
 309     ] dip map-as ; inline
 310
 311 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 312     { } progressive-index-by-as ; inline
 313
 314 : progressive-index ( seq1 seq2 -- hash seq' )
 315     [ ] progressive-index-by ; inline
 316
 317 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 318     [ 0 ] dip reduce ; inline
 319
 320 : ?unclip ( seq -- rest/f first/f )
 321     [ f f ] [ unclip ] if-empty ;
 322
 323 : 1reduce ( seq quot: ( prev elt -- next ) -- result )
 324     [ ?unclip ] dip reduce ; inline
 325
 326 <PRIVATE
 327
 328 : change-nth-of-unsafe ( seq i quot -- seq )
 329     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 330
 331 PRIVATE>
 332
 333 : nth-of ( seq n -- elt ) swap nth ; inline
 334 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
 335 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 336 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 337
 338 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 339     swap reduce ; inline
 340
 341 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 342     swap accumulate ; inline
 343
 344 <PRIVATE
 345
 346 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 347     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 348
 349 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 350     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 351
 352 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 353     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 354
 355 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 356     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 357
 358 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 359     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 360
 361 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 362     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 363
 364 PRIVATE>
 365
 366 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 367     pick length over
 368     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 369
 370 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 371     over filter-map-as* ; inline
 372
 373 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 374     [ [ not ] compose ] dip filter-map-as* ; inline
 375
 376 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 377     over reject-map-as* ; inline
 378
 379 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 380     reach length over
 381     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 382
 383 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 384     pick 2filter-map-as* ; inline
 385
 386 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 387     [ [ not ] compose ] dip 2filter-map-as* ; inline
 388
 389 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 390     pick 2reject-map-as* ; inline
 391
 392
 393 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 394     reach length over
 395     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 396
 397 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 398     pick filter-map-as ; inline
 399
 400 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 401     [ [ not ] compose ] 2dip filter-map-as ; inline
 402
 403 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 404     pick reject-map-as ; inline
 405
 406 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 407     5 npick length over
 408     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 409
 410 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 411     reach 2filter-map-as ; inline
 412
 413 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 414     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 415
 416 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 417     pick 2reject-map-as ; inline
 418
 419 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 420     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 421
 422 : (2selector-as) ( quot length exemplar -- selector accum )
 423     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 424
 425 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 426     [
 427         pick [ length ] keep
 428         [ (2selector-as) [ 2each ] dip ] 2curry call
 429     ] dip like ; inline
 430
 431 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 432     pick 2filter-as ; inline
 433
 434 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 435     [ [ not ] compose ] dip 2filter-as ; inline
 436
 437 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 438     pick 2reject-as ; inline
 439
 440 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 441     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 442
 443 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 444     [ 1 0 ? ] compose 2map-sum ; inline
 445
 446 : 3each-from
 447     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 448     [ 3length-operator ] dip -rot each-integer-from ; inline
 449
 450 : 3map-reduce
 451     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 452     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 453
 454 : round-robin ( seq -- newseq )
 455     [ { } ] [
 456         [ longest length <iota> ] keep
 457         [ [ ?nth ] with map ] curry map concat sift
 458     ] if-empty ;
 459
 460 : sift-as ( seq exemplar -- newseq )
 461     [ ] swap filter-as ;
 462
 463 : sift! ( seq -- newseq )
 464     [ ] filter! ;
 465
 466 : harvest-as ( seq exemplar -- newseq )
 467     [ empty? not ] swap filter-as ;
 468
 469 : harvest! ( seq -- newseq )
 470     [ empty? ] reject! ;
 471
 472 : head-as ( seq n exemplar -- seq' )
 473     [ head-slice ] [ like ] bi* ; inline
 474
 475 : head*-as ( seq n exemplar -- seq' )
 476     [ head-slice* ] [ like ] bi* ; inline
 477
 478 : tail-as ( seq n exemplar -- seq' )
 479     [ tail-slice ] [ like ] bi* ; inline
 480
 481 : tail*-as ( seq n exemplar -- seq' )
 482     [ tail-slice* ] [ like ] bi* ; inline
 483
 484 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 485     [ trim-slice ] [ like ] bi* ; inline
 486
 487 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 488     over empty? [ drop ] [
 489         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 490         [ trim ] [ drop ] if
 491     ] if ; inline
 492
 493 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 494     over empty? [ drop ] [
 495         over first-unsafe over call
 496         [ trim-head ] [ drop ] if
 497     ] if ; inline
 498
 499 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 500     over empty? [ drop ] [
 501         over last-unsafe over call
 502         [ trim-tail ] [ drop ] if
 503     ] if ; inline
 504
 505 : unsurround ( newseq seq2 seq3 -- seq1 )
 506     [ ?head drop ] [ ?tail drop ] bi* ;
 507
 508 : >string-list ( seq -- seq' )
 509     [ "\"" 1surround ] map "," join ;
 510
 511 : with-string-lines ( str quot -- str' )
 512     [ string-lines ] dip map "\n" join ; inline
 513
 514 : prepend-lines-with-spaces ( str -- str' )
 515     [ "    " prepend ] with-string-lines ;
 516
 517 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 518     [ find ] 2keep rot [
 519         [ 1 + ] 2dip find-from drop not
 520     ] [ 3drop f ] if ; inline
 521
 522 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 523     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 524
 525 <PRIVATE
 526
 527 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 528     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 529
 530 PRIVATE>
 531
 532 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 533     2sequence-index-iterator each-integer ; inline
 534
 535 : 2map-into ( seq1 seq2 quot into -- )
 536     [ 2length-operator ] dip collect ; inline
 537
 538 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 539     pick [ 2map-into ] keep ; inline
 540
 541 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 542     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 543
 544 TUPLE: evens { seq read-only } ;
 545
 546 C: <evens> evens
 547
 548 M: evens length seq>> length 1 + 2/ ; inline
 549
 550 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 551
 552 M: evens virtual-exemplar seq>> ; inline
 553
 554 INSTANCE: evens virtual-sequence
 555
 556 TUPLE: odds { seq read-only } ;
 557
 558 C: <odds> odds
 559
 560 M: odds length seq>> length 2/ ; inline
 561
 562 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 563
 564 M: odds virtual-exemplar seq>> ; inline
 565
 566 INSTANCE: odds virtual-sequence
 567
 568 : until-empty ( seq quot -- )
 569     [ dup empty? ] swap until drop ; inline
 570
 571 <PRIVATE
 572
 573 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 574     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 575
 576 PRIVATE>
 577
 578 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 579     over length <vector> [
 580         [ push-index-if ] 2curry each-index
 581     ] keep ; inline
 582
 583 : arg-sort ( seq -- indices )
 584     zip-index sort-keys values ;
 585
 586 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 587 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 588 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 589 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 590 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 591 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 592
 593 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 594 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 595 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 596 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 597 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 598 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 599
 600 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 601     [ ] swap produce-as nip ; inline
 602
 603 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 604     { } loop>sequence** ; inline
 605
 606 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 607     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 608
 609 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 610     { } loop>sequence* ; inline
 611
 612 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 613     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 614
 615 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 616     { } loop>sequence ; inline
 617
 618 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 619     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 620
 621 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 622     { } zero-loop>sequence ; inline
 623
 624 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 625     pick heap-empty?
 626     [ 3drop f f ]
 627     [
 628         [ [ heap-peek ] 2dip drop 2keep ]
 629         [
 630             nip ! ( pop? value key heap quot2 )
 631             5roll [
 632                 swap heap-pop* call( value key -- obj/f ) t
 633             ] [
 634                 4drop f f
 635             ] if
 636         ] 3bi
 637     ] if ; inline
 638
 639 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 640     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 641
 642 : heap>pairs ( heap -- pairs )
 643     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 644
 645 : map-zip-swap ( quot: ( x -- y ) -- alist )
 646     '[ _ keep ] map>alist ; inline
 647
 648 : ?heap-pop-value>array ( heap -- array )
 649     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 650
 651 <PRIVATE
 652
 653 : (reverse) ( seq -- newseq )
 654     dup [ length ] keep new-sequence
 655     [ 0 swap copy-unsafe ] keep reverse! ;
 656
 657 PRIVATE>
 658
 659 : reverse-as ( seq exemplar -- newseq )
 660     [ (reverse) ] [ like ] bi* ;
 661
 662 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 663     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 664
 665 : insert-nth! ( elt n seq -- )
 666     [ length ] keep ensure swap pick (a..b]
 667     over '[ [ 1 + ] keep _ move-unsafe ] each
 668     set-nth-unsafe ;
 669
 670 : set-nths ( value indices seq -- )
 671     swapd '[ _ swap _ set-nth ] each ; inline
 672
 673 : set-nths-unsafe ( value indices seq -- )
 674     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 675
 676 <PRIVATE
 677
 678 : (map-find-index) ( seq quot find-quot -- result i elt )
 679     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 680     [ [ [ drop f ] unless ] keep ] dip ; inline
 681
 682 PRIVATE>
 683
 684 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 685     [ find-index ] (map-find-index) ; inline
 686
 687 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 688
 689 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 690
 691 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 692
 693 <PRIVATE
 694
 695 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 696 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 697 : set-length-of ( seq n -- seq ) over set-length ; inline
 698
 699 : move-unsafe-of ( seq to from -- seq )
 700     2dup = [
 701         2drop
 702     ] [
 703         overd nth-unsafe-of set-nth-unsafe-of
 704     ] if ; inline
 705
 706 : move-backward-of ( seq shift from to -- seq )
 707     2dup = [
 708         3drop
 709     ] [
 710         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 711     ] if ;
 712
 713 : open-slice-of ( seq shift from -- seq )
 714     over 0 = [
 715         2drop
 716     ] [
 717         [ ] [ drop [ length ] dip + ] 3bi
 718         [ pick length [ over - ] dip move-backward-of ] dip
 719         set-length-of
 720     ] if ;
 721
 722 PRIVATE>
 723
 724 ERROR: slice-error-of from to seq ;
 725
 726 : check-slice-of ( seq from to -- seq from to )
 727     over 0 < [ slice-error-of ] when
 728     dup reach length > [ slice-error-of ] when
 729     2dup > [ slice-error-of ] when ; inline
 730
 731 : delete-slice-of ( seq from to -- seq )
 732     check-slice-of over [ - ] dip open-slice-of ;
 733
 734 : remove-nth-of ( seq n -- seq' )
 735     [ dup 1 + rot snip-slice ] keepd append-as ;
 736
 737 : remove-nth-of* ( seq n -- nth seq' )
 738     [ nth-of ] [ remove-nth-of ] 2bi ;
 739
 740 : remove-nth-of! ( seq n -- seq )
 741     dup 1 + delete-slice-of ;
 742
 743 : remove-nth-of*! ( seq n -- nth seq )
 744     [ nth-of ] [ dup 1 + delete-slice-of ] 2bi ;
 745
 746 : snip-of ( seq from to -- head tail )
 747     [ head ] [ tail ] bi-curry* bi ; inline
 748
 749 : snip-slice-of ( seq from to -- head tail )
 750     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 751
 752 : index* ( seq obj -- n ) [ = ] curry find drop ;
 753
 754 : index-from* ( i seq obj -- n )
 755     [ = ] curry find-from drop ;
 756
 757 : last-index* ( seq obj -- n )
 758     [ = ] curry find-last drop ;
 759
 760 : last-index-from* ( i seq obj -- n )
 761     [ = ] curry find-last-from drop ;
 762
 763 : indices* ( seq obj -- indices )
 764     [ = ] curry [ swap ] prepose V{ } clone [
 765         [ push ] curry [ [ drop ] if ] curry compose each-index
 766     ] keep ;
 767
 768 : remove-first ( obj seq -- seq' )
 769     [ index ] keep over [ remove-nth ] [ nip ] if ;
 770
 771 : remove-first-of ( seq obj -- seq' )
 772     dupd index* [ remove-nth-of ] when* ;
 773
 774 : remove-first! ( obj seq -- seq )
 775     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 776
 777 : remove-last ( obj seq -- seq' )
 778     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 779
 780 : remove-last! ( obj seq -- seq )
 781     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 782
 783 : member-of? ( seq elt -- ? )
 784     [ = ] curry any? ;
 785
 786 : member-eq-of? ( seq elt -- ? )
 787     [ eq? ] curry any? ;
 788
 789 : remove-of ( seq elt -- newseq )
 790     [ = ] curry reject ;
 791
 792 : remove-eq-of ( seq elt -- newseq )
 793     [ eq? ] curry reject ;
 794
 795 : ?first2 ( seq -- first/f second/f )
 796     dup length {
 797         { 0 [ drop f f ] }
 798         { 1 [ first-unsafe f ] }
 799         [ drop first2-unsafe ]
 800     } case ;
 801
 802 : ?first3 ( seq -- first/f second/f third/f )
 803     dup length {
 804         { 0 [ drop f f f ] }
 805         { 1 [ first-unsafe f f ] }
 806         { 2 [ first2-unsafe f ] }
 807         [ drop first3-unsafe ]
 808     } case ;
 809
 810 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 811     dup length {
 812         { 0 [ drop f f f f ] }
 813         { 1 [ first-unsafe f f f ] }
 814         { 2 [ first2-unsafe f f ] }
 815         { 3 [ first3-unsafe f ] }
 816         [ drop first4-unsafe ]
 817     } case ;
 818
 819 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 820     [ find drop ] keepd swap
 821     [ cut ] [ f over like ] if* ; inline
 822
 823 : nth* ( n seq -- elt )
 824     [ length 1 - swap - ] [ nth ] bi ; inline
 825
 826 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 827     -rot sequence-index-operator each-integer-from ; inline
 828
 829 <PRIVATE
 830
 831 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 832     [
 833         [ keep swap ] curry [ dip ] curry
 834         [ [ first 0 ] dip call ] 2keep
 835         [ 2curry 3dip 5 npick pick ] curry
 836     ] [
 837         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 838     ] bi* compose 1 each-index-from nip swap ; inline
 839
 840 PRIVATE>
 841
 842 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 843     [ after? ] select-by* ; inline
 844
 845 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 846     [ before? ] select-by* ; inline
 847
 848 : arg-max ( seq -- n )
 849     [ ] supremum-by* drop ;
 850
 851 : arg-min ( seq -- n )
 852     [ ] infimum-by* drop ;
 853
 854 : ?supremum ( seq/f -- elt/f )
 855     [ f ] [
 856         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 857     ] if-empty ;
 858
 859 : ?infimum ( seq/f -- elt/f )
 860     [ f ] [
 861         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 862     ] if-empty ;
 863
 864 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 865     [ min ] map-reduce ; inline
 866
 867 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 868     [ max ] map-reduce ; inline
 869
 870 : change-last ( seq quot -- )
 871     [ index-of-last ] [ change-nth ] bi* ; inline
 872
 873 : change-last-unsafe ( seq quot -- )
 874     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 875
 876 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 877     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 878
 879 : percent-of ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 880     over length 0 =
 881     [ 2drop 0 ]
 882     [ over [ count ] [ length ] bi* / ] if ; inline
 883
 884 : sequence-index-operator-last ( n seq quot -- n quot' )
 885     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 886
 887 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 888     '[
 889         _ [ sequence-index-operator-last find-last-integer ] keepd
 890         index/element
 891     ] bounds-check-call ; inline
 892
 893 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 894     [ index-of-last ] dip find-last-index-from ; inline
 895
 896 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 897     [ find-last-index ] (map-find-index) ; inline
 898
 899 :: (start-all) ( seq subseq increment -- indices )
 900     0
 901     [ seq subseq subseq-index-from dup ]
 902     [ [ increment + ] keep ] produce nip ;
 903
 904 : start-all ( seq subseq -- indices )
 905     dup length (start-all) ; inline
 906
 907 : start-all* ( seq subseq -- indices )
 908     1 (start-all) ; inline
 909
 910 : count-subseq ( seq subseq -- n )
 911     start-all length ; inline
 912
 913 : count-subseq* ( seq subseq -- n )
 914     start-all* length ; inline
 915
 916 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 917     '[ _ 2keep 2array swap ] assoc-map ; inline
 918
 919 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 920     [ '[ @ not ] find drop ] keepd swap
 921     [ dup length ] unless* head-slice ; inline
 922
 923 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 924     [ '[ @ not ] find drop ] keepd swap
 925     [ dup length ] unless* tail-slice ; inline
 926
 927 : count-head ( seq quot -- n )
 928     [ not ] compose [ find drop ] keepd length or ; inline
 929
 930 : count-tail ( seq quot -- n )
 931     [ not ] compose [ find-last drop ] keepd
 932     length swap [ - 1 - ] when* ; inline
 933
 934 :: shorten* ( vector n -- seq )
 935     vector n tail
 936     n vector shorten ;
 937
 938 :: interleaved-as ( seq glue exemplar -- newseq )
 939     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 940     seq [ 2 * newseq set-nth-unsafe ] each-index
 941     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 942     newseq ;
 943
 944 : interleaved ( seq glue -- newseq )
 945     over interleaved-as ;
 946
 947 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 948     [ dup ] compose over [ length ] keep new-resizable
 949     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 950
 951 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 952     2pick < [
 953         [ nipd call ] 4keep
 954         3 7 0 nrotated
 955         [ [ 3drop ] 2dip rot ]
 956         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 957     ] [
 958         4drop f f f
 959     ] if ; inline recursive
 960
 961 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 962     [ 0 ] 3dip
 963     [ [ length check-length ] keep ] 2dip
 964     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 965
 966 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 967 ! Kadane's algorithm O(n) largest sum in subarray
 968 : max-subarray-sum ( seq -- sum )
 969     [ -1/0. 0 ] dip
 970     [ [ + ] keep max [ max ] keep ] each drop ;
 971
 972 TUPLE: step-slice
 973     { from integer read-only initial: 0 }
 974     { to integer read-only initial: 0 }
 975     { seq read-only }
 976     { step integer read-only } ;
 977
 978 :: <step-slice> ( from/f to/f step seq -- step-slice )
 979     step zero? [ "can't be zero" throw ] when
 980     seq length :> len
 981     step 0 > [
 982         from/f [ 0 ] unless*
 983         to/f [ len ] unless*
 984     ] [
 985         from/f [ len ] unless*
 986         to/f [ 0 ] unless*
 987     ] if
 988     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 989     ! FIXME: make this work with steps
 990     seq dup slice? [ collapse-slice ] when
 991     step step-slice boa ;
 992
 993 M: step-slice virtual-exemplar seq>> ; inline
 994
 995 M: step-slice virtual@
 996     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 997
 998 M: step-slice length
 999     [ to>> ] [ from>> - ] [ step>> ] tri
1000     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
1001     zero? [ 1 + ] unless ; inline
1002
1003 INSTANCE: step-slice virtual-sequence
1004
1005 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
1006     '[
1007         _ keep swap _ with each
1008     ] each ; inline
1009
1010 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
1011     [ 2over [ length ] bi@ * ] dip
1012     [
1013         new-resizable
1014         [ [ maybe-push ] curry compose 2nested-each* ] keep
1015     ] keep like ; inline
1016
1017 : 2nested-filter* ( seq1 seq-quot quot -- seq )
1018     pick 2nested-filter-as* ; inline
1019
1020 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
1021     [ 2over [ length ] bi@ * ] dip
1022     [
1023         new-resizable
1024         [ [ push ] curry compose 2nested-each* ] keep
1025     ] keep like ; inline
1026
1027 : 2nested-map* ( seq1 seq-quot quot -- seq )
1028     pick 2nested-map-as* ; inline
1029
1030
1031 : 2nested-each ( seq1 seq2 quot -- )
1032     swapd '[
1033         swap _ with each
1034     ] with each ; inline
1035
1036 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1037     [ 2over [ length ] bi@ * ] dip
1038     [
1039         new-resizable
1040         [ [ maybe-push ] curry compose 2nested-each ] keep
1041     ] keep like ; inline
1042
1043 : 2nested-filter ( seq1 seq2 quot -- seq )
1044     pick 2nested-filter-as ; inline
1045
1046 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1047     [ 2over [ length ] bi@ * ] dip
1048     [
1049         new-resizable
1050         [ [ push ] curry compose 2nested-each ] keep
1051     ] keep like ; inline
1052
1053 : 2nested-map ( seq1 seq2 quot -- seq )
1054     pick 2nested-map-as ; inline
1055
1056 : 3nested-each ( seq1 seq2 seq3 quot -- )
1057     [ spin ] dip '[
1058         -rot [
1059             swap _ with with each
1060         ] with with each
1061     ] with with each ; inline
1062
1063 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1064     [ 3 nover [ length ] tri@ * * ] dip
1065     [
1066         new-resizable
1067         [ [ maybe-push ] curry compose 3nested-each ] keep
1068     ] keep like ; inline
1069
1070 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1071     reach 3nested-filter-as ; inline
1072
1073 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1074     [ 3 nover [ length ] tri@ * * ] dip
1075     [
1076         new-resizable
1077         [ [ push ] curry compose 3nested-each ] keep
1078     ] keep like ; inline
1079
1080 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1081     reach 3nested-map-as ; inline
1082
1083 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1084 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1085 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1086 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1087 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1088 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1089
1090 : prev-identity ( i seq -- identity i seq )
1091     2dup ??prev [ drop 0 ] unless -rot ; inline
1092
1093 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1094     '[ [ swap @ ] keep ]
1095     length-operator each-integer-from drop ; inline
1096
1097 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1098     [ prev-identity ] dip each-prior-identity-from ; inline
1099
1100 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1101     0 -rot each-prior-from ; inline
1102
1103 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1104     [
1105         '[ [ swap @ ] keep swap ] length-operator
1106     ] dip map-integers-from-as nip ; inline
1107
1108 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1109     [ 0 ] 3dip map-prior-identity-from-as ; inline
1110
1111 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1112     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1113
1114 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1115     0 -roll map-prior-from-as ; inline
1116
1117 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1118     over map-prior-from-as ; inline
1119
1120 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1121     over map-prior-as ; inline
1122
1123 TUPLE: virtual-zip-index seq ;
1124
1125 C: <zip-index> virtual-zip-index
1126
1127 M: virtual-zip-index length seq>> length ; inline
1128
1129 M: virtual-zip-index nth-unsafe
1130     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1131
1132 INSTANCE: virtual-zip-index immutable-sequence
1133
1134 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
1135     [ call ] dip swap [ push ] [ 2drop ] if ; inline
1136
1137 : fry-map-as ( seq quot exemplar -- newseq )
1138     [ 2drop length ]
1139     [ overd new-sequence-like dup ]
1140     [ 2nip ] 3tri
1141     '[ [ [ _ nth-unsafe @ ] [ _ set-nth-unsafe ] bi ] each-integer _ _ like ] call ;