extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  10     [ swap ] 2dip each-from ; inline
  11
  12 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
  13     [ -rot ] 2dip 2each-from ; inline
  14
  15 :: subseq* ( from to seq -- subseq )
  16     seq length :> len
  17     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  18     to [ dup 0 < [ len + ] when ] [ len ] if*
  19     [ 0 len clamp ] bi@ dupd max seq subseq ;
  20
  21 : safe-subseq ( from to seq -- subseq )
  22     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  23
  24 : all-subseqs ( seq -- seqs )
  25     dup length [1..b] [ clump ] with map concat ;
  26
  27 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  28     [ dup length [ [0..b] ] [ ] bi ] dip '[
  29         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  30     ] each drop ; inline
  31
  32 : map-like ( seq exemplar -- seq' )
  33     '[ _ like ] map ; inline
  34
  35 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  36     [
  37         '[ <clumps> _ filter ] with map concat
  38     ] keepdd map-like ; inline
  39
  40 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  41     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  42
  43 :: longest-subseq ( seq1 seq2 -- subseq )
  44     seq1 length :> len1
  45     seq2 length :> len2
  46     0 :> n!
  47     0 :> end!
  48     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  49     len1 [1..b] [| x |
  50         len2 [1..b] [| y |
  51             x 1 - seq1 nth-unsafe
  52             y 1 - seq2 nth-unsafe = [
  53                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  54                 len y x table nth-unsafe set-nth-unsafe
  55                 len n > [ len n! x end! ] when
  56             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  57         ] each
  58     ] each end n - end seq1 subseq ;
  59
  60 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  61     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  62
  63 : pad-center ( seq n elt -- padded )
  64     swap pick length [-] [ drop ] [
  65         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  66         pick surround-as
  67     ] if-zero ;
  68
  69 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  70     [ change-nth ] 2curry each ; inline
  71
  72 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  73     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  74
  75 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  76     [ call ] dip [ push ] [ drop ] if* ; inline
  77
  78 : push? ( elt/f accum -- )
  79     over [ push ] [ 2drop ] if ; inline
  80
  81 <PRIVATE
  82
  83 : (index-selector-as) ( quot length exampler -- selector accum )
  84     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  85
  86 : (selector-as*) ( quot length exemplar -- selector accum )
  87     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  88
  89 PRIVATE>
  90
  91 : index-selector-as ( quot exemplar -- selector accum )
  92     [ length ] keep (index-selector-as) ; inline
  93
  94 : index-selector ( quot -- selector accum )
  95     V{ } index-selector-as ; inline
  96
  97 : selector-as* ( quot exemplar -- selector accum )
  98     [ length ] keep (selector-as*) ; inline
  99
 100 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 101
 102 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 103     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 104
 105 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 106     over filter-index-as ; inline
 107
 108 : even-indices ( seq -- seq' )
 109     [ length 1 + 2/ ] keep [
 110         [ [ 2 * ] dip nth-unsafe ] curry
 111     ] keep map-integers-as ;
 112
 113 : odd-indices ( seq -- seq' )
 114     [ length 2/ ] keep [
 115         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 116     ] keep map-integers-as ;
 117
 118 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 119     [ split-when harvest ] dip join ; inline
 120
 121 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 122     [ split-when ] dip
 123     [ [ harvest ] dip join ]
 124     [ [ first empty? ] dip [ prepend ] curry when ]
 125     [ [ last empty? ] dip [ append ] curry when ]
 126     2tri ; inline
 127
 128 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 129     seq length :> len
 130     0 [ len dupd < ] [
 131         dup seq quot find-from drop
 132         [ 2dup = [ 1 + ] when ] [ len ] if*
 133         [ seq <slice> ] keep len or swap
 134     ] produce nip ; inline
 135
 136 : ?<slice> ( from/f to/f sequence -- slice )
 137     [ [ 0 ] unless* ] 2dip
 138     over [ nip [ length ] [ ] bi ] unless
 139     <slice> ; inline
 140
 141 : sequence>slice ( sequence -- slice )
 142     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 143
 144 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 145     2dup [ from>> ] bi@ > [ swap ] when ; inline
 146
 147 : ordered-slices-range ( slice-lt slice-gt -- to from )
 148     [ to>> ] [ from>> ] bi* ;
 149
 150 : unordered-slices-range ( slice1 slice2 -- to from )
 151     slice-order-by-from ordered-slices-range ;
 152
 153 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 154     ordered-slices-range > ; inline
 155
 156 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 157     unordered-slices-range > ; inline
 158
 159 : slices-overlap? ( slice1 slice2 -- ? )
 160     unordered-slices-overlap? ;
 161
 162 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 163     ordered-slices-range >= ; inline
 164
 165 : unordered-slices-touch? ( slice1 slice2 -- ? )
 166     unordered-slices-range >= ; inline
 167
 168 : slices-touch? ( slice1 slice2 -- ? )
 169     unordered-slices-touch? ;
 170
 171 ERROR: slices-don't-touch slice1 slice2 ;
 172
 173 : merge-slices ( slice1 slice2 -- slice/* )
 174     slice-order-by-from
 175     2dup ordered-slices-touch? [
 176         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 177     ] [
 178         slices-don't-touch
 179     ] if ;
 180
 181 : rotate ( seq n -- seq' )
 182     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 183
 184 ERROR: underlying-mismatch slice1 slice2 ;
 185
 186 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 187     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 188
 189 : span-slices ( slice1 slice2 -- slice )
 190     ensure-same-underlying
 191     [ [ from>> ] bi@ min ]
 192     [ [ to>> ] bi@ max ]
 193     [ drop seq>> ] 2tri <slice> ;
 194
 195 : ?span-slices ( slice1/f slice2/f -- slice )
 196     2dup and [ span-slices ] [ or ] if ;
 197
 198 :: rotate! ( seq n -- )
 199     seq length :> len
 200     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 201     [ 2dup = ] [
 202         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 203         dup len = [ drop over ] when
 204         2over = [ -rot nip over ] when
 205     ] until 3drop ;
 206
 207 : all-rotations ( seq -- seq' )
 208     dup length <iota> [ rotate ] with map ;
 209
 210 <PRIVATE
 211
 212 : (appender-for) ( quot length exemplar -- appender accum )
 213     new-resizable [ [ push-all ] curry compose ] keep ; inline
 214
 215 PRIVATE>
 216
 217 : appender-for ( quot exemplar -- appender accum )
 218     [ length ] keep (appender-for) ; inline
 219
 220 : appender ( quot -- appender accum )
 221     V{ } appender-for ; inline
 222
 223 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 224     [ appender-for [ each ] dip ] keep like ; inline
 225
 226 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 227     [ length ] keep [ new-resizable ] [ append! ] bi ;
 228
 229 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 230     over empty? [ 2drop { } ] [
 231         [ [ first ] dip call ] 2keep rot [
 232             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 233         ] keep like
 234     ] if ; inline
 235
 236 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 237     reach length over
 238     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 239
 240 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 241     pick map-filter-as ; inline
 242
 243 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 244     [ ] map-filter ; inline
 245
 246 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 247     [ empty? not ] map-filter ; inline
 248
 249 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 250     2over < [
 251         [ nip call ] 4keep nipdd
 252         [ 1 + ] 2dip (each-integer-with-previous)
 253     ] [
 254         4drop
 255     ] if ; inline recursive
 256
 257 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 258     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 259
 260 : (collect-with-previous) ( quot into -- quot' )
 261     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 262
 263 : collect-with-previous ( n quot into --  )
 264     (collect-with-previous) each-integer-with-previous ; inline
 265
 266 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 267     overd [ [ collect-with-previous ] keep ] new-like ; inline
 268
 269 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 270     [ length-operator ] dip map-integers-with ; inline
 271
 272 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 273     over map-with-previous-as ; inline
 274
 275 <PRIVATE
 276
 277 : (setup-each-from) ( i seq -- n quot )
 278     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 279
 280 : setup-each-from ( i seq quot -- n quot' )
 281     [ (setup-each-from) ] dip compose ; inline
 282
 283 PRIVATE>
 284
 285 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 286     [ -rot setup-each-from ] dip map-integers-as ; inline
 287
 288 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 289     pick map-from-as ; inline
 290
 291 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 292     '[ dup @ _ when ] map ; inline
 293
 294 <PRIVATE
 295
 296 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 297     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 298
 299 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 300     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 301
 302 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 303     [ length ] keep (filter-mapper-for) ; inline
 304
 305 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 306     V{ } filter-mapper-for ; inline
 307
 308 PRIVATE>
 309
 310 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 311     reach length over
 312     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 313
 314 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 315     pick filter-map-as ; inline
 316
 317 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 318     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 319
 320 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 321     [ 1 0 ? ] compose 2map-sum ; inline
 322
 323 : 3each-from
 324     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 325     [ 3length-operator ] dip -rot each-integer-from ; inline
 326
 327 : 3map-reduce
 328     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 329     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 330
 331 : round-robin ( seq -- newseq )
 332     [ { } ] [
 333         [ longest length <iota> ] keep
 334         [ [ ?nth ] with map ] curry map concat sift
 335     ] if-empty ;
 336
 337 : sift-as ( seq exemplar -- newseq )
 338     [ ] swap filter-as ;
 339
 340 : sift! ( seq -- newseq )
 341     [ ] filter! ;
 342
 343 : harvest-as ( seq exemplar -- newseq )
 344     [ empty? not ] swap filter-as ;
 345
 346 : harvest! ( seq -- newseq )
 347     [ empty? ] reject! ;
 348
 349 : head-as ( seq n exemplar -- seq' )
 350     [ head-slice ] [ like ] bi* ; inline
 351
 352 : head*-as ( seq n exemplar -- seq' )
 353     [ head-slice* ] [ like ] bi* ; inline
 354
 355 : tail-as ( seq n exemplar -- seq' )
 356     [ tail-slice ] [ like ] bi* ; inline
 357
 358 : tail*-as ( seq n exemplar -- seq' )
 359     [ tail-slice* ] [ like ] bi* ; inline
 360
 361 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 362     [ trim-slice ] [ like ] bi* ; inline
 363
 364 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 365     over empty? [ drop ] [
 366         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 367         [ trim ] [ drop ] if
 368     ] if ; inline
 369
 370 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 371     over empty? [ drop ] [
 372         over first-unsafe over call
 373         [ trim-head ] [ drop ] if
 374     ] if ; inline
 375
 376 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 377     over empty? [ drop ] [
 378         over last-unsafe over call
 379         [ trim-tail ] [ drop ] if
 380     ] if ; inline
 381
 382 : unsurround ( newseq seq2 seq3 -- seq1 )
 383     [ ?head drop ] [ ?tail drop ] bi* ;
 384
 385 : >string-list ( seq -- seq' )
 386     [ "\"" 1surround ] map "," join ;
 387
 388 : with-string-lines ( str quot -- str' )
 389     [ string-lines ] dip map "\n" join ; inline
 390
 391 : prepend-lines-with-spaces ( str -- str' )
 392     [ "    " prepend ] with-string-lines ;
 393
 394 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 395     [ find ] 2keep rot [
 396         [ 1 + ] 2dip find-from drop not
 397     ] [ 3drop f ] if ; inline
 398
 399 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 400     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 401
 402 <PRIVATE
 403
 404 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 405     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 406
 407 PRIVATE>
 408
 409 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 410     2sequence-index-iterator each-integer ; inline
 411
 412 : 2map-into ( seq1 seq2 quot into -- )
 413     [ 2length-operator ] dip collect ; inline
 414
 415 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 416     pick [ 2map-into ] keep ; inline
 417
 418 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 419     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 420
 421 TUPLE: evens { seq read-only } ;
 422
 423 C: <evens> evens
 424
 425 M: evens length seq>> length 1 + 2/ ; inline
 426
 427 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 428
 429 M: evens virtual-exemplar seq>> ; inline
 430
 431 INSTANCE: evens virtual-sequence
 432
 433 TUPLE: odds { seq read-only } ;
 434
 435 C: <odds> odds
 436
 437 M: odds length seq>> length 2/ ; inline
 438
 439 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 440
 441 M: odds virtual-exemplar seq>> ; inline
 442
 443 INSTANCE: odds virtual-sequence
 444
 445 : until-empty ( seq quot -- )
 446     [ dup empty? ] swap until drop ; inline
 447
 448 <PRIVATE
 449
 450 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 451     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 452
 453 PRIVATE>
 454
 455 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 456     over length <vector> [
 457         [ push-index-if ] 2curry each-index
 458     ] keep ; inline
 459
 460 : arg-sort ( seq -- indices )
 461     zip-index sort-keys values ;
 462
 463 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 464 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 465 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 466 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 467 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 468 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 469
 470 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 471 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 472 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 473 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 474 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 475 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 476
 477 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 478     [ ] swap produce-as nip ; inline
 479
 480 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 481     { } loop>sequence** ; inline
 482
 483 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 484     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 485
 486 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 487     { } loop>sequence* ; inline
 488
 489 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 490     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 491
 492 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 493     { } loop>sequence ; inline
 494
 495 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 496     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 497
 498 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 499     { } zero-loop>sequence ; inline
 500
 501 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 502     pick heap-empty?
 503     [ 3drop f f ]
 504     [
 505         [ [ heap-peek ] 2dip drop 2keep ]
 506         [
 507             nip ! ( pop? value key heap quot2 )
 508             5roll [
 509                 swap heap-pop* call( value key -- obj/f ) t
 510             ] [
 511                 4drop f f
 512             ] if
 513         ] 3bi
 514     ] if ; inline
 515
 516 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 517     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 518
 519 : heap>pairs ( heap -- pairs )
 520     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 521
 522 : map-zip-swap ( quot: ( x -- y ) -- alist )
 523     '[ _ keep ] map>alist ; inline
 524
 525 : ?heap-pop-value>array ( heap -- array )
 526     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 527
 528 <PRIVATE
 529
 530 : (reverse) ( seq -- newseq )
 531     dup [ length ] keep new-sequence
 532     [ 0 swap copy-unsafe ] keep reverse! ;
 533
 534 PRIVATE>
 535
 536 : reverse-as ( seq exemplar -- newseq )
 537     [ (reverse) ] [ like ] bi* ;
 538
 539 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 540     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 541
 542 : insert-nth! ( elt n seq -- )
 543     [ length ] keep ensure swap pick (a..b]
 544     over '[ [ 1 + ] keep _ move-unsafe ] each
 545     set-nth-unsafe ;
 546
 547 : set-nths ( value indices seq -- )
 548     swapd '[ _ swap _ set-nth ] each ; inline
 549
 550 : set-nths-unsafe ( value indices seq -- )
 551     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 552
 553 <PRIVATE
 554
 555 : (map-find-index) ( seq quot find-quot -- result i elt )
 556     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 557     [ [ [ drop f ] unless ] keep ] dip ; inline
 558
 559 PRIVATE>
 560
 561 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 562     [ find-index ] (map-find-index) ; inline
 563
 564 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 565
 566 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 567
 568 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 569
 570 : remove-first ( obj seq -- seq' )
 571     [ index ] keep over [ remove-nth ] [ nip ] if ;
 572
 573 : remove-first! ( obj seq -- seq )
 574     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 575
 576 : remove-last ( obj seq -- seq' )
 577     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 578
 579 : remove-last! ( obj seq -- seq )
 580     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 581
 582 : ?first2 ( seq -- first/f second/f )
 583     dup length {
 584         { 0 [ drop f f ] }
 585         { 1 [ first-unsafe f ] }
 586         [ drop first2-unsafe ]
 587     } case ;
 588
 589 : ?first3 ( seq -- first/f second/f third/f )
 590     dup length {
 591         { 0 [ drop f f f ] }
 592         { 1 [ first-unsafe f f ] }
 593         { 2 [ first2-unsafe f ] }
 594         [ drop first3-unsafe ]
 595     } case ;
 596
 597 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 598     dup length {
 599         { 0 [ drop f f f f ] }
 600         { 1 [ first-unsafe f f f ] }
 601         { 2 [ first2-unsafe f f ] }
 602         { 3 [ first3-unsafe f ] }
 603         [ drop first4-unsafe ]
 604     } case ;
 605
 606 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 607     [ find drop ] keepd swap
 608     [ cut ] [ f over like ] if* ; inline
 609
 610 : nth* ( n seq -- elt )
 611     [ length 1 - swap - ] [ nth ] bi ; inline
 612
 613 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 614     -rot sequence-index-operator each-integer-from ; inline
 615
 616 <PRIVATE
 617
 618 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 619     [
 620         [ keep swap ] curry [ dip ] curry
 621         [ [ first 0 ] dip call ] 2keep
 622         [ 2curry 3dip 5 npick pick ] curry
 623     ] [
 624         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 625     ] bi* compose 1 each-index-from nip swap ; inline
 626
 627 PRIVATE>
 628
 629 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 630     [ after? ] select-by* ; inline
 631
 632 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 633     [ before? ] select-by* ; inline
 634
 635 : arg-max ( seq -- n )
 636     [ ] supremum-by* drop ;
 637
 638 : arg-min ( seq -- n )
 639     [ ] infimum-by* drop ;
 640
 641 : ?supremum ( seq/f -- elt/f )
 642     [ f ] [
 643         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 644     ] if-empty ;
 645
 646 : ?infimum ( seq/f -- elt/f )
 647     [ f ] [
 648         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 649     ] if-empty ;
 650
 651 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 652     [ min ] map-reduce ; inline
 653
 654 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 655     [ max ] map-reduce ; inline
 656
 657 : change-last ( seq quot -- )
 658     [ index-of-last ] [ change-nth ] bi* ; inline
 659
 660 : change-last-unsafe ( seq quot -- )
 661     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 662
 663 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 664     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 665
 666 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 667     over [ count ] [ length ] bi* / ; inline
 668
 669 : sequence-index-operator-last ( n seq quot -- n quot' )
 670     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 671
 672 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 673     '[
 674         _ [ sequence-index-operator-last find-last-integer ] keepd
 675         index/element
 676     ] bounds-check-call ; inline
 677
 678 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 679     [ index-of-last ] dip find-last-index-from ; inline
 680
 681 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 682     [ find-last-index ] (map-find-index) ; inline
 683
 684 :: (start-all) ( seq subseq increment -- indices )
 685     0
 686     [ seq subseq subseq-index-from dup ]
 687     [ [ increment + ] keep ] produce nip ;
 688
 689 : start-all ( seq subseq -- indices )
 690     dup length (start-all) ; inline
 691
 692 : start-all* ( seq subseq -- indices )
 693     1 (start-all) ; inline
 694
 695 : count-subseq ( seq subseq -- n )
 696     start-all length ; inline
 697
 698 : count-subseq* ( seq subseq -- n )
 699     start-all* length ; inline
 700
 701 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 702     '[ _ 2keep 2array swap ] assoc-map ; inline
 703
 704 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 705     [ '[ @ not ] find drop ] keepd swap
 706     [ dup length ] unless* head-slice ; inline
 707
 708 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 709     [ '[ @ not ] find drop ] keepd swap
 710     [ dup length ] unless* tail-slice ; inline
 711
 712 : count-head ( seq quot -- n )
 713     [ not ] compose [ find drop ] keepd length or ; inline
 714
 715 : count-tail ( seq quot -- n )
 716     [ not ] compose [ find-last drop ] keepd
 717     length swap [ - 1 - ] when* ; inline
 718
 719 :: shorten* ( vector n -- seq )
 720     vector n tail
 721     n vector shorten ;
 722
 723 :: interleaved-as ( seq glue exemplar -- newseq )
 724     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 725     seq [ 2 * newseq set-nth-unsafe ] each-index
 726     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 727     newseq ;
 728
 729 : interleaved ( seq glue -- newseq )
 730     over interleaved-as ;
 731
 732 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 733     [ dup ] compose over [ length ] keep new-resizable
 734     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 735
 736 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 737     2pick < [
 738         [ nipd call ] 4keep
 739         3 7 0 nrotated
 740         [ [ 3drop ] 2dip rot ]
 741         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 742     ] [
 743         4drop f f f
 744     ] if ; inline recursive
 745
 746 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 747     [ 0 ] 3dip
 748     [ [ length check-length ] keep ] 2dip
 749     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 750
 751 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 752 ! Kadane's algorithm O(n) largest sum in subarray
 753 : max-subarray-sum ( seq -- sum )
 754     [ -1/0. 0 ] dip
 755     [ [ + ] keep max [ max ] keep ] each drop ;
 756
 757 TUPLE: step-slice
 758     { from integer read-only initial: 0 }
 759     { to integer read-only initial: 0 }
 760     { seq read-only }
 761     { step integer read-only } ;
 762
 763 :: <step-slice> ( from/f to/f step seq -- step-slice )
 764     step zero? [ "can't be zero" throw ] when
 765     seq length :> len
 766     step 0 > [
 767         from/f [ 0 ] unless*
 768         to/f [ len ] unless*
 769     ] [
 770         from/f [ len ] unless*
 771         to/f [ 0 ] unless*
 772     ] if
 773     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 774     ! FIXME: make this work with steps
 775     seq dup slice? [ collapse-slice ] when
 776     step step-slice boa ;
 777
 778 M: step-slice virtual-exemplar seq>> ; inline
 779
 780 M: step-slice virtual@
 781     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 782
 783 M: step-slice length
 784     [ to>> ] [ from>> - ] [ step>> ] tri
 785     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 786     zero? [ 1 + ] unless ; inline
 787
 788 INSTANCE: step-slice virtual-sequence
 789
 790 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 791     '[
 792         _ keep swap _ with each
 793     ] each ; inline
 794
 795 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 796     [ 2over [ length ] bi@ * ] dip
 797     [
 798         new-resizable
 799         [ [ push? ] curry compose 2nested-each* ] keep
 800     ] keep like ; inline
 801
 802 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 803     pick 2nested-filter-as* ; inline
 804
 805 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 806     [ 2over [ length ] bi@ * ] dip
 807     [
 808         new-resizable
 809         [ [ push ] curry compose 2nested-each* ] keep
 810     ] keep like ; inline
 811
 812 : 2nested-map* ( seq1 seq-quot quot -- seq )
 813     pick 2nested-map-as* ; inline
 814
 815
 816 : 2nested-each ( seq1 seq2 quot -- )
 817     swapd '[
 818         swap _ with each
 819     ] with each ; inline
 820
 821 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
 822     [ 2over [ length ] bi@ * ] dip
 823     [
 824         new-resizable
 825         [ [ push? ] curry compose 2nested-each ] keep
 826     ] keep like ; inline
 827
 828 : 2nested-filter ( seq1 seq2 quot -- seq )
 829     pick 2nested-filter-as ; inline
 830
 831 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
 832     [ 2over [ length ] bi@ * ] dip
 833     [
 834         new-resizable
 835         [ [ push ] curry compose 2nested-each ] keep
 836     ] keep like ; inline
 837
 838 : 2nested-map ( seq1 seq2 quot -- seq )
 839     pick 2nested-map-as ; inline
 840
 841 : 3nested-each ( seq1 seq2 seq3 quot -- )
 842     [ spin ] dip '[
 843         -rot [
 844             swap _ with with each
 845         ] with with each
 846     ] with with each ; inline
 847
 848 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
 849     [ 3 nover [ length ] tri@ * * ] dip
 850     [
 851         new-resizable
 852         [ [ push? ] curry compose 3nested-each ] keep
 853     ] keep like ; inline
 854
 855 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
 856     reach 3nested-filter-as ; inline
 857
 858 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
 859     [ 3 nover [ length ] tri@ * * ] dip
 860     [
 861         new-resizable
 862         [ [ push ] curry compose 3nested-each ] keep
 863     ] keep like ; inline
 864
 865 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
 866     reach 3nested-map-as ; inline
 867
 868 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
 869 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
 870 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
 871 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
 872 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
 873 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
 874
 875 : prev-identity ( i seq -- identity i seq )
 876     2dup ??prev [ drop 0 ] unless -rot ; inline
 877
 878 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
 879     '[ [ swap @ ] keep ]
 880     length-operator each-integer-from drop ; inline
 881
 882 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
 883     [ prev-identity ] dip each-prior-identity-from ; inline
 884
 885 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
 886     0 -rot each-prior-from ; inline
 887
 888 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 889     [
 890         '[ [ swap @ ] keep swap ] length-operator
 891     ] dip map-integers-from-as nip ; inline
 892
 893 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 894     [ 0 ] 3dip map-prior-identity-from-as ; inline
 895
 896 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 897     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
 898
 899 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 900     0 -roll map-prior-from-as ; inline
 901
 902 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
 903     over map-prior-from-as ; inline
 904
 905 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
 906     over map-prior-as ; inline
 907
 908 TUPLE: virtual-zip-index seq ;
 909
 910 C: <zip-index> virtual-zip-index
 911
 912 M: virtual-zip-index length seq>> length ; inline
 913
 914 M: virtual-zip-index nth-unsafe
 915     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
 916
 917 INSTANCE: virtual-zip-index immutable-sequence
 918
 919 : nth-index ( n obj seq -- i )
 920     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;