extra/sequences/modified/modified.factor

   1 ! Copyright (C) 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel locals math sequences
   4 sequences.private ;
   5 IN: sequences.modified
   6
   7 TUPLE: modified ;
   8
   9 GENERIC: modified-nth ( n seq -- elt )
  10
  11 M: modified nth modified-nth ;
  12 M: modified nth-unsafe modified-nth ;
  13
  14 GENERIC: modified-set-nth ( elt n seq -- )
  15
  16 M: modified set-nth modified-set-nth ;
  17 M: modified set-nth-unsafe modified-set-nth ;
  18
  19 INSTANCE: modified virtual-sequence
  20
  21 TUPLE: 1modified < modified seq ;
  22
  23 M: 1modified length seq>> length ;
  24 M: 1modified set-length seq>> set-length ;
  25 M: 1modified virtual-exemplar seq>> ;
  26
  27 TUPLE: scaled < 1modified c ;
  28
  29 C: <scaled> scaled
  30
  31 : scale ( seq c -- new-seq )
  32     dupd <scaled> swap like ;
  33
  34 M: scaled modified-nth
  35     [ seq>> nth ] [ c>> * ] bi ;
  36
  37 M: scaled modified-set-nth
  38     ! don't set c to 0!
  39     [ nip c>> / ] [ seq>> set-nth ] 2bi ;
  40
  41 TUPLE: offset < 1modified n ;
  42
  43 C: <offset> offset
  44
  45 : seq-offset ( seq n -- new-seq )
  46     dupd <offset> swap like ;
  47
  48 M: offset modified-nth
  49     [ seq>> nth ] [ n>> + ] bi ;
  50
  51 M: offset modified-set-nth
  52     [ nip n>> - ] [ seq>> set-nth ] 2bi ;
  53
  54 TUPLE: summed < modified seqs ;
  55
  56 C: <summed> summed
  57
  58 M: summed length seqs>> longest length ;
  59
  60 M: summed modified-nth
  61     seqs>> [ ?nth [ + ] when* ] with 0 swap reduce ;
  62
  63 M: summed modified-set-nth immutable ;
  64
  65 M: summed set-length
  66     seqs>> [ set-length ] with each ;
  67
  68 M: summed virtual-exemplar
  69     seqs>> ?first ;
  70
  71 : <2summed> ( seq seq -- summed-seq ) 2array <summed> ;
  72
  73 : <3summed> ( seq seq seq -- summed-seq ) 3array <summed> ;