extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* drop ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : nth-index ( n obj seq -- i )
 302     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 303
 304 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 305     [
 306         pick length '[
 307             tuck [ @ over inc-at* drop ] 2dip swap nth-index _ or
 308         ] [ H{ } clone ] 3dip with
 309     ] dip map-as ; inline
 310
 311 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 312     { } progressive-index-by-as ; inline
 313
 314 : progressive-index ( seq1 seq2 -- hash seq' )
 315     [ ] progressive-index-by ; inline
 316
 317 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 318     [ 0 ] dip reduce ; inline
 319
 320 : ?unclip ( seq -- rest/f first/f )
 321     [ f f ] [ unclip ] if-empty ;
 322
 323 : 1reduce ( seq quot: ( prev elt -- next ) -- result )
 324     [ ?unclip ] dip reduce ; inline
 325
 326 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 327     swap reduce ; inline
 328
 329 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 330     swap accumulate ; inline
 331
 332 <PRIVATE
 333
 334 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 335     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 336
 337 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 338     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 339
 340 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 341     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 342
 343 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 344     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 345
 346 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 347     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 348
 349 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 350     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 351
 352 PRIVATE>
 353
 354 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 355     pick length over
 356     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 357
 358 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 359     over filter-map-as* ; inline
 360
 361 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 362     [ [ not ] compose ] dip filter-map-as* ; inline
 363
 364 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 365     over reject-map-as* ; inline
 366
 367 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 368     reach length over
 369     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 370
 371 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 372     pick 2filter-map-as* ; inline
 373
 374 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 375     [ [ not ] compose ] dip 2filter-map-as* ; inline
 376
 377 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 378     pick 2reject-map-as* ; inline
 379
 380
 381 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 382     reach length over
 383     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 384
 385 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 386     pick filter-map-as ; inline
 387
 388 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 389     [ [ not ] compose ] 2dip filter-map-as ; inline
 390
 391 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 392     pick reject-map-as ; inline
 393
 394 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 395     5 npick length over
 396     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 397
 398 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 399     reach 2filter-map-as ; inline
 400
 401 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 402     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 403
 404 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 405     pick 2reject-map-as ; inline
 406
 407 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 408     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 409
 410 : (2selector-as) ( quot length exemplar -- selector accum )
 411     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 412
 413 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 414     [
 415         pick [ length ] keep
 416         [ (2selector-as) [ 2each ] dip ] 2curry call
 417     ] dip like ; inline
 418
 419 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 420     pick 2filter-as ; inline
 421
 422 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 423     [ [ not ] compose ] dip 2filter-as ; inline
 424
 425 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 426     pick 2reject-as ; inline
 427
 428 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 429     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 430
 431 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 432     [ 1 0 ? ] compose 2map-sum ; inline
 433
 434 : 3each-from
 435     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 436     [ 3length-operator ] dip -rot each-integer-from ; inline
 437
 438 : 3map-reduce
 439     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 440     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 441
 442 : round-robin ( seq -- newseq )
 443     [ { } ] [
 444         [ longest length <iota> ] keep
 445         [ [ ?nth ] with map ] curry map concat sift
 446     ] if-empty ;
 447
 448 : sift-as ( seq exemplar -- newseq )
 449     [ ] swap filter-as ;
 450
 451 : sift! ( seq -- newseq )
 452     [ ] filter! ;
 453
 454 : harvest-as ( seq exemplar -- newseq )
 455     [ empty? not ] swap filter-as ;
 456
 457 : harvest! ( seq -- newseq )
 458     [ empty? ] reject! ;
 459
 460 : head-as ( seq n exemplar -- seq' )
 461     [ head-slice ] [ like ] bi* ; inline
 462
 463 : head*-as ( seq n exemplar -- seq' )
 464     [ head-slice* ] [ like ] bi* ; inline
 465
 466 : tail-as ( seq n exemplar -- seq' )
 467     [ tail-slice ] [ like ] bi* ; inline
 468
 469 : tail*-as ( seq n exemplar -- seq' )
 470     [ tail-slice* ] [ like ] bi* ; inline
 471
 472 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 473     [ trim-slice ] [ like ] bi* ; inline
 474
 475 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 476     over empty? [ drop ] [
 477         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 478         [ trim ] [ drop ] if
 479     ] if ; inline
 480
 481 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 482     over empty? [ drop ] [
 483         over first-unsafe over call
 484         [ trim-head ] [ drop ] if
 485     ] if ; inline
 486
 487 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 488     over empty? [ drop ] [
 489         over last-unsafe over call
 490         [ trim-tail ] [ drop ] if
 491     ] if ; inline
 492
 493 : unsurround ( newseq seq2 seq3 -- seq1 )
 494     [ ?head drop ] [ ?tail drop ] bi* ;
 495
 496 : >string-list ( seq -- seq' )
 497     [ "\"" 1surround ] map "," join ;
 498
 499 : with-string-lines ( str quot -- str' )
 500     [ string-lines ] dip map "\n" join ; inline
 501
 502 : prepend-lines-with-spaces ( str -- str' )
 503     [ "    " prepend ] with-string-lines ;
 504
 505 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 506     [ find ] 2keep rot [
 507         [ 1 + ] 2dip find-from drop not
 508     ] [ 3drop f ] if ; inline
 509
 510 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 511     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 512
 513 <PRIVATE
 514
 515 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 516     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 517
 518 PRIVATE>
 519
 520 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 521     2sequence-index-iterator each-integer ; inline
 522
 523 : 2map-into ( seq1 seq2 quot into -- )
 524     [ 2length-operator ] dip collect ; inline
 525
 526 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 527     pick [ 2map-into ] keep ; inline
 528
 529 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 530     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 531
 532 TUPLE: evens { seq read-only } ;
 533
 534 C: <evens> evens
 535
 536 M: evens length seq>> length 1 + 2/ ; inline
 537
 538 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 539
 540 M: evens virtual-exemplar seq>> ; inline
 541
 542 INSTANCE: evens virtual-sequence
 543
 544 TUPLE: odds { seq read-only } ;
 545
 546 C: <odds> odds
 547
 548 M: odds length seq>> length 2/ ; inline
 549
 550 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 551
 552 M: odds virtual-exemplar seq>> ; inline
 553
 554 INSTANCE: odds virtual-sequence
 555
 556 : until-empty ( seq quot -- )
 557     [ dup empty? ] swap until drop ; inline
 558
 559 <PRIVATE
 560
 561 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 562     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 563
 564 PRIVATE>
 565
 566 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 567     over length <vector> [
 568         [ push-index-if ] 2curry each-index
 569     ] keep ; inline
 570
 571 : arg-sort ( seq -- indices )
 572     zip-index sort-keys values ;
 573
 574 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 575 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 576 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 577 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 578 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 579 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 580
 581 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 582 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 583 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 584 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 585 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 586 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 587
 588 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 589     [ ] swap produce-as nip ; inline
 590
 591 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 592     { } loop>sequence** ; inline
 593
 594 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 595     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 596
 597 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 598     { } loop>sequence* ; inline
 599
 600 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 601     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 602
 603 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 604     { } loop>sequence ; inline
 605
 606 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 607     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 608
 609 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 610     { } zero-loop>sequence ; inline
 611
 612 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 613     pick heap-empty?
 614     [ 3drop f f ]
 615     [
 616         [ [ heap-peek ] 2dip drop 2keep ]
 617         [
 618             nip ! ( pop? value key heap quot2 )
 619             5roll [
 620                 swap heap-pop* call( value key -- obj/f ) t
 621             ] [
 622                 4drop f f
 623             ] if
 624         ] 3bi
 625     ] if ; inline
 626
 627 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 628     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 629
 630 : heap>pairs ( heap -- pairs )
 631     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 632
 633 : map-zip-swap ( quot: ( x -- y ) -- alist )
 634     '[ _ keep ] map>alist ; inline
 635
 636 : ?heap-pop-value>array ( heap -- array )
 637     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 638
 639 <PRIVATE
 640
 641 : (reverse) ( seq -- newseq )
 642     dup [ length ] keep new-sequence
 643     [ 0 swap copy-unsafe ] keep reverse! ;
 644
 645 PRIVATE>
 646
 647 : reverse-as ( seq exemplar -- newseq )
 648     [ (reverse) ] [ like ] bi* ;
 649
 650 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 651     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 652
 653 : insert-nth! ( elt n seq -- )
 654     [ length ] keep ensure swap pick (a..b]
 655     over '[ [ 1 + ] keep _ move-unsafe ] each
 656     set-nth-unsafe ;
 657
 658 : set-nths ( value indices seq -- )
 659     swapd '[ _ swap _ set-nth ] each ; inline
 660
 661 : set-nths-unsafe ( value indices seq -- )
 662     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 663
 664 <PRIVATE
 665
 666 : (map-find-index) ( seq quot find-quot -- result i elt )
 667     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 668     [ [ [ drop f ] unless ] keep ] dip ; inline
 669
 670 PRIVATE>
 671
 672 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 673     [ find-index ] (map-find-index) ; inline
 674
 675 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 676
 677 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 678
 679 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 680
 681 <PRIVATE
 682
 683 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 684 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 685 : set-length-of ( seq n -- seq ) over set-length ; inline
 686
 687 : move-unsafe-of ( seq to from -- seq )
 688     2dup = [
 689         2drop
 690     ] [
 691         overd nth-unsafe-of set-nth-unsafe-of
 692     ] if ; inline
 693
 694 : move-backward-of ( seq shift from to -- seq )
 695     2dup = [
 696         3drop
 697     ] [
 698         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 699     ] if ;
 700
 701 : open-slice-of ( seq shift from -- seq )
 702     over 0 = [
 703         2drop
 704     ] [
 705         [ ] [ drop [ length ] dip + ] 3bi
 706         [ pick length [ over - ] dip move-backward-of ] dip
 707         set-length-of
 708     ] if ;
 709
 710 PRIVATE>
 711
 712 ERROR: slice-error-of from to seq ;
 713
 714 : check-slice-of ( seq from to -- seq from to )
 715     over 0 < [ slice-error-of ] when
 716     dup reach length > [ slice-error-of ] when
 717     2dup > [ slice-error-of ] when ; inline
 718
 719 : delete-slice-of ( seq from to -- seq )
 720     check-slice-of over [ - ] dip open-slice-of ;
 721
 722 : remove-nth-of ( seq n -- seq' )
 723     [ dup 1 + rot snip-slice ] keepd append-as ;
 724
 725 : remove-nth-of! ( seq n -- seq )
 726     dup 1 + delete-slice-of ;
 727
 728 : snip-of ( seq from to -- head tail )
 729     [ head ] [ tail ] bi-curry* bi ; inline
 730
 731 : snip-slice-of ( seq from to -- head tail )
 732     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 733
 734 : index* ( seq obj -- n ) [ = ] curry find drop ;
 735
 736 : index-from* ( i seq obj -- n )
 737     [ = ] curry find-from drop ;
 738
 739 : last-index* ( seq obj -- n )
 740     [ = ] curry find-last drop ;
 741
 742 : last-index-from* ( i seq obj -- n )
 743     [ = ] curry find-last-from drop ;
 744
 745 : indices* ( seq obj -- indices )
 746     [ = ] curry [ swap ] prepose V{ } clone [
 747         [ push ] curry [ [ drop ] if ] curry compose each-index
 748     ] keep ;
 749
 750 : remove-first ( obj seq -- seq' )
 751     [ index ] keep over [ remove-nth ] [ nip ] if ;
 752
 753 : remove-first-of ( seq obj -- seq' )
 754     dupd index* [ remove-nth-of ] when* ;
 755
 756 : remove-first! ( obj seq -- seq )
 757     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 758
 759 : remove-last ( obj seq -- seq' )
 760     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 761
 762 : remove-last! ( obj seq -- seq )
 763     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 764
 765 : member-of? ( seq elt -- ? )
 766     [ = ] curry any? ;
 767
 768 : member-eq-of? ( seq elt -- ? )
 769     [ eq? ] curry any? ;
 770
 771 : remove-of ( seq elt -- newseq )
 772     [ = ] curry reject ;
 773
 774 : remove-eq-of ( seq elt -- newseq )
 775     [ eq? ] curry reject ;
 776
 777 : ?first2 ( seq -- first/f second/f )
 778     dup length {
 779         { 0 [ drop f f ] }
 780         { 1 [ first-unsafe f ] }
 781         [ drop first2-unsafe ]
 782     } case ;
 783
 784 : ?first3 ( seq -- first/f second/f third/f )
 785     dup length {
 786         { 0 [ drop f f f ] }
 787         { 1 [ first-unsafe f f ] }
 788         { 2 [ first2-unsafe f ] }
 789         [ drop first3-unsafe ]
 790     } case ;
 791
 792 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 793     dup length {
 794         { 0 [ drop f f f f ] }
 795         { 1 [ first-unsafe f f f ] }
 796         { 2 [ first2-unsafe f f ] }
 797         { 3 [ first3-unsafe f ] }
 798         [ drop first4-unsafe ]
 799     } case ;
 800
 801 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 802     [ find drop ] keepd swap
 803     [ cut ] [ f over like ] if* ; inline
 804
 805 : nth* ( n seq -- elt )
 806     [ length 1 - swap - ] [ nth ] bi ; inline
 807
 808 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 809     -rot sequence-index-operator each-integer-from ; inline
 810
 811 <PRIVATE
 812
 813 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 814     [
 815         [ keep swap ] curry [ dip ] curry
 816         [ [ first 0 ] dip call ] 2keep
 817         [ 2curry 3dip 5 npick pick ] curry
 818     ] [
 819         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 820     ] bi* compose 1 each-index-from nip swap ; inline
 821
 822 PRIVATE>
 823
 824 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 825     [ after? ] select-by* ; inline
 826
 827 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 828     [ before? ] select-by* ; inline
 829
 830 : arg-max ( seq -- n )
 831     [ ] supremum-by* drop ;
 832
 833 : arg-min ( seq -- n )
 834     [ ] infimum-by* drop ;
 835
 836 : ?supremum ( seq/f -- elt/f )
 837     [ f ] [
 838         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 839     ] if-empty ;
 840
 841 : ?infimum ( seq/f -- elt/f )
 842     [ f ] [
 843         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 844     ] if-empty ;
 845
 846 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 847     [ min ] map-reduce ; inline
 848
 849 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 850     [ max ] map-reduce ; inline
 851
 852 : change-last ( seq quot -- )
 853     [ index-of-last ] [ change-nth ] bi* ; inline
 854
 855 : change-last-unsafe ( seq quot -- )
 856     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 857
 858 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 859     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 860
 861 : percent-of ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 862     over length 0 =
 863     [ 2drop 0 ]
 864     [ over [ count ] [ length ] bi* / ] if ; inline
 865
 866 : sequence-index-operator-last ( n seq quot -- n quot' )
 867     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 868
 869 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 870     '[
 871         _ [ sequence-index-operator-last find-last-integer ] keepd
 872         index/element
 873     ] bounds-check-call ; inline
 874
 875 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 876     [ index-of-last ] dip find-last-index-from ; inline
 877
 878 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 879     [ find-last-index ] (map-find-index) ; inline
 880
 881 :: (start-all) ( seq subseq increment -- indices )
 882     0
 883     [ seq subseq subseq-index-from dup ]
 884     [ [ increment + ] keep ] produce nip ;
 885
 886 : start-all ( seq subseq -- indices )
 887     dup length (start-all) ; inline
 888
 889 : start-all* ( seq subseq -- indices )
 890     1 (start-all) ; inline
 891
 892 : count-subseq ( seq subseq -- n )
 893     start-all length ; inline
 894
 895 : count-subseq* ( seq subseq -- n )
 896     start-all* length ; inline
 897
 898 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 899     '[ _ 2keep 2array swap ] assoc-map ; inline
 900
 901 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 902     [ '[ @ not ] find drop ] keepd swap
 903     [ dup length ] unless* head-slice ; inline
 904
 905 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 906     [ '[ @ not ] find drop ] keepd swap
 907     [ dup length ] unless* tail-slice ; inline
 908
 909 : count-head ( seq quot -- n )
 910     [ not ] compose [ find drop ] keepd length or ; inline
 911
 912 : count-tail ( seq quot -- n )
 913     [ not ] compose [ find-last drop ] keepd
 914     length swap [ - 1 - ] when* ; inline
 915
 916 :: shorten* ( vector n -- seq )
 917     vector n tail
 918     n vector shorten ;
 919
 920 :: interleaved-as ( seq glue exemplar -- newseq )
 921     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 922     seq [ 2 * newseq set-nth-unsafe ] each-index
 923     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 924     newseq ;
 925
 926 : interleaved ( seq glue -- newseq )
 927     over interleaved-as ;
 928
 929 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 930     [ dup ] compose over [ length ] keep new-resizable
 931     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 932
 933 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 934     2pick < [
 935         [ nipd call ] 4keep
 936         3 7 0 nrotated
 937         [ [ 3drop ] 2dip rot ]
 938         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 939     ] [
 940         4drop f f f
 941     ] if ; inline recursive
 942
 943 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 944     [ 0 ] 3dip
 945     [ [ length check-length ] keep ] 2dip
 946     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 947
 948 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 949 ! Kadane's algorithm O(n) largest sum in subarray
 950 : max-subarray-sum ( seq -- sum )
 951     [ -1/0. 0 ] dip
 952     [ [ + ] keep max [ max ] keep ] each drop ;
 953
 954 TUPLE: step-slice
 955     { from integer read-only initial: 0 }
 956     { to integer read-only initial: 0 }
 957     { seq read-only }
 958     { step integer read-only } ;
 959
 960 :: <step-slice> ( from/f to/f step seq -- step-slice )
 961     step zero? [ "can't be zero" throw ] when
 962     seq length :> len
 963     step 0 > [
 964         from/f [ 0 ] unless*
 965         to/f [ len ] unless*
 966     ] [
 967         from/f [ len ] unless*
 968         to/f [ 0 ] unless*
 969     ] if
 970     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 971     ! FIXME: make this work with steps
 972     seq dup slice? [ collapse-slice ] when
 973     step step-slice boa ;
 974
 975 M: step-slice virtual-exemplar seq>> ; inline
 976
 977 M: step-slice virtual@
 978     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 979
 980 M: step-slice length
 981     [ to>> ] [ from>> - ] [ step>> ] tri
 982     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 983     zero? [ 1 + ] unless ; inline
 984
 985 INSTANCE: step-slice virtual-sequence
 986
 987 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 988     '[
 989         _ keep swap _ with each
 990     ] each ; inline
 991
 992 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 993     [ 2over [ length ] bi@ * ] dip
 994     [
 995         new-resizable
 996         [ [ push? ] curry compose 2nested-each* ] keep
 997     ] keep like ; inline
 998
 999 : 2nested-filter* ( seq1 seq-quot quot -- seq )
1000     pick 2nested-filter-as* ; inline
1001
1002 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
1003     [ 2over [ length ] bi@ * ] dip
1004     [
1005         new-resizable
1006         [ [ push ] curry compose 2nested-each* ] keep
1007     ] keep like ; inline
1008
1009 : 2nested-map* ( seq1 seq-quot quot -- seq )
1010     pick 2nested-map-as* ; inline
1011
1012
1013 : 2nested-each ( seq1 seq2 quot -- )
1014     swapd '[
1015         swap _ with each
1016     ] with each ; inline
1017
1018 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1019     [ 2over [ length ] bi@ * ] dip
1020     [
1021         new-resizable
1022         [ [ push? ] curry compose 2nested-each ] keep
1023     ] keep like ; inline
1024
1025 : 2nested-filter ( seq1 seq2 quot -- seq )
1026     pick 2nested-filter-as ; inline
1027
1028 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1029     [ 2over [ length ] bi@ * ] dip
1030     [
1031         new-resizable
1032         [ [ push ] curry compose 2nested-each ] keep
1033     ] keep like ; inline
1034
1035 : 2nested-map ( seq1 seq2 quot -- seq )
1036     pick 2nested-map-as ; inline
1037
1038 : 3nested-each ( seq1 seq2 seq3 quot -- )
1039     [ spin ] dip '[
1040         -rot [
1041             swap _ with with each
1042         ] with with each
1043     ] with with each ; inline
1044
1045 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1046     [ 3 nover [ length ] tri@ * * ] dip
1047     [
1048         new-resizable
1049         [ [ push? ] curry compose 3nested-each ] keep
1050     ] keep like ; inline
1051
1052 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1053     reach 3nested-filter-as ; inline
1054
1055 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1056     [ 3 nover [ length ] tri@ * * ] dip
1057     [
1058         new-resizable
1059         [ [ push ] curry compose 3nested-each ] keep
1060     ] keep like ; inline
1061
1062 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1063     reach 3nested-map-as ; inline
1064
1065 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1066 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1067 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1068 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1069 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1070 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1071
1072 : prev-identity ( i seq -- identity i seq )
1073     2dup ??prev [ drop 0 ] unless -rot ; inline
1074
1075 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1076     '[ [ swap @ ] keep ]
1077     length-operator each-integer-from drop ; inline
1078
1079 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1080     [ prev-identity ] dip each-prior-identity-from ; inline
1081
1082 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1083     0 -rot each-prior-from ; inline
1084
1085 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1086     [
1087         '[ [ swap @ ] keep swap ] length-operator
1088     ] dip map-integers-from-as nip ; inline
1089
1090 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1091     [ 0 ] 3dip map-prior-identity-from-as ; inline
1092
1093 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1094     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1095
1096 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1097     0 -roll map-prior-from-as ; inline
1098
1099 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1100     over map-prior-from-as ; inline
1101
1102 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1103     over map-prior-as ; inline
1104
1105 TUPLE: virtual-zip-index seq ;
1106
1107 C: <zip-index> virtual-zip-index
1108
1109 M: virtual-zip-index length seq>> length ; inline
1110
1111 M: virtual-zip-index nth-unsafe
1112     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1113
1114 INSTANCE: virtual-zip-index immutable-sequence
1115
1116 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
1117     [ call ] dip swap [ push ] [ 2drop ] if ; inline
1118
1119 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
1120     '[ _ find-from-unsafe element/index ] bounds-check-call ; inline
1121
1122 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
1123     [ 0 ] 2dip find-from-unsafe element/index ; inline
1124
1125 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
1126     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
1127
1128 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
1129     [ index-of-last ] dip find-last-from* ; inline
1130
1131 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
1132     '[
1133         _ [ sequence-index-operator find-integer-from ] keepd
1134         element/index
1135     ] bounds-check-call ; inline
1136
1137 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
1138     [ 0 ] 2dip find-index-from* ; inline