extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs assocs.extras combinators
   2 generalizations grouping growable hash-sets heaps kernel math
   3 math.order ranges sequences sequences.private sets shuffle
   4 sorting splitting vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enumerated> ] dip '[ @ ] filter-values ; inline
   9
  10 :: subseq* ( from to seq -- subseq )
  11     seq length :> len
  12     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  13     to [ dup 0 < [ len + ] when ] [ len ] if*
  14     [ 0 len clamp ] bi@ dupd max seq subseq ;
  15
  16 : safe-subseq ( from to seq -- subseq )
  17     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  18
  19 : all-subseqs ( seq -- seqs )
  20     dup length [1..b] [ clump ] with map concat ;
  21
  22 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  23     [ dup length [ [0..b] ] [ ] bi ] dip '[
  24         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  25     ] each drop ; inline
  26
  27 : map-like ( seq exemplar -- seq' )
  28     '[ _ like ] map ; inline
  29
  30 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  31     [
  32         '[ <clumps> _ filter ] with map concat
  33     ] keepdd map-like ; inline
  34
  35 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  36     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  37
  38 :: longest-subseq ( seq1 seq2 -- subseq )
  39     seq1 length :> len1
  40     seq2 length :> len2
  41     0 :> n!
  42     0 :> end!
  43     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  44     len1 [1..b] [| x |
  45         len2 [1..b] [| y |
  46             x 1 - seq1 nth-unsafe
  47             y 1 - seq2 nth-unsafe = [
  48                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  49                 len y x table nth-unsafe set-nth-unsafe
  50                 len n > [ len n! x end! ] when
  51             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  52         ] each
  53     ] each end n - end seq1 subseq ;
  54
  55 : mismatch-last ( seq1 seq2 -- i-back )
  56     [ <reversed> ] bi@ mismatch ; inline
  57
  58 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  59     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  60
  61 : pad-center ( seq n elt -- padded )
  62     swap pick length [-] [ drop ] [
  63         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  64         pick surround-as
  65     ] if-zero ;
  66
  67 : zip-longest-with ( seq1 seq2 fill -- assoc )
  68     pad-longest zip ;
  69
  70 : zip-longest ( seq1 seq2 -- assoc )
  71     f zip-longest-with ;
  72
  73 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  74     [ change-nth ] 2curry each ; inline
  75
  76 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  77     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  78
  79 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  80     [ call ] dip [ push ] [ drop ] if* ; inline
  81
  82 : maybe-push ( elt/f accum -- )
  83     over [ push ] [ 2drop ] if ; inline
  84
  85 <PRIVATE
  86
  87 : (index-selector-as) ( quot length exampler -- selector accum )
  88     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  89
  90 : (selector-as*) ( quot length exemplar -- selector accum )
  91     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  92
  93 PRIVATE>
  94
  95 : index-selector-as ( quot exemplar -- selector accum )
  96     [ length ] keep (index-selector-as) ; inline
  97
  98 : index-selector ( quot -- selector accum )
  99     V{ } index-selector-as ; inline
 100
 101 : selector-as* ( quot exemplar -- selector accum )
 102     [ length ] keep (selector-as*) ; inline
 103
 104 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 105
 106 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 107     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 108
 109 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 110     over filter-index-as ; inline
 111
 112 : even-indices ( seq -- seq' )
 113     [ length 1 + 2/ ] keep [
 114         [ [ 2 * ] dip nth-unsafe ] curry
 115     ] keep map-integers-as ;
 116
 117 : odd-indices ( seq -- seq' )
 118     [ length 2/ ] keep [
 119         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 120     ] keep map-integers-as ;
 121
 122 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 123     [ split-when harvest ] dip join ; inline
 124
 125 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 126     [ split-when ] dip
 127     [ [ harvest ] dip join ]
 128     [ [ first empty? ] dip [ prepend ] curry when ]
 129     [ [ last empty? ] dip [ append ] curry when ]
 130     2tri ; inline
 131
 132 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 133     seq length :> len
 134     0 [ len dupd < ] [
 135         dup seq quot find-from drop
 136         [ 2dup = [ 1 + ] when ] [ len ] if*
 137         [ seq <slice> ] keep len or swap
 138     ] produce nip ; inline
 139
 140 : ?<slice> ( from/f to/f sequence -- slice )
 141     [ [ 0 ] unless* ] 2dip
 142     over [ nip [ length ] [ ] bi ] unless
 143     <slice> ; inline
 144
 145 : sequence>slice ( sequence -- slice )
 146     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 147
 148 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 149     2dup [ from>> ] bi@ > [ swap ] when ; inline
 150
 151 : ordered-slices-range ( slice-lt slice-gt -- to from )
 152     [ to>> ] [ from>> ] bi* ;
 153
 154 : unordered-slices-range ( slice1 slice2 -- to from )
 155     slice-order-by-from ordered-slices-range ;
 156
 157 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 158     ordered-slices-range > ; inline
 159
 160 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 161     unordered-slices-range > ; inline
 162
 163 : slices-overlap? ( slice1 slice2 -- ? )
 164     unordered-slices-overlap? ;
 165
 166 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 167     ordered-slices-range >= ; inline
 168
 169 : unordered-slices-touch? ( slice1 slice2 -- ? )
 170     unordered-slices-range >= ; inline
 171
 172 : slices-touch? ( slice1 slice2 -- ? )
 173     unordered-slices-touch? ;
 174
 175 ERROR: slices-don't-touch slice1 slice2 ;
 176
 177 : merge-slices ( slice1 slice2 -- slice/* )
 178     slice-order-by-from
 179     2dup ordered-slices-touch? [
 180         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 181     ] [
 182         slices-don't-touch
 183     ] if ;
 184
 185 : rotate ( seq n -- seq' )
 186     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 187
 188 ERROR: underlying-mismatch slice1 slice2 ;
 189
 190 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 191     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 192
 193 : span-slices ( slice1 slice2 -- slice )
 194     ensure-same-underlying
 195     [ [ from>> ] bi@ min ]
 196     [ [ to>> ] bi@ max ]
 197     [ drop seq>> ] 2tri <slice> ;
 198
 199 : ?span-slices ( slice1/f slice2/f -- slice )
 200     2dup and [ span-slices ] [ or ] if ;
 201
 202 :: rotate! ( seq n -- )
 203     seq length :> len
 204     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 205     [ 2dup = ] [
 206         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 207         dup len = [ drop over ] when
 208         2over = [ -rot nip over ] when
 209     ] until 3drop ;
 210
 211 : all-rotations ( seq -- seq' )
 212     dup length <iota> [ rotate ] with map ;
 213
 214 <PRIVATE
 215
 216 : (appender-for) ( quot length exemplar -- appender accum )
 217     new-resizable [ [ push-all ] curry compose ] keep ; inline
 218
 219 PRIVATE>
 220
 221 : appender-for ( quot exemplar -- appender accum )
 222     [ length ] keep (appender-for) ; inline
 223
 224 : appender ( quot -- appender accum )
 225     V{ } appender-for ; inline
 226
 227 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 228     [ appender-for [ each ] dip ] keep like ; inline
 229
 230 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 231     [ length ] keep [ new-resizable ] [ append! ] bi ;
 232
 233 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 234     over empty? [ 2drop { } ] [
 235         [ [ first ] dip call ] 2keep rot [
 236             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 237         ] keep like
 238     ] if ; inline
 239
 240 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 241     reach length over
 242     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 243
 244 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 245     pick map-filter-as ; inline
 246
 247 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 248     [ ] map-filter ; inline
 249
 250 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 251     [ empty? not ] map-filter ; inline
 252
 253 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 254     2over < [
 255         [ nip call ] 4keep nipdd
 256         [ 1 + ] 2dip (each-integer-with-previous)
 257     ] [
 258         4drop
 259     ] if ; inline recursive
 260
 261 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 262     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 263
 264 : (collect-with-previous) ( quot into -- quot' )
 265     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 266
 267 : collect-with-previous ( n quot into -- )
 268     (collect-with-previous) each-integer-with-previous ; inline
 269
 270 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 271     overd [ [ collect-with-previous ] keep ] new-like ; inline
 272
 273 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 274     [ length-operator ] dip map-integers-with ; inline
 275
 276 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 277     over map-with-previous-as ; inline
 278
 279 : setup-each-from ( seq quot -- n quot )
 280     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 281
 282 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 283     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 284
 285 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 286     pick map-from-as ; inline
 287
 288 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 289     '[ dup @ _ when ] map ; inline
 290
 291 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 292     [ swap ] 2dip each-from ; inline
 293
 294 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 295     [ -rot ] 2dip 2each-from ; inline
 296
 297 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 298     pick empty? [
 299         2nip clone
 300     ] [
 301         [ 0 ] 2dip
 302         [ swapd [ dup ] compose ] dip map-as nip
 303     ] if ; inline
 304
 305 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 306     over 0accumulate-as ; inline
 307
 308 : nth-index ( n obj seq -- i )
 309     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 310
 311 : at+* ( n key assoc -- old new ) [ 0 or [ + ] keep swap dup ] change-at ; inline
 312
 313 : inc-at* ( key assoc -- old new ) [ 1 ] 2dip at+* ; inline
 314
 315 : mark-firsts ( seq -- seq' )
 316     dup length <hash-set> '[ _ ?adjoin 1 0 ? ] { } map-as ;
 317
 318 : deduplicate ( seq -- seq' )
 319     dup length <hash-set> '[ _ ?adjoin ] { } filter-as ;
 320
 321 : deduplicate-last ( seq -- seq' )
 322     <reversed> deduplicate reverse ;
 323
 324 : classify-from ( next hash seq -- next' hash seq' )
 325     '[
 326         swap '[
 327             dupd _ ?set-once-at
 328             [ [ 1 + ] dip ] when
 329         ] { } map-as
 330     ] keepd swap ;
 331
 332 : classify* ( seq -- next hash seq' )
 333     [ 0 H{ } clone ] dip classify-from ;
 334
 335 : classify ( seq -- seq' ) classify* 2nip ; inline
 336
 337 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 338     '[ nip @ over inc-at* drop ] [ H{ } clone ] 2dip { } 0accumulate-as ; inline
 339
 340 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 341     [
 342         pick length '[
 343             tuck [ @ over inc-at* drop ] 2dip swap nth-index _ or
 344         ] [ H{ } clone ] 3dip with
 345     ] dip map-as ; inline
 346
 347 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 348     { } progressive-index-by-as ; inline
 349
 350 : progressive-index ( seq1 seq2 -- hash seq' )
 351     [ ] progressive-index-by ; inline
 352
 353 : 0reduce ( seq quot: ( ..a prev elt -- ..a next ) -- result )
 354     [ 0 ] dip reduce ; inline
 355
 356 : ?unclip ( seq -- rest/f first/f )
 357     [ f f ] [ unclip ] if-empty ;
 358
 359 : 1reduce ( seq quot: ( ..a prev elt -- ..a next ) -- result )
 360     [ f ] swap '[ [ ] _ map-reduce ] if-empty ; inline
 361
 362 <PRIVATE
 363
 364 : change-nth-of-unsafe ( seq i quot -- seq )
 365     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 366
 367 PRIVATE>
 368
 369 : nth-of ( seq n -- elt ) swap nth ; inline
 370 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
 371 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 372 : ??nth ( n seq -- elt/f ? )
 373     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 374 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 375
 376 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 377     swap reduce ; inline
 378
 379 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 380     swap accumulate ; inline
 381
 382 <PRIVATE
 383
 384 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 385     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 386
 387 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 388     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 389
 390 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 391     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 392
 393 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 394     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 395
 396 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 397     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 398
 399 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 400     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 401
 402 PRIVATE>
 403
 404 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 405     pick length over
 406     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 407
 408 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 409     over filter-map-as* ; inline
 410
 411 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 412     [ [ not ] compose ] dip filter-map-as* ; inline
 413
 414 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 415     over reject-map-as* ; inline
 416
 417 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 418     reach length over
 419     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 420
 421 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 422     pick 2filter-map-as* ; inline
 423
 424 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 425     [ [ not ] compose ] dip 2filter-map-as* ; inline
 426
 427 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 428     pick 2reject-map-as* ; inline
 429
 430
 431 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 432     reach length over
 433     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 434
 435 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 436     pick filter-map-as ; inline
 437
 438 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 439     [ [ not ] compose ] 2dip filter-map-as ; inline
 440
 441 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 442     pick reject-map-as ; inline
 443
 444 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 445     5 npick length over
 446     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 447
 448 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 449     reach 2filter-map-as ; inline
 450
 451 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 452     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 453
 454 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 455     pick 2reject-map-as ; inline
 456
 457 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 458     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 459
 460 : (2selector-as) ( quot length exemplar -- selector accum )
 461     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 462
 463 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 464     [
 465         pick [ length ] keep
 466         [ (2selector-as) [ 2each ] dip ] 2curry call
 467     ] dip like ; inline
 468
 469 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 470     pick 2filter-as ; inline
 471
 472 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 473     [ [ not ] compose ] dip 2filter-as ; inline
 474
 475 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 476     pick 2reject-as ; inline
 477
 478 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 479     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 480
 481 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 482     [ 1 0 ? ] compose 2map-sum ; inline
 483
 484 : 3each-from
 485     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 486     [ 3length-operator ] dip -rot each-integer-from ; inline
 487
 488 : 3map-reduce
 489     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 490     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 491
 492 : round-robin ( seq -- newseq )
 493     [ { } ] [
 494         [ longest length <iota> ] keep
 495         [ [ ?nth ] with map ] curry map concat sift
 496     ] if-empty ;
 497
 498 : sift-as ( seq exemplar -- newseq )
 499     [ ] swap filter-as ;
 500
 501 : sift! ( seq -- seq' )
 502     [ ] filter! ;
 503
 504 : harvest-as ( seq exemplar -- newseq )
 505     [ empty? not ] swap filter-as ;
 506
 507 : harvest! ( seq -- newseq )
 508     [ empty? ] reject! ;
 509
 510 : head-as ( seq n exemplar -- seq' )
 511     [ head-slice ] [ like ] bi* ; inline
 512
 513 : head*-as ( seq n exemplar -- seq' )
 514     [ head-slice* ] [ like ] bi* ; inline
 515
 516 : tail-as ( seq n exemplar -- seq' )
 517     [ tail-slice ] [ like ] bi* ; inline
 518
 519 : tail*-as ( seq n exemplar -- seq' )
 520     [ tail-slice* ] [ like ] bi* ; inline
 521
 522 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 523     [ trim-slice ] [ like ] bi* ; inline
 524
 525 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 526     over empty? [ drop ] [
 527         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 528         [ trim ] [ drop ] if
 529     ] if ; inline
 530
 531 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 532     over empty? [ drop ] [
 533         over first-unsafe over call
 534         [ trim-head ] [ drop ] if
 535     ] if ; inline
 536
 537 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 538     over empty? [ drop ] [
 539         over last-unsafe over call
 540         [ trim-tail ] [ drop ] if
 541     ] if ; inline
 542
 543 : unsurround ( newseq seq2 seq3 -- seq1 )
 544     [ ?head drop ] [ ?tail drop ] bi* ;
 545
 546 : >string-list ( seq -- seq' )
 547     [ "\"" 1surround ] map "," join ;
 548
 549 : with-string-lines ( str quot -- str' )
 550     [ string-lines ] dip map "\n" join ; inline
 551
 552 : prepend-lines-with-spaces ( str -- str' )
 553     [ "    " prepend ] with-string-lines ;
 554
 555 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 556     [ find ] 2keep rot [
 557         [ 1 + ] 2dip find-from drop not
 558     ] [ 3drop f ] if ; inline
 559
 560 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 561     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 562
 563 <PRIVATE
 564
 565 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 566     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 567
 568 PRIVATE>
 569
 570 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 571     2sequence-index-iterator each-integer ; inline
 572
 573 : 2map-into ( seq1 seq2 quot into -- )
 574     [ 2length-operator ] dip collect ; inline
 575
 576 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 577     pick [ 2map-into ] keep ; inline
 578
 579 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 580     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 581
 582 TUPLE: evens < sequence-view ;
 583
 584 C: <evens> evens
 585
 586 M: evens length seq>> length 1 + 2/ ; inline
 587
 588 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 589
 590 TUPLE: odds < sequence-view ;
 591
 592 C: <odds> odds
 593
 594 M: odds length seq>> length 2/ ; inline
 595
 596 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 597
 598 : until-empty ( seq quot -- )
 599     [ dup empty? ] swap until drop ; inline
 600
 601 <PRIVATE
 602
 603 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 604     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 605
 606 PRIVATE>
 607
 608 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 609     over length <vector> [
 610         [ push-index-if ] 2curry each-index
 611     ] keep ; inline
 612
 613 : arg-sort ( seq -- indices )
 614     zip-index sort-keys values ;
 615
 616 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 617 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 618 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 619 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 620 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 621 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 622
 623 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 624 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 625 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 626 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 627 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 628 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 629
 630 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 631     [ ] swap produce-as nip ; inline
 632
 633 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 634     { } loop>sequence** ; inline
 635
 636 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 637     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 638
 639 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 640     { } loop>sequence* ; inline
 641
 642 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 643     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 644
 645 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 646     { } loop>sequence ; inline
 647
 648 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 649     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 650
 651 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 652     { } zero-loop>sequence ; inline
 653
 654 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 655     pick heap-empty?
 656     [ 3drop f f ]
 657     [
 658         [ [ heap-peek ] 2dip drop 2keep ]
 659         [
 660             nip ! ( pop? value key heap quot2 )
 661             5roll [
 662                 swap heap-pop* call( value key -- obj/f ) t
 663             ] [
 664                 4drop f f
 665             ] if
 666         ] 3bi
 667     ] if ; inline
 668
 669 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 670     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 671
 672 : heap>pairs ( heap -- pairs )
 673     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 674
 675 : map-zip-swap ( quot: ( x -- y ) -- alist )
 676     '[ _ keep ] map>alist ; inline
 677
 678 : ?heap-pop-value>array ( heap -- array )
 679     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 680
 681 <PRIVATE
 682
 683 : (reverse) ( seq -- newseq )
 684     dup [ length ] keep new-sequence
 685     [ 0 swap copy-unsafe ] keep reverse! ;
 686
 687 PRIVATE>
 688
 689 : reverse-as ( seq exemplar -- newseq )
 690     [ (reverse) ] [ like ] bi* ;
 691
 692 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 693     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 694
 695 : insert-nth! ( elt n seq -- )
 696     [ length ] keep ensure swap pick (a..b]
 697     over '[ [ 1 + ] keep _ move-unsafe ] each
 698     set-nth-unsafe ;
 699
 700 : set-nths ( value indices seq -- )
 701     swapd '[ _ swap _ set-nth ] each ; inline
 702
 703 : set-nths-unsafe ( value indices seq -- )
 704     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 705
 706 <PRIVATE
 707
 708 : (map-find-index) ( seq quot find-quot -- result i elt )
 709     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 710     [ [ [ drop f ] unless ] keep ] dip ; inline
 711
 712 PRIVATE>
 713
 714 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 715     [ find-index ] (map-find-index) ; inline
 716
 717 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 718     '[ _ do-find-from element/index ] bounds-check-call ; inline
 719
 720 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 721     [ 0 ] 2dip do-find-from element/index ; inline
 722
 723 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 724     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
 725
 726 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 727     [ index-of-last ] dip find-last-from* ; inline
 728
 729 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 730     '[
 731         _ [ sequence-index-operator find-integer-from ] keepd
 732         element/index
 733     ] bounds-check-call ; inline
 734
 735 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 736     [ 0 ] 2dip find-index-from* ; inline
 737
 738 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 739
 740 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 741
 742 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 743
 744 <PRIVATE
 745
 746 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 747 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 748 : set-length-of ( seq n -- seq ) over set-length ; inline
 749
 750 : move-unsafe-of ( seq to from -- seq )
 751     2dup = [
 752         2drop
 753     ] [
 754         overd nth-unsafe-of set-nth-unsafe-of
 755     ] if ; inline
 756
 757 : move-backward-of ( seq shift from to -- seq )
 758     2dup = [
 759         3drop
 760     ] [
 761         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 762     ] if ;
 763
 764 : open-slice-of ( seq shift from -- seq )
 765     over 0 = [
 766         2drop
 767     ] [
 768         [ ] [ drop [ length ] dip + ] 3bi
 769         [ pick length [ over - ] dip move-backward-of ] dip
 770         set-length-of
 771     ] if ;
 772
 773 PRIVATE>
 774
 775 ERROR: slice-error-of from to seq ;
 776
 777 : check-slice-of ( seq from to -- seq from to )
 778     over 0 < [ slice-error-of ] when
 779     dup reach length > [ slice-error-of ] when
 780     2dup > [ slice-error-of ] when ; inline
 781
 782 : delete-slice-of ( seq from to -- seq )
 783     check-slice-of over [ - ] dip open-slice-of ;
 784
 785 : remove-nth-of ( seq n -- seq' )
 786     [ dup 1 + rot snip-slice ] keepd append-as ;
 787
 788 : remove-nth-of* ( seq n -- nth seq' )
 789     [ nth-of ] [ remove-nth-of ] 2bi ;
 790
 791 : remove-nth-of! ( seq n -- seq )
 792     dup 1 + delete-slice-of ;
 793
 794 : remove-nth-of*! ( seq n -- nth seq )
 795     [ nth-of ] [ dup 1 + delete-slice-of ] 2bi ;
 796
 797 : snip-of ( seq from to -- head tail )
 798     [ head ] [ tail ] bi-curry* bi ; inline
 799
 800 : snip-slice-of ( seq from to -- head tail )
 801     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 802
 803 : index* ( seq obj -- n ) [ = ] curry find drop ;
 804
 805 : index-from* ( i seq obj -- n )
 806     [ = ] curry find-from drop ;
 807
 808 : last-index* ( seq obj -- n )
 809     [ = ] curry find-last drop ;
 810
 811 : last-index-from* ( i seq obj -- n )
 812     [ = ] curry find-last-from drop ;
 813
 814 : indices* ( seq obj -- indices )
 815     [ = ] curry [ swap ] prepose V{ } clone [
 816         [ push ] curry [ [ drop ] if ] curry compose each-index
 817     ] keep ;
 818
 819 : remove-first ( obj seq -- seq' )
 820     [ index ] keep over [ remove-nth ] [ nip ] if ;
 821
 822 : remove-first-of ( seq obj -- seq' )
 823     dupd index* [ remove-nth-of ] when* ;
 824
 825 : remove-first! ( obj seq -- seq )
 826     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 827
 828 : remove-last ( obj seq -- seq' )
 829     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 830
 831 : remove-last! ( obj seq -- seq )
 832     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 833
 834 : member-of? ( seq elt -- ? )
 835     [ = ] curry any? ;
 836
 837 : member-eq-of? ( seq elt -- ? )
 838     [ eq? ] curry any? ;
 839
 840 : remove-of ( seq elt -- newseq )
 841     [ = ] curry reject ;
 842
 843 : remove-eq-of ( seq elt -- newseq )
 844     [ eq? ] curry reject ;
 845
 846 : ?first2 ( seq -- first/f second/f )
 847     dup length {
 848         { 0 [ drop f f ] }
 849         { 1 [ first-unsafe f ] }
 850         [ drop first2-unsafe ]
 851     } case ;
 852
 853 : ?first3 ( seq -- first/f second/f third/f )
 854     dup length {
 855         { 0 [ drop f f f ] }
 856         { 1 [ first-unsafe f f ] }
 857         { 2 [ first2-unsafe f ] }
 858         [ drop first3-unsafe ]
 859     } case ;
 860
 861 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 862     dup length {
 863         { 0 [ drop f f f f ] }
 864         { 1 [ first-unsafe f f f ] }
 865         { 2 [ first2-unsafe f f ] }
 866         { 3 [ first3-unsafe f ] }
 867         [ drop first4-unsafe ]
 868     } case ;
 869
 870 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 871     [ find drop ] keepd swap
 872     [ cut ] [ f over like ] if* ; inline
 873
 874 : ?cut ( seq n -- before after ) [ index-or-length head ] [ index-or-length tail ] 2bi ;
 875
 876 : nth* ( n seq -- elt )
 877     [ length 1 - swap - ] [ nth ] bi ; inline
 878
 879 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 880     -rot sequence-index-operator each-integer-from ; inline
 881
 882 <PRIVATE
 883
 884 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 885     [
 886         [ keep swap ] curry [ dip ] curry
 887         [ [ first 0 ] dip call ] 2keep
 888         [ 2curry 3dip 5 npick pick ] curry
 889     ] [
 890         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 891     ] bi* compose 1 each-index-from nip swap ; inline
 892
 893 PRIVATE>
 894
 895 : maximum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 896     [ after? ] select-by* ; inline
 897
 898 : minimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 899     [ before? ] select-by* ; inline
 900
 901 ALIAS: supremum-by* maximum-by* deprecated
 902 ALIAS: infimum-by* minimum-by* deprecated
 903
 904 : arg-max ( seq -- n )
 905     [ ] maximum-by* drop ;
 906
 907 : arg-min ( seq -- n )
 908     [ ] minimum-by* drop ;
 909
 910 : ?maximum ( seq/f -- elt/f )
 911     [ f ] [
 912         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 913     ] if-empty ;
 914
 915 : ?minimum ( seq/f -- elt/f )
 916     [ f ] [
 917         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 918     ] if-empty ;
 919
 920 ALIAS: ?supremum ?maximum deprecated
 921 ALIAS: ?infimum ?minimum deprecated
 922
 923 : map-minimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 924     [ min ] map-reduce ; inline
 925
 926 : map-maximum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 927     [ max ] map-reduce ; inline
 928
 929 ALIAS: map-supremum map-maximum deprecated
 930 ALIAS: map-infimum map-minimum deprecated
 931
 932 : change-last ( seq quot -- )
 933     [ index-of-last ] [ change-nth ] bi* ; inline
 934
 935 : change-last-unsafe ( seq quot -- )
 936     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 937
 938 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 939     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 940
 941 : percent-of ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 942     over length 0 =
 943     [ 2drop 0 ]
 944     [ over [ count ] [ length ] bi* / ] if ; inline
 945
 946 : sequence-index-operator-last ( n seq quot -- n quot' )
 947     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 948
 949 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 950     '[
 951         _ [ sequence-index-operator-last find-last-integer ] keepd
 952         index/element
 953     ] bounds-check-call ; inline
 954
 955 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 956     [ index-of-last ] dip find-last-index-from ; inline
 957
 958 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 959     [ find-last-index ] (map-find-index) ; inline
 960
 961 :: (start-all) ( seq subseq increment -- indices )
 962     0
 963     [ seq subseq subseq-index-from dup ]
 964     [ [ increment + ] keep ] produce nip ;
 965
 966 : start-all ( seq subseq -- indices )
 967     dup length (start-all) ; inline
 968
 969 : start-all* ( seq subseq -- indices )
 970     1 (start-all) ; inline
 971
 972 : count-subseq ( seq subseq -- n )
 973     start-all length ; inline
 974
 975 : count-subseq* ( seq subseq -- n )
 976     start-all* length ; inline
 977
 978 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 979     '[ _ 2keep 2array swap ] assoc-map ; inline
 980
 981 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 982     [ '[ @ not ] find drop ] keepd swap
 983     [ dup length ] unless* head-slice ; inline
 984
 985 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 986     [ '[ @ not ] find drop ] keepd swap
 987     [ dup length ] unless* tail-slice ; inline
 988
 989 : count-head ( seq quot -- n )
 990     [ not ] compose [ find drop ] keepd length or ; inline
 991
 992 : count-tail ( seq quot -- n )
 993     [ not ] compose [ find-last drop ] keepd
 994     length swap [ - 1 - ] when* ; inline
 995
 996 : count= ( ... seq quot: ( ... elt -- ... ? ) n -- ... ? )
 997     [ 0 ] 3dip [
 998         '[ swap _ dip swap [ 1 + ] when dup _ > ] find 2drop
 999     ] keep = ; inline
1000
1001 :: shorten* ( vector n -- seq )
1002     vector n tail
1003     n vector shorten ;
1004
1005 :: interleaved-as ( seq glue exemplar -- newseq )
1006     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
1007     seq [ 2 * newseq set-nth-unsafe ] each-index
1008     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
1009     newseq ;
1010
1011 : interleaved ( seq glue -- newseq )
1012     over interleaved-as ;
1013
1014 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
1015     [ dup ] compose over [ length ] keep new-resizable
1016     [ [ push-when ] 2curry reject! ] keep swap like ; inline
1017
1018 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
1019     2pick < [
1020         [ nipd call ] 4keep
1021         3 7 0 nrotated
1022         [ [ 3drop ] 2dip rot ]
1023         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
1024     ] [
1025         4drop f f f
1026     ] if ; inline recursive
1027
1028 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
1029     [ 0 ] 3dip
1030     [ [ length check-length ] keep ] 2dip
1031     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
1032
1033 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
1034 ! Kadane's algorithm O(n) largest sum in subarray
1035 : max-subarray-sum ( seq -- sum )
1036     [ -1/0. ] dip
1037     [ [ + ] keep max [ max ] keep ] 0reduce drop ;
1038
1039 TUPLE: step-slice
1040     { from integer read-only initial: 0 }
1041     { to integer read-only initial: 0 }
1042     { seq read-only }
1043     { step integer read-only } ;
1044
1045 :: <step-slice> ( from/f to/f step seq -- step-slice )
1046     step zero? [ "can't be zero" throw ] when
1047     seq length :> len
1048     step 0 > [
1049         from/f [ 0 ] unless*
1050         to/f [ len ] unless*
1051     ] [
1052         from/f [ len ] unless*
1053         to/f [ 0 ] unless*
1054     ] if
1055     [ dup 0 < [ len + ] when 0 len clamp ] bi@
1056     ! FIXME: make this work with steps
1057     seq dup slice? [ collapse-slice ] when
1058     step step-slice boa ;
1059
1060 M: step-slice virtual@
1061     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
1062
1063 M: step-slice length
1064     [ to>> ] [ from>> - ] [ step>> ] tri
1065     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
1066     zero? [ 1 + ] unless ; inline
1067
1068 INSTANCE: step-slice wrapped-sequence
1069
1070 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
1071     '[
1072         _ keep swap _ with each
1073     ] each ; inline
1074
1075 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
1076     [ 2over [ length ] bi@ * ] dip
1077     [
1078         new-resizable
1079         [ [ maybe-push ] curry compose 2nested-each* ] keep
1080     ] keep like ; inline
1081
1082 : 2nested-filter* ( seq1 seq-quot quot -- seq )
1083     pick 2nested-filter-as* ; inline
1084
1085 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
1086     [ 2over [ length ] bi@ * ] dip
1087     [
1088         new-resizable
1089         [ [ push ] curry compose 2nested-each* ] keep
1090     ] keep like ; inline
1091
1092 : 2nested-map* ( seq1 seq-quot quot -- seq )
1093     pick 2nested-map-as* ; inline
1094
1095
1096 : 2nested-each ( seq1 seq2 quot -- )
1097     swapd '[
1098         swap _ with each
1099     ] with each ; inline
1100
1101 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1102     [ 2over [ length ] bi@ * ] dip
1103     [
1104         new-resizable
1105         [ [ maybe-push ] curry compose 2nested-each ] keep
1106     ] keep like ; inline
1107
1108 : 2nested-filter ( seq1 seq2 quot -- seq )
1109     pick 2nested-filter-as ; inline
1110
1111 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1112     [ 2over [ length ] bi@ * ] dip
1113     [
1114         new-resizable
1115         [ [ push ] curry compose 2nested-each ] keep
1116     ] keep like ; inline
1117
1118 : 2nested-map ( seq1 seq2 quot -- seq )
1119     pick 2nested-map-as ; inline
1120
1121 : 3nested-each ( seq1 seq2 seq3 quot -- )
1122     spind '[
1123         -rot [
1124             swap _ with with each
1125         ] with with each
1126     ] with with each ; inline
1127
1128 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1129     [ 3 nover [ length ] tri@ * * ] dip
1130     [
1131         new-resizable
1132         [ [ maybe-push ] curry compose 3nested-each ] keep
1133     ] keep like ; inline
1134
1135 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1136     reach 3nested-filter-as ; inline
1137
1138 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1139     [ 3 nover [ length ] tri@ * * ] dip
1140     [
1141         new-resizable
1142         [ [ push ] curry compose 3nested-each ] keep
1143     ] keep like ; inline
1144
1145 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1146     reach 3nested-map-as ; inline
1147
1148 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1149 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1150 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1151 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1152 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1153 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1154
1155 : prev-identity ( i seq -- identity i seq )
1156     2dup ??prev [ drop 0 ] unless -rot ; inline
1157
1158 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1159     '[ [ swap @ ] keep ]
1160     length-operator each-integer-from drop ; inline
1161
1162 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1163     [ prev-identity ] dip each-prior-identity-from ; inline
1164
1165 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1166     0 -rot each-prior-from ; inline
1167
1168 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1169     [
1170         '[ [ swap @ ] keep swap ] length-operator
1171     ] dip map-integers-from-as nip ; inline
1172
1173 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1174     [ 0 ] 3dip map-prior-identity-from-as ; inline
1175
1176 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1177     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1178
1179 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1180     0 -roll map-prior-from-as ; inline
1181
1182 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1183     over map-prior-from-as ; inline
1184
1185 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1186     over map-prior-as ; inline
1187
1188 TUPLE: virtual-zip-index seq ;
1189
1190 C: <zip-index> virtual-zip-index
1191
1192 M: virtual-zip-index length seq>> length ; inline
1193
1194 M: virtual-zip-index nth-unsafe
1195     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1196
1197 INSTANCE: virtual-zip-index immutable-sequence
1198
1199 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
1200     [ call ] dip swap [ push ] [ 2drop ] if ; inline
1201
1202 : fry-map-as ( seq quot exemplar -- newseq )
1203     [ 2drop length ]
1204     [ overd new-sequence-like dup ] 3bi
1205     '[ [ [ _ nth-unsafe @ ] [ _ set-nth-unsafe ] bi ] each-integer _ ] call ; inline
1206
1207 : exchange-subseq ( len pos1 pos2 seq -- )
1208     [ [ assert-non-negative ] tri@ 3dup max + 1 - ] dip bounds-check nip '[
1209         2dup _ exchange-unsafe
1210         [ 1 - ] [ 1 + ] [ 1 + ] tri*
1211     ] [ pick 0 > ] swap while 3drop ;
1212
1213 : sequence-cartesian-product ( seqs -- seqs' )
1214     dup length 1 <= [
1215         [ [ 1array ] map ] map concat
1216     ] [
1217         2 cut [ first2 cartesian-product concat ] dip swap
1218         [ [ suffix ] cartesian-map concat ] reduce
1219     ] if ;