extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : maybe-push ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* drop ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : nth-index ( n obj seq -- i )
 302     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 303
 304 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 305     [
 306         pick length '[
 307             tuck [ @ over inc-at* drop ] 2dip swap nth-index _ or
 308         ] [ H{ } clone ] 3dip with
 309     ] dip map-as ; inline
 310
 311 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 312     { } progressive-index-by-as ; inline
 313
 314 : progressive-index ( seq1 seq2 -- hash seq' )
 315     [ ] progressive-index-by ; inline
 316
 317 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 318     [ 0 ] dip reduce ; inline
 319
 320 : ?unclip ( seq -- rest/f first/f )
 321     [ f f ] [ unclip ] if-empty ;
 322
 323 : 1reduce ( seq quot: ( prev elt -- next ) -- result )
 324     [ ?unclip ] dip reduce ; inline
 325
 326 <PRIVATE
 327
 328 : change-nth-of-unsafe ( seq i quot -- seq )
 329     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 330
 331 PRIVATE>
 332
 333 : nth-of ( seq n -- elt ) swap nth ; inline
 334 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
 335 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 336 : ??nth ( n seq -- elt/f ? )
 337     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 338 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 339
 340 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 341     swap reduce ; inline
 342
 343 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 344     swap accumulate ; inline
 345
 346 <PRIVATE
 347
 348 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 349     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 350
 351 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 352     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 353
 354 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 355     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 356
 357 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 358     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 359
 360 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 361     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 362
 363 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 364     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 365
 366 PRIVATE>
 367
 368 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 369     pick length over
 370     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 371
 372 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 373     over filter-map-as* ; inline
 374
 375 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 376     [ [ not ] compose ] dip filter-map-as* ; inline
 377
 378 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 379     over reject-map-as* ; inline
 380
 381 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 382     reach length over
 383     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 384
 385 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 386     pick 2filter-map-as* ; inline
 387
 388 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 389     [ [ not ] compose ] dip 2filter-map-as* ; inline
 390
 391 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 392     pick 2reject-map-as* ; inline
 393
 394
 395 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 396     reach length over
 397     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 398
 399 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 400     pick filter-map-as ; inline
 401
 402 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 403     [ [ not ] compose ] 2dip filter-map-as ; inline
 404
 405 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 406     pick reject-map-as ; inline
 407
 408 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 409     5 npick length over
 410     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 411
 412 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 413     reach 2filter-map-as ; inline
 414
 415 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 416     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 417
 418 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 419     pick 2reject-map-as ; inline
 420
 421 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 422     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 423
 424 : (2selector-as) ( quot length exemplar -- selector accum )
 425     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 426
 427 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 428     [
 429         pick [ length ] keep
 430         [ (2selector-as) [ 2each ] dip ] 2curry call
 431     ] dip like ; inline
 432
 433 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 434     pick 2filter-as ; inline
 435
 436 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 437     [ [ not ] compose ] dip 2filter-as ; inline
 438
 439 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 440     pick 2reject-as ; inline
 441
 442 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 443     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 444
 445 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 446     [ 1 0 ? ] compose 2map-sum ; inline
 447
 448 : 3each-from
 449     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 450     [ 3length-operator ] dip -rot each-integer-from ; inline
 451
 452 : 3map-reduce
 453     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 454     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 455
 456 : round-robin ( seq -- newseq )
 457     [ { } ] [
 458         [ longest length <iota> ] keep
 459         [ [ ?nth ] with map ] curry map concat sift
 460     ] if-empty ;
 461
 462 : sift-as ( seq exemplar -- newseq )
 463     [ ] swap filter-as ;
 464
 465 : sift! ( seq -- newseq )
 466     [ ] filter! ;
 467
 468 : harvest-as ( seq exemplar -- newseq )
 469     [ empty? not ] swap filter-as ;
 470
 471 : harvest! ( seq -- newseq )
 472     [ empty? ] reject! ;
 473
 474 : head-as ( seq n exemplar -- seq' )
 475     [ head-slice ] [ like ] bi* ; inline
 476
 477 : head*-as ( seq n exemplar -- seq' )
 478     [ head-slice* ] [ like ] bi* ; inline
 479
 480 : tail-as ( seq n exemplar -- seq' )
 481     [ tail-slice ] [ like ] bi* ; inline
 482
 483 : tail*-as ( seq n exemplar -- seq' )
 484     [ tail-slice* ] [ like ] bi* ; inline
 485
 486 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 487     [ trim-slice ] [ like ] bi* ; inline
 488
 489 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 490     over empty? [ drop ] [
 491         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 492         [ trim ] [ drop ] if
 493     ] if ; inline
 494
 495 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 496     over empty? [ drop ] [
 497         over first-unsafe over call
 498         [ trim-head ] [ drop ] if
 499     ] if ; inline
 500
 501 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 502     over empty? [ drop ] [
 503         over last-unsafe over call
 504         [ trim-tail ] [ drop ] if
 505     ] if ; inline
 506
 507 : unsurround ( newseq seq2 seq3 -- seq1 )
 508     [ ?head drop ] [ ?tail drop ] bi* ;
 509
 510 : >string-list ( seq -- seq' )
 511     [ "\"" 1surround ] map "," join ;
 512
 513 : with-string-lines ( str quot -- str' )
 514     [ string-lines ] dip map "\n" join ; inline
 515
 516 : prepend-lines-with-spaces ( str -- str' )
 517     [ "    " prepend ] with-string-lines ;
 518
 519 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 520     [ find ] 2keep rot [
 521         [ 1 + ] 2dip find-from drop not
 522     ] [ 3drop f ] if ; inline
 523
 524 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 525     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 526
 527 <PRIVATE
 528
 529 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 530     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 531
 532 PRIVATE>
 533
 534 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 535     2sequence-index-iterator each-integer ; inline
 536
 537 : 2map-into ( seq1 seq2 quot into -- )
 538     [ 2length-operator ] dip collect ; inline
 539
 540 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 541     pick [ 2map-into ] keep ; inline
 542
 543 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 544     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 545
 546 TUPLE: evens { seq read-only } ;
 547
 548 C: <evens> evens
 549
 550 M: evens length seq>> length 1 + 2/ ; inline
 551
 552 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 553
 554 M: evens virtual-exemplar seq>> ; inline
 555
 556 INSTANCE: evens virtual-sequence
 557
 558 TUPLE: odds { seq read-only } ;
 559
 560 C: <odds> odds
 561
 562 M: odds length seq>> length 2/ ; inline
 563
 564 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 565
 566 M: odds virtual-exemplar seq>> ; inline
 567
 568 INSTANCE: odds virtual-sequence
 569
 570 : until-empty ( seq quot -- )
 571     [ dup empty? ] swap until drop ; inline
 572
 573 <PRIVATE
 574
 575 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 576     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 577
 578 PRIVATE>
 579
 580 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 581     over length <vector> [
 582         [ push-index-if ] 2curry each-index
 583     ] keep ; inline
 584
 585 : arg-sort ( seq -- indices )
 586     zip-index sort-keys values ;
 587
 588 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 589 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 590 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 591 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 592 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 593 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 594
 595 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 596 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 597 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 598 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 599 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 600 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 601
 602 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 603     [ ] swap produce-as nip ; inline
 604
 605 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 606     { } loop>sequence** ; inline
 607
 608 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 609     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 610
 611 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 612     { } loop>sequence* ; inline
 613
 614 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 615     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 616
 617 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 618     { } loop>sequence ; inline
 619
 620 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 621     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 622
 623 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 624     { } zero-loop>sequence ; inline
 625
 626 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 627     pick heap-empty?
 628     [ 3drop f f ]
 629     [
 630         [ [ heap-peek ] 2dip drop 2keep ]
 631         [
 632             nip ! ( pop? value key heap quot2 )
 633             5roll [
 634                 swap heap-pop* call( value key -- obj/f ) t
 635             ] [
 636                 4drop f f
 637             ] if
 638         ] 3bi
 639     ] if ; inline
 640
 641 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 642     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 643
 644 : heap>pairs ( heap -- pairs )
 645     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 646
 647 : map-zip-swap ( quot: ( x -- y ) -- alist )
 648     '[ _ keep ] map>alist ; inline
 649
 650 : ?heap-pop-value>array ( heap -- array )
 651     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 652
 653 <PRIVATE
 654
 655 : (reverse) ( seq -- newseq )
 656     dup [ length ] keep new-sequence
 657     [ 0 swap copy-unsafe ] keep reverse! ;
 658
 659 PRIVATE>
 660
 661 : reverse-as ( seq exemplar -- newseq )
 662     [ (reverse) ] [ like ] bi* ;
 663
 664 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 665     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 666
 667 : insert-nth! ( elt n seq -- )
 668     [ length ] keep ensure swap pick (a..b]
 669     over '[ [ 1 + ] keep _ move-unsafe ] each
 670     set-nth-unsafe ;
 671
 672 : set-nths ( value indices seq -- )
 673     swapd '[ _ swap _ set-nth ] each ; inline
 674
 675 : set-nths-unsafe ( value indices seq -- )
 676     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 677
 678 <PRIVATE
 679
 680 : (map-find-index) ( seq quot find-quot -- result i elt )
 681     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 682     [ [ [ drop f ] unless ] keep ] dip ; inline
 683
 684 PRIVATE>
 685
 686 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 687     [ find-index ] (map-find-index) ; inline
 688
 689 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 690     '[ _ do-find-from element/index ] bounds-check-call ; inline
 691
 692 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 693     [ 0 ] 2dip do-find-from element/index ; inline
 694
 695 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 696     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
 697
 698 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 699     [ index-of-last ] dip find-last-from* ; inline
 700
 701 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 702     '[
 703         _ [ sequence-index-operator find-integer-from ] keepd
 704         element/index
 705     ] bounds-check-call ; inline
 706
 707 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 708     [ 0 ] 2dip find-index-from* ; inline
 709
 710 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 711
 712 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 713
 714 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 715
 716 <PRIVATE
 717
 718 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 719 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 720 : set-length-of ( seq n -- seq ) over set-length ; inline
 721
 722 : move-unsafe-of ( seq to from -- seq )
 723     2dup = [
 724         2drop
 725     ] [
 726         overd nth-unsafe-of set-nth-unsafe-of
 727     ] if ; inline
 728
 729 : move-backward-of ( seq shift from to -- seq )
 730     2dup = [
 731         3drop
 732     ] [
 733         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 734     ] if ;
 735
 736 : open-slice-of ( seq shift from -- seq )
 737     over 0 = [
 738         2drop
 739     ] [
 740         [ ] [ drop [ length ] dip + ] 3bi
 741         [ pick length [ over - ] dip move-backward-of ] dip
 742         set-length-of
 743     ] if ;
 744
 745 PRIVATE>
 746
 747 ERROR: slice-error-of from to seq ;
 748
 749 : check-slice-of ( seq from to -- seq from to )
 750     over 0 < [ slice-error-of ] when
 751     dup reach length > [ slice-error-of ] when
 752     2dup > [ slice-error-of ] when ; inline
 753
 754 : delete-slice-of ( seq from to -- seq )
 755     check-slice-of over [ - ] dip open-slice-of ;
 756
 757 : remove-nth-of ( seq n -- seq' )
 758     [ dup 1 + rot snip-slice ] keepd append-as ;
 759
 760 : remove-nth-of* ( seq n -- nth seq' )
 761     [ nth-of ] [ remove-nth-of ] 2bi ;
 762
 763 : remove-nth-of! ( seq n -- seq )
 764     dup 1 + delete-slice-of ;
 765
 766 : remove-nth-of*! ( seq n -- nth seq )
 767     [ nth-of ] [ dup 1 + delete-slice-of ] 2bi ;
 768
 769 : snip-of ( seq from to -- head tail )
 770     [ head ] [ tail ] bi-curry* bi ; inline
 771
 772 : snip-slice-of ( seq from to -- head tail )
 773     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 774
 775 : index* ( seq obj -- n ) [ = ] curry find drop ;
 776
 777 : index-from* ( i seq obj -- n )
 778     [ = ] curry find-from drop ;
 779
 780 : last-index* ( seq obj -- n )
 781     [ = ] curry find-last drop ;
 782
 783 : last-index-from* ( i seq obj -- n )
 784     [ = ] curry find-last-from drop ;
 785
 786 : indices* ( seq obj -- indices )
 787     [ = ] curry [ swap ] prepose V{ } clone [
 788         [ push ] curry [ [ drop ] if ] curry compose each-index
 789     ] keep ;
 790
 791 : remove-first ( obj seq -- seq' )
 792     [ index ] keep over [ remove-nth ] [ nip ] if ;
 793
 794 : remove-first-of ( seq obj -- seq' )
 795     dupd index* [ remove-nth-of ] when* ;
 796
 797 : remove-first! ( obj seq -- seq )
 798     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 799
 800 : remove-last ( obj seq -- seq' )
 801     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 802
 803 : remove-last! ( obj seq -- seq )
 804     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 805
 806 : member-of? ( seq elt -- ? )
 807     [ = ] curry any? ;
 808
 809 : member-eq-of? ( seq elt -- ? )
 810     [ eq? ] curry any? ;
 811
 812 : remove-of ( seq elt -- newseq )
 813     [ = ] curry reject ;
 814
 815 : remove-eq-of ( seq elt -- newseq )
 816     [ eq? ] curry reject ;
 817
 818 : ?first2 ( seq -- first/f second/f )
 819     dup length {
 820         { 0 [ drop f f ] }
 821         { 1 [ first-unsafe f ] }
 822         [ drop first2-unsafe ]
 823     } case ;
 824
 825 : ?first3 ( seq -- first/f second/f third/f )
 826     dup length {
 827         { 0 [ drop f f f ] }
 828         { 1 [ first-unsafe f f ] }
 829         { 2 [ first2-unsafe f ] }
 830         [ drop first3-unsafe ]
 831     } case ;
 832
 833 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 834     dup length {
 835         { 0 [ drop f f f f ] }
 836         { 1 [ first-unsafe f f f ] }
 837         { 2 [ first2-unsafe f f ] }
 838         { 3 [ first3-unsafe f ] }
 839         [ drop first4-unsafe ]
 840     } case ;
 841
 842 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 843     [ find drop ] keepd swap
 844     [ cut ] [ f over like ] if* ; inline
 845
 846 : nth* ( n seq -- elt )
 847     [ length 1 - swap - ] [ nth ] bi ; inline
 848
 849 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 850     -rot sequence-index-operator each-integer-from ; inline
 851
 852 <PRIVATE
 853
 854 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 855     [
 856         [ keep swap ] curry [ dip ] curry
 857         [ [ first 0 ] dip call ] 2keep
 858         [ 2curry 3dip 5 npick pick ] curry
 859     ] [
 860         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 861     ] bi* compose 1 each-index-from nip swap ; inline
 862
 863 PRIVATE>
 864
 865 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 866     [ after? ] select-by* ; inline
 867
 868 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 869     [ before? ] select-by* ; inline
 870
 871 : arg-max ( seq -- n )
 872     [ ] supremum-by* drop ;
 873
 874 : arg-min ( seq -- n )
 875     [ ] infimum-by* drop ;
 876
 877 : ?supremum ( seq/f -- elt/f )
 878     [ f ] [
 879         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 880     ] if-empty ;
 881
 882 : ?infimum ( seq/f -- elt/f )
 883     [ f ] [
 884         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 885     ] if-empty ;
 886
 887 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 888     [ min ] map-reduce ; inline
 889
 890 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 891     [ max ] map-reduce ; inline
 892
 893 : change-last ( seq quot -- )
 894     [ index-of-last ] [ change-nth ] bi* ; inline
 895
 896 : change-last-unsafe ( seq quot -- )
 897     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 898
 899 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 900     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 901
 902 : percent-of ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 903     over length 0 =
 904     [ 2drop 0 ]
 905     [ over [ count ] [ length ] bi* / ] if ; inline
 906
 907 : sequence-index-operator-last ( n seq quot -- n quot' )
 908     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 909
 910 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 911     '[
 912         _ [ sequence-index-operator-last find-last-integer ] keepd
 913         index/element
 914     ] bounds-check-call ; inline
 915
 916 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 917     [ index-of-last ] dip find-last-index-from ; inline
 918
 919 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 920     [ find-last-index ] (map-find-index) ; inline
 921
 922 :: (start-all) ( seq subseq increment -- indices )
 923     0
 924     [ seq subseq subseq-index-from dup ]
 925     [ [ increment + ] keep ] produce nip ;
 926
 927 : start-all ( seq subseq -- indices )
 928     dup length (start-all) ; inline
 929
 930 : start-all* ( seq subseq -- indices )
 931     1 (start-all) ; inline
 932
 933 : count-subseq ( seq subseq -- n )
 934     start-all length ; inline
 935
 936 : count-subseq* ( seq subseq -- n )
 937     start-all* length ; inline
 938
 939 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 940     '[ _ 2keep 2array swap ] assoc-map ; inline
 941
 942 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 943     [ '[ @ not ] find drop ] keepd swap
 944     [ dup length ] unless* head-slice ; inline
 945
 946 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 947     [ '[ @ not ] find drop ] keepd swap
 948     [ dup length ] unless* tail-slice ; inline
 949
 950 : count-head ( seq quot -- n )
 951     [ not ] compose [ find drop ] keepd length or ; inline
 952
 953 : count-tail ( seq quot -- n )
 954     [ not ] compose [ find-last drop ] keepd
 955     length swap [ - 1 - ] when* ; inline
 956
 957 :: shorten* ( vector n -- seq )
 958     vector n tail
 959     n vector shorten ;
 960
 961 :: interleaved-as ( seq glue exemplar -- newseq )
 962     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 963     seq [ 2 * newseq set-nth-unsafe ] each-index
 964     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 965     newseq ;
 966
 967 : interleaved ( seq glue -- newseq )
 968     over interleaved-as ;
 969
 970 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 971     [ dup ] compose over [ length ] keep new-resizable
 972     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 973
 974 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 975     2pick < [
 976         [ nipd call ] 4keep
 977         3 7 0 nrotated
 978         [ [ 3drop ] 2dip rot ]
 979         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 980     ] [
 981         4drop f f f
 982     ] if ; inline recursive
 983
 984 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 985     [ 0 ] 3dip
 986     [ [ length check-length ] keep ] 2dip
 987     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 988
 989 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 990 ! Kadane's algorithm O(n) largest sum in subarray
 991 : max-subarray-sum ( seq -- sum )
 992     [ -1/0. 0 ] dip
 993     [ [ + ] keep max [ max ] keep ] each drop ;
 994
 995 TUPLE: step-slice
 996     { from integer read-only initial: 0 }
 997     { to integer read-only initial: 0 }
 998     { seq read-only }
 999     { step integer read-only } ;
1000
1001 :: <step-slice> ( from/f to/f step seq -- step-slice )
1002     step zero? [ "can't be zero" throw ] when
1003     seq length :> len
1004     step 0 > [
1005         from/f [ 0 ] unless*
1006         to/f [ len ] unless*
1007     ] [
1008         from/f [ len ] unless*
1009         to/f [ 0 ] unless*
1010     ] if
1011     [ dup 0 < [ len + ] when 0 len clamp ] bi@
1012     ! FIXME: make this work with steps
1013     seq dup slice? [ collapse-slice ] when
1014     step step-slice boa ;
1015
1016 M: step-slice virtual-exemplar seq>> ; inline
1017
1018 M: step-slice virtual@
1019     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
1020
1021 M: step-slice length
1022     [ to>> ] [ from>> - ] [ step>> ] tri
1023     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
1024     zero? [ 1 + ] unless ; inline
1025
1026 INSTANCE: step-slice virtual-sequence
1027
1028 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
1029     '[
1030         _ keep swap _ with each
1031     ] each ; inline
1032
1033 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
1034     [ 2over [ length ] bi@ * ] dip
1035     [
1036         new-resizable
1037         [ [ maybe-push ] curry compose 2nested-each* ] keep
1038     ] keep like ; inline
1039
1040 : 2nested-filter* ( seq1 seq-quot quot -- seq )
1041     pick 2nested-filter-as* ; inline
1042
1043 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
1044     [ 2over [ length ] bi@ * ] dip
1045     [
1046         new-resizable
1047         [ [ push ] curry compose 2nested-each* ] keep
1048     ] keep like ; inline
1049
1050 : 2nested-map* ( seq1 seq-quot quot -- seq )
1051     pick 2nested-map-as* ; inline
1052
1053
1054 : 2nested-each ( seq1 seq2 quot -- )
1055     swapd '[
1056         swap _ with each
1057     ] with each ; inline
1058
1059 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1060     [ 2over [ length ] bi@ * ] dip
1061     [
1062         new-resizable
1063         [ [ maybe-push ] curry compose 2nested-each ] keep
1064     ] keep like ; inline
1065
1066 : 2nested-filter ( seq1 seq2 quot -- seq )
1067     pick 2nested-filter-as ; inline
1068
1069 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1070     [ 2over [ length ] bi@ * ] dip
1071     [
1072         new-resizable
1073         [ [ push ] curry compose 2nested-each ] keep
1074     ] keep like ; inline
1075
1076 : 2nested-map ( seq1 seq2 quot -- seq )
1077     pick 2nested-map-as ; inline
1078
1079 : 3nested-each ( seq1 seq2 seq3 quot -- )
1080     spind '[
1081         -rot [
1082             swap _ with with each
1083         ] with with each
1084     ] with with each ; inline
1085
1086 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1087     [ 3 nover [ length ] tri@ * * ] dip
1088     [
1089         new-resizable
1090         [ [ maybe-push ] curry compose 3nested-each ] keep
1091     ] keep like ; inline
1092
1093 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1094     reach 3nested-filter-as ; inline
1095
1096 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1097     [ 3 nover [ length ] tri@ * * ] dip
1098     [
1099         new-resizable
1100         [ [ push ] curry compose 3nested-each ] keep
1101     ] keep like ; inline
1102
1103 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1104     reach 3nested-map-as ; inline
1105
1106 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1107 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1108 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1109 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1110 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1111 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1112
1113 : prev-identity ( i seq -- identity i seq )
1114     2dup ??prev [ drop 0 ] unless -rot ; inline
1115
1116 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1117     '[ [ swap @ ] keep ]
1118     length-operator each-integer-from drop ; inline
1119
1120 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1121     [ prev-identity ] dip each-prior-identity-from ; inline
1122
1123 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1124     0 -rot each-prior-from ; inline
1125
1126 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1127     [
1128         '[ [ swap @ ] keep swap ] length-operator
1129     ] dip map-integers-from-as nip ; inline
1130
1131 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1132     [ 0 ] 3dip map-prior-identity-from-as ; inline
1133
1134 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1135     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1136
1137 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1138     0 -roll map-prior-from-as ; inline
1139
1140 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1141     over map-prior-from-as ; inline
1142
1143 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1144     over map-prior-as ; inline
1145
1146 TUPLE: virtual-zip-index seq ;
1147
1148 C: <zip-index> virtual-zip-index
1149
1150 M: virtual-zip-index length seq>> length ; inline
1151
1152 M: virtual-zip-index nth-unsafe
1153     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1154
1155 INSTANCE: virtual-zip-index immutable-sequence
1156
1157 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
1158     [ call ] dip swap [ push ] [ 2drop ] if ; inline
1159
1160 : fry-map-as ( seq quot exemplar -- newseq )
1161     [ 2drop length ]
1162     [ overd new-sequence-like dup ]
1163     [ 2nip ] 3tri
1164     '[ [ [ _ nth-unsafe @ ] [ _ set-nth-unsafe ] bi ] each-integer _ _ like ] call ; inline