extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  10     [ swap ] 2dip each-from ; inline
  11
  12 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
  13     [ -rot ] 2dip 2each-from ; inline
  14
  15 :: subseq* ( from to seq -- subseq )
  16     seq length :> len
  17     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  18     to [ dup 0 < [ len + ] when ] [ len ] if*
  19     [ 0 len clamp ] bi@ dupd max seq subseq ;
  20
  21 : safe-subseq ( from to seq -- subseq )
  22     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  23
  24 : all-subseqs ( seq -- seqs )
  25     dup length [1..b] [ clump ] with map concat ;
  26
  27 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  28     [ dup length [ [0..b] ] [ ] bi ] dip '[
  29         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  30     ] each drop ; inline
  31
  32 : map-like ( seq exemplar -- seq' )
  33     '[ _ like ] map ; inline
  34
  35 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  36     [
  37         '[ <clumps> _ filter ] with map concat
  38     ] keepdd map-like ; inline
  39
  40 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  41     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  42
  43 :: longest-subseq ( seq1 seq2 -- subseq )
  44     seq1 length :> len1
  45     seq2 length :> len2
  46     0 :> n!
  47     0 :> end!
  48     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  49     len1 [1..b] [| x |
  50         len2 [1..b] [| y |
  51             x 1 - seq1 nth-unsafe
  52             y 1 - seq2 nth-unsafe = [
  53                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  54                 len y x table nth-unsafe set-nth-unsafe
  55                 len n > [ len n! x end! ] when
  56             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  57         ] each
  58     ] each end n - end seq1 subseq ;
  59
  60 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  61     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  62
  63 : pad-center ( seq n elt -- padded )
  64     swap pick length [-] [ drop ] [
  65         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  66         pick surround-as
  67     ] if-zero ;
  68
  69 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  70     [ change-nth ] 2curry each ; inline
  71
  72 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  73     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  74
  75 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  76     [ call ] dip [ push ] [ drop ] if* ; inline
  77
  78 <PRIVATE
  79
  80 : (index-selector-as) ( quot length exampler -- selector accum )
  81     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  82
  83 : (selector-as*) ( quot length exemplar -- selector accum )
  84     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  85
  86 PRIVATE>
  87
  88 : index-selector-as ( quot exemplar -- selector accum )
  89     [ length ] keep (index-selector-as) ; inline
  90
  91 : index-selector ( quot -- selector accum )
  92     V{ } index-selector-as ; inline
  93
  94 : selector-as* ( quot exemplar -- selector accum )
  95     [ length ] keep (selector-as*) ; inline
  96
  97 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  98
  99 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 100     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 101
 102 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 103     over filter-index-as ; inline
 104
 105 : even-indices ( seq -- seq' )
 106     [ length 1 + 2/ ] keep [
 107         [ [ 2 * ] dip nth-unsafe ] curry
 108     ] keep map-integers-as ;
 109
 110 : odd-indices ( seq -- seq' )
 111     [ length 2/ ] keep [
 112         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 113     ] keep map-integers-as ;
 114
 115 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when harvest ] dip join ; inline
 117
 118 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 119     [ split-when ] dip
 120     [ [ harvest ] dip join ]
 121     [ [ first empty? ] dip [ prepend ] curry when ]
 122     [ [ last empty? ] dip [ append ] curry when ]
 123     2tri ; inline
 124
 125 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 126     seq length :> len
 127     0 [ len dupd < ] [
 128         dup seq quot find-from drop
 129         [ 2dup = [ 1 + ] when ] [ len ] if*
 130         [ seq <slice> ] keep len or swap
 131     ] produce nip ; inline
 132
 133 : ?<slice> ( from/f to/f sequence -- slice )
 134     [ [ 0 ] unless* ] 2dip
 135     over [ nip [ length ] [ ] bi ] unless
 136     <slice> ; inline
 137
 138 : sequence>slice ( sequence -- slice )
 139     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 140
 141 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 142     2dup [ from>> ] bi@ > [ swap ] when ; inline
 143
 144 : ordered-slices-range ( slice-lt slice-gt -- to from )
 145     [ to>> ] [ from>> ] bi* ;
 146
 147 : unordered-slices-range ( slice1 slice2 -- to from )
 148     slice-order-by-from ordered-slices-range ;
 149
 150 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 151     ordered-slices-range > ; inline
 152
 153 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-range > ; inline
 155
 156 : slices-overlap? ( slice1 slice2 -- ? )
 157     unordered-slices-overlap? ;
 158
 159 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 160     ordered-slices-range >= ; inline
 161
 162 : unordered-slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-range >= ; inline
 164
 165 : slices-touch? ( slice1 slice2 -- ? )
 166     unordered-slices-touch? ;
 167
 168 ERROR: slices-don't-touch slice1 slice2 ;
 169
 170 : merge-slices ( slice1 slice2 -- slice/* )
 171     slice-order-by-from
 172     2dup ordered-slices-touch? [
 173         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 174     ] [
 175         slices-don't-touch
 176     ] if ;
 177
 178 : rotate ( seq n -- seq' )
 179     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 180
 181 ERROR: underlying-mismatch slice1 slice2 ;
 182
 183 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 184     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 185
 186 : span-slices ( slice1 slice2 -- slice )
 187     ensure-same-underlying
 188     [ [ from>> ] bi@ min ]
 189     [ [ to>> ] bi@ max ]
 190     [ drop seq>> ] 2tri <slice> ;
 191
 192 : ?span-slices ( slice1/f slice2/f -- slice )
 193     2dup and [ span-slices ] [ or ] if ;
 194
 195 :: rotate! ( seq n -- )
 196     seq length :> len
 197     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 198     [ 2dup = ] [
 199         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 200         dup len = [ drop over ] when
 201         2over = [ -rot nip over ] when
 202     ] until 3drop ;
 203
 204 : all-rotations ( seq -- seq' )
 205     dup length <iota> [ rotate ] with map ;
 206
 207 <PRIVATE
 208
 209 : (appender-for) ( quot length exemplar -- appender accum )
 210     new-resizable [ [ push-all ] curry compose ] keep ; inline
 211
 212 PRIVATE>
 213
 214 : appender-for ( quot exemplar -- appender accum )
 215     [ length ] keep (appender-for) ; inline
 216
 217 : appender ( quot -- appender accum )
 218     V{ } appender-for ; inline
 219
 220 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 221     [ appender-for [ each ] dip ] keep like ; inline
 222
 223 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 224     [ length ] keep [ new-resizable ] [ append! ] bi ;
 225
 226 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 227     over empty? [ 2drop { } ] [
 228         [ [ first ] dip call ] 2keep rot [
 229             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 230         ] keep like
 231     ] if ; inline
 232
 233 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 234     reach length over
 235     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 236
 237 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 238     pick map-filter-as ; inline
 239
 240 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ ] map-filter ; inline
 242
 243 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 244     [ empty? not ] map-filter ; inline
 245
 246 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 247     2over < [
 248         [ nip call ] 4keep nipdd
 249         [ 1 + ] 2dip (each-integer-with-previous)
 250     ] [
 251         4drop
 252     ] if ; inline recursive
 253
 254 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 255     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 256
 257 : (collect-with-previous) ( quot into -- quot' )
 258     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 259
 260 : collect-with-previous ( n quot into --  )
 261     (collect-with-previous) each-integer-with-previous ; inline
 262
 263 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 264     overd [ [ collect-with-previous ] keep ] new-like ; inline
 265
 266 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 267     [ length-operator ] dip map-integers-with ; inline
 268
 269 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 270     over map-with-previous-as ; inline
 271
 272 <PRIVATE
 273
 274 : (setup-each-from) ( i seq -- n quot )
 275     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 276
 277 : setup-each-from ( i seq quot -- n quot' )
 278     [ (setup-each-from) ] dip compose ; inline
 279
 280 PRIVATE>
 281
 282 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 283     [ -rot setup-each-from ] dip map-integers-as ; inline
 284
 285 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 286     pick map-from-as ; inline
 287
 288 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 289     '[ dup @ _ when ] map ; inline
 290
 291 <PRIVATE
 292
 293 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 294     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 295
 296 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 297     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 298
 299 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 300     [ length ] keep (filter-mapper-for) ; inline
 301
 302 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 303     V{ } filter-mapper-for ; inline
 304
 305 PRIVATE>
 306
 307 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 308     reach length over
 309     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 310
 311 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 312     pick filter-map-as ; inline
 313
 314 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 315     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 316
 317 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 318     [ 1 0 ? ] compose 2map-sum ; inline
 319
 320 : 3each-from
 321     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 322     [ 3length-operator ] dip -rot each-integer-from ; inline
 323
 324 : 3map-reduce
 325     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 326     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 327
 328 : round-robin ( seq -- newseq )
 329     [ { } ] [
 330         [ longest length <iota> ] keep
 331         [ [ ?nth ] with map ] curry map concat sift
 332     ] if-empty ;
 333
 334 : sift-as ( seq exemplar -- newseq )
 335     [ ] swap filter-as ;
 336
 337 : sift! ( seq -- newseq )
 338     [ ] filter! ;
 339
 340 : harvest-as ( seq exemplar -- newseq )
 341     [ empty? not ] swap filter-as ;
 342
 343 : harvest! ( seq -- newseq )
 344     [ empty? ] reject! ;
 345
 346 : head-as ( seq n exemplar -- seq' )
 347     [ head-slice ] [ like ] bi* ; inline
 348
 349 : head*-as ( seq n exemplar -- seq' )
 350     [ head-slice* ] [ like ] bi* ; inline
 351
 352 : tail-as ( seq n exemplar -- seq' )
 353     [ tail-slice ] [ like ] bi* ; inline
 354
 355 : tail*-as ( seq n exemplar -- seq' )
 356     [ tail-slice* ] [ like ] bi* ; inline
 357
 358 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 359     [ trim-slice ] [ like ] bi* ; inline
 360
 361 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 362     over empty? [ drop ] [
 363         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 364         [ trim ] [ drop ] if
 365     ] if ; inline
 366
 367 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 368     over empty? [ drop ] [
 369         over first-unsafe over call
 370         [ trim-head ] [ drop ] if
 371     ] if ; inline
 372
 373 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 374     over empty? [ drop ] [
 375         over last-unsafe over call
 376         [ trim-tail ] [ drop ] if
 377     ] if ; inline
 378
 379 : unsurround ( newseq seq2 seq3 -- seq1 )
 380     [ ?head drop ] [ ?tail drop ] bi* ;
 381
 382 : >string-list ( seq -- seq' )
 383     [ "\"" 1surround ] map "," join ;
 384
 385 : with-string-lines ( str quot -- str' )
 386     [ string-lines ] dip map "\n" join ; inline
 387
 388 : prepend-lines-with-spaces ( str -- str' )
 389     [ "    " prepend ] with-string-lines ;
 390
 391 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 392     [ find ] 2keep rot [
 393         [ 1 + ] 2dip find-from drop not
 394     ] [ 3drop f ] if ; inline
 395
 396 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 397     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 398
 399 <PRIVATE
 400
 401 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 402     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 403
 404 PRIVATE>
 405
 406 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 407     2sequence-index-iterator each-integer ; inline
 408
 409 : 2map-into ( seq1 seq2 quot into -- )
 410     [ 2length-operator ] dip collect ; inline
 411
 412 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 413     pick [ 2map-into ] keep ; inline
 414
 415 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 416     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 417
 418 TUPLE: evens { seq read-only } ;
 419
 420 C: <evens> evens
 421
 422 M: evens length seq>> length 1 + 2/ ; inline
 423
 424 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 425
 426 M: evens virtual-exemplar seq>> ; inline
 427
 428 INSTANCE: evens virtual-sequence
 429
 430 TUPLE: odds { seq read-only } ;
 431
 432 C: <odds> odds
 433
 434 M: odds length seq>> length 2/ ; inline
 435
 436 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 437
 438 M: odds virtual-exemplar seq>> ; inline
 439
 440 INSTANCE: odds virtual-sequence
 441
 442 : until-empty ( seq quot -- )
 443     [ dup empty? ] swap until drop ; inline
 444
 445 <PRIVATE
 446
 447 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 448     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 449
 450 PRIVATE>
 451
 452 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 453     over length <vector> [
 454         [ push-index-if ] 2curry each-index
 455     ] keep ; inline
 456
 457 : arg-sort ( seq -- indices )
 458     zip-index sort-keys values ;
 459
 460 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 461 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 462 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 463 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 464 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 465 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 466
 467 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 468 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 469 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 470 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 471 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 472 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 473
 474 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 475     [ ] swap produce-as nip ; inline
 476
 477 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 478     { } loop>sequence** ; inline
 479
 480 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 481     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 482
 483 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 484     { } loop>sequence* ; inline
 485
 486 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 487     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 488
 489 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 490     { } loop>sequence ; inline
 491
 492 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 493     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 494
 495 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 496     { } zero-loop>sequence ; inline
 497
 498 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 499     pick heap-empty?
 500     [ 3drop f f ]
 501     [
 502         [ [ heap-peek ] 2dip drop 2keep ]
 503         [
 504             nip ! ( pop? value key heap quot2 )
 505             5roll [
 506                 swap heap-pop* call( value key -- obj/f ) t
 507             ] [
 508                 4drop f f
 509             ] if
 510         ] 3bi
 511     ] if ; inline
 512
 513 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 514     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 515
 516 : heap>pairs ( heap -- pairs )
 517     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 518
 519 : map-zip-swap ( quot: ( x -- y ) -- alist )
 520     '[ _ keep ] map>alist ; inline
 521
 522 : ?heap-pop-value>array ( heap -- array )
 523     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 524
 525 <PRIVATE
 526
 527 : (reverse) ( seq -- newseq )
 528     dup [ length ] keep new-sequence
 529     [ 0 swap copy-unsafe ] keep reverse! ;
 530
 531 PRIVATE>
 532
 533 : reverse-as ( seq exemplar -- newseq )
 534     [ (reverse) ] [ like ] bi* ;
 535
 536 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 537     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 538
 539 : insert-nth! ( elt n seq -- )
 540     [ length ] keep ensure swap pick (a..b]
 541     over '[ [ 1 + ] keep _ move-unsafe ] each
 542     set-nth-unsafe ;
 543
 544 : set-nths ( value indices seq -- )
 545     swapd '[ _ swap _ set-nth ] each ; inline
 546
 547 : set-nths-unsafe ( value indices seq -- )
 548     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 549
 550 <PRIVATE
 551
 552 : (map-find-index) ( seq quot find-quot -- result i elt )
 553     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 554     [ [ [ drop f ] unless ] keep ] dip ; inline
 555
 556 PRIVATE>
 557
 558 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 559     [ find-index ] (map-find-index) ; inline
 560
 561 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 562
 563 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 564
 565 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 566
 567 : remove-first ( obj seq -- seq' )
 568     [ index ] keep over [ remove-nth ] [ nip ] if ;
 569
 570 : remove-first! ( obj seq -- seq )
 571     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 572
 573 : remove-last ( obj seq -- seq' )
 574     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 575
 576 : remove-last! ( obj seq -- seq )
 577     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 578
 579 : ?first2 ( seq -- first/f second/f )
 580     dup length {
 581         { 0 [ drop f f ] }
 582         { 1 [ first-unsafe f ] }
 583         [ drop first2-unsafe ]
 584     } case ;
 585
 586 : ?first3 ( seq -- first/f second/f third/f )
 587     dup length {
 588         { 0 [ drop f f f ] }
 589         { 1 [ first-unsafe f f ] }
 590         { 2 [ first2-unsafe f ] }
 591         [ drop first3-unsafe ]
 592     } case ;
 593
 594 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 595     dup length {
 596         { 0 [ drop f f f f ] }
 597         { 1 [ first-unsafe f f f ] }
 598         { 2 [ first2-unsafe f f ] }
 599         { 3 [ first3-unsafe f ] }
 600         [ drop first4-unsafe ]
 601     } case ;
 602
 603 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 604     [ find drop ] keepd swap
 605     [ cut ] [ f over like ] if* ; inline
 606
 607 : nth* ( n seq -- elt )
 608     [ length 1 - swap - ] [ nth ] bi ; inline
 609
 610 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 611     -rot sequence-index-operator each-integer-from ; inline
 612
 613 <PRIVATE
 614
 615 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 616     [
 617         [ keep swap ] curry [ dip ] curry
 618         [ [ first 0 ] dip call ] 2keep
 619         [ 2curry 3dip 5 npick pick ] curry
 620     ] [
 621         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 622     ] bi* compose 1 each-index-from nip swap ; inline
 623
 624 PRIVATE>
 625
 626 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 627     [ after? ] select-by* ; inline
 628
 629 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 630     [ before? ] select-by* ; inline
 631
 632 : arg-max ( seq -- n )
 633     [ ] supremum-by* drop ;
 634
 635 : arg-min ( seq -- n )
 636     [ ] infimum-by* drop ;
 637
 638 : ?supremum ( seq/f -- elt/f )
 639     [ f ] [
 640         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 641     ] if-empty ;
 642
 643 : ?infimum ( seq/f -- elt/f )
 644     [ f ] [
 645         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 646     ] if-empty ;
 647
 648 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 649     [ min ] map-reduce ; inline
 650
 651 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 652     [ max ] map-reduce ; inline
 653
 654 : change-last ( seq quot -- )
 655     [ index-of-last ] [ change-nth ] bi* ; inline
 656
 657 : change-last-unsafe ( seq quot -- )
 658     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 659
 660 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 661     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 662
 663 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 664     over [ count ] [ length ] bi* / ; inline
 665
 666 : sequence-index-operator-last ( n seq quot -- n quot' )
 667     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 668
 669 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 670     '[
 671         _ [ sequence-index-operator-last find-last-integer ] keepd
 672         index/element
 673     ] bounds-check-call ; inline
 674
 675 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 676     [ index-of-last ] dip find-last-index-from ; inline
 677
 678 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 679     [ find-last-index ] (map-find-index) ; inline
 680
 681 :: (start-all) ( seq subseq increment -- indices )
 682     0
 683     [ seq subseq subseq-index-from dup ]
 684     [ [ increment + ] keep ] produce nip ;
 685
 686 : start-all ( seq subseq -- indices )
 687     dup length (start-all) ; inline
 688
 689 : start-all* ( seq subseq -- indices )
 690     1 (start-all) ; inline
 691
 692 : count-subseq ( seq subseq -- n )
 693     start-all length ; inline
 694
 695 : count-subseq* ( seq subseq -- n )
 696     start-all* length ; inline
 697
 698 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 699     '[ _ 2keep 2array swap ] assoc-map ; inline
 700
 701 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 702     [ '[ @ not ] find drop ] keepd swap
 703     [ dup length ] unless* head-slice ; inline
 704
 705 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 706     [ '[ @ not ] find drop ] keepd swap
 707     [ dup length ] unless* tail-slice ; inline
 708
 709 : count-head ( seq quot -- n )
 710     [ not ] compose [ find drop ] keepd length or ; inline
 711
 712 : count-tail ( seq quot -- n )
 713     [ not ] compose [ find-last drop ] keepd
 714     length swap [ - 1 - ] when* ; inline
 715
 716 :: shorten* ( vector n -- seq )
 717     vector n tail
 718     n vector shorten ;
 719
 720 :: interleaved-as ( seq glue exemplar -- newseq )
 721     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 722     seq [ 2 * newseq set-nth-unsafe ] each-index
 723     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 724     newseq ;
 725
 726 : interleaved ( seq glue -- newseq )
 727     over interleaved-as ;
 728
 729 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 730     [ dup ] compose over [ length ] keep new-resizable
 731     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 732
 733 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 734     2pick < [
 735         [ nipd call ] 4keep
 736         3 7 0 nrotated
 737         [ [ 3drop ] 2dip rot ]
 738         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 739     ] [
 740         4drop f f f
 741     ] if ; inline recursive
 742
 743 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 744     [ 0 ] 3dip
 745     [ [ length check-length ] keep ] 2dip
 746     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 747
 748 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 749 ! Kadane's algorithm O(n) largest sum in subarray
 750 : max-subarray-sum ( seq -- sum )
 751     [ -1/0. 0 ] dip
 752     [ [ + ] keep max [ max ] keep ] each drop ;
 753
 754 TUPLE: step-slice
 755     { from integer read-only initial: 0 }
 756     { to integer read-only initial: 0 }
 757     { seq read-only }
 758     { step integer read-only } ;
 759
 760 :: <step-slice> ( from/f to/f step seq -- step-slice )
 761     step zero? [ "can't be zero" throw ] when
 762     seq length :> len
 763     step 0 > [
 764         from/f [ 0 ] unless*
 765         to/f [ len ] unless*
 766     ] [
 767         from/f [ len ] unless*
 768         to/f [ 0 ] unless*
 769     ] if
 770     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 771     ! FIXME: make this work with steps
 772     seq dup slice? [ collapse-slice ] when
 773     step step-slice boa ;
 774
 775 M: step-slice virtual-exemplar seq>> ; inline
 776
 777 M: step-slice virtual@
 778     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 779
 780 M: step-slice length
 781     [ to>> ] [ from>> - ] [ step>> ] tri
 782     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 783     zero? [ 1 + ] unless ; inline
 784
 785 INSTANCE: step-slice virtual-sequence
 786
 787 : 2nested-each ( seq1 seq2 quot -- )
 788     swapd '[
 789         swap _ with each
 790     ] with each ; inline
 791
 792 : 3nested-each ( seq1 seq2 seq3 quot -- )
 793     [ spin ] dip '[
 794         -rot [
 795             swap _ with with each
 796         ] with with each
 797     ] with with each ; inline
 798
 799 : 2nested-map ( seq1 seq2 quot -- seq )
 800     2over [ length ] bi@ * reach
 801     [
 802         new-resizable
 803         [ [ push ] curry compose 2nested-each ] keep
 804     ] keep like ; inline
 805
 806 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
 807     3 nover [ length ] tri@ * * 5 npick
 808     [
 809         new-resizable
 810         [ [ push ] curry compose 3nested-each ] keep
 811     ] keep like ; inline
 812
 813 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
 814 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
 815 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
 816 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
 817 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
 818 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
 819
 820 : prev-identity ( i seq -- identity i seq )
 821     2dup ??prev [ drop 0 ] unless -rot ; inline
 822
 823 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
 824     '[ [ swap @ ] keep ]
 825     length-operator each-integer-from drop ; inline
 826
 827 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
 828     [ prev-identity ] dip each-prior-identity-from ; inline
 829
 830 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
 831     0 -rot each-prior-from ; inline
 832
 833 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 834     [
 835         '[ [ swap @ ] keep swap ] length-operator
 836     ] dip map-integers-from-as nip ; inline
 837
 838 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 839     [ 0 ] 3dip map-prior-identity-from-as ; inline
 840
 841 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 842     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
 843
 844 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 845     0 -roll map-prior-from-as ; inline
 846
 847 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
 848     over map-prior-from-as ; inline
 849
 850 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
 851     over map-prior-as ; inline
 852
 853 TUPLE: virtual-zip-index seq ;
 854
 855 C: <zip-index> virtual-zip-index
 856
 857 M: virtual-zip-index length seq>> length ; inline
 858
 859 M: virtual-zip-index nth-unsafe
 860     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
 861
 862 INSTANCE: virtual-zip-index immutable-sequence
 863
 864 : nth-index ( n obj seq -- i )
 865     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;