extra/shapefiles/shapefiles.factor

   1 ! Copyright (C) 2018 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: arrays combinators io io.binary.fast io.encodings.binary
   5 io.files kernel math sequences ;
   6
   7 IN: shapefiles
   8
   9 <PRIVATE
  10
  11 : read-int ( -- n )
  12     4 read le> ;
  13
  14 : read-ints ( n -- parts )
  15     [ read-int ] replicate ;
  16
  17 : read-double ( -- n )
  18     8 read le> bits>double ;
  19
  20 : read-doubles ( n -- array )
  21     [ read-double ] replicate ;
  22
  23 : read-box ( -- box )
  24     4 read-doubles ;
  25
  26 : read-range ( -- range )
  27     2 read-doubles ;
  28
  29 PRIVATE>
  30
  31 TUPLE: header file-code file-length version shape-type x-min
  32 y-min x-max y-max z-min z-max m-min m-max ;
  33
  34 : read-header ( -- header )
  35     4 read be> dup 9994 assert=
  36     20 read drop ! unused
  37     4 read be>
  38     read-int dup 1000 assert=
  39     read-int
  40     read-double
  41     read-double
  42     read-double
  43     read-double
  44     read-double
  45     read-double
  46     read-double
  47     read-double
  48     header boa ;
  49
  50 SINGLETON: null-shape
  51
  52 TUPLE: point x y ;
  53
  54 : read-point ( -- point )
  55     read-double read-double point boa ;
  56
  57 : read-points ( n -- points )
  58     [ read-point ] replicate ;
  59
  60 TUPLE: multipoint box points ;
  61
  62 : read-multipoint ( -- multipoint )
  63     read-box read-int read-points multipoint boa ;
  64
  65 TUPLE: polyline box parts points ;
  66
  67 : read-polyline ( -- polyline )
  68     read-box read-int read-int [ read-ints ] dip
  69     read-points polyline boa ;
  70
  71 TUPLE: polygon box parts points ;
  72
  73 : read-polygon ( -- polygon )
  74     read-box read-int read-int [ read-ints ] dip
  75     read-points polygon boa ;
  76
  77 TUPLE: point-m x y m ;
  78
  79 : read-point-m ( -- point-m )
  80     read-double read-double read-double point-m boa ;
  81
  82 TUPLE: multipoint-m box points m-range m-array ;
  83
  84 : read-multipoint-m ( -- multipoint-m )
  85     read-box read-int
  86     [ read-points read-range ] [ read-doubles ] bi
  87     multipoint-m boa ;
  88
  89 TUPLE: polyline-m box parts points m-range m-array ;
  90
  91 : read-polyline-m ( -- polyline-m )
  92     read-box read-int read-int [ read-ints ] dip
  93     [ read-points read-range ] [ read-doubles ] bi
  94     polyline-m boa ;
  95
  96 TUPLE: polygon-m box parts points m-range m-array ;
  97
  98 : read-polygon-m ( -- polygon-m )
  99     read-box read-int read-int [ read-ints ] dip
 100     [ read-points read-range ] [ read-doubles ] bi
 101     polygon-m boa ;
 102
 103 TUPLE: point-z x y z m ;
 104
 105 : read-point-z ( -- point-z )
 106     read-double read-double read-double read-double point-z boa ;
 107
 108 TUPLE: multipoint-z box points z-range z-array m-range m-array ;
 109
 110 : read-multipoint-z ( -- multipoint-z )
 111     read-box read-int
 112     [ read-points read-range ]
 113     [ read-doubles read-range ]
 114     [ read-doubles ] tri multipoint-z boa ;
 115
 116 TUPLE: polyline-z box parts points z-range z-array m-range
 117 m-array ;
 118
 119 : read-polyline-z ( -- polyline-z )
 120     read-box read-int read-int [ read-ints ] dip
 121     [ read-points read-range ]
 122     [ read-doubles read-range ]
 123     [ read-doubles ] tri polyline-z boa ;
 124
 125 TUPLE: polygon-z box parts points z-range z-array m-range
 126 m-array ;
 127
 128 : read-polygon-z ( -- polygon-z )
 129     read-box read-int read-int [ read-ints ] dip
 130     [ read-points read-range ]
 131     [ read-doubles read-range ]
 132     [ read-doubles ] tri polygon-z boa ;
 133
 134 TUPLE: multipatch box parts points part-types z-range z-array
 135 m-range m-array ;
 136
 137 : read-multipatch ( -- multipatch )
 138     read-box read-int read-int
 139     [ [ read-ints ] [ read-ints ] bi ] dip
 140     [ read-points read-range ]
 141     [ read-doubles read-range ]
 142     [ read-doubles ] tri multipatch boa ;
 143
 144 : read-shape ( -- shape )
 145     4 read le> {
 146         { 0 [ null-shape ] }
 147         { 1 [ read-point ] }
 148         { 3 [ read-polyline ] }
 149         { 5 [ read-polygon ] }
 150         { 8 [ read-multipoint ] }
 151         { 11 [ read-point-z ] }
 152         { 13 [ read-polyline-z ] }
 153         { 15 [ read-polygon-z ] }
 154         { 18 [ read-multipoint-z ] }
 155         { 21 [ read-point-m ] }
 156         { 23 [ read-polyline-m ] }
 157         { 25 [ read-polygon-m ] }
 158         { 28 [ read-multipoint-m ] }
 159         { 31 [ read-multipatch ] }
 160     } case ;
 161
 162 TUPLE: record number content-length shape ;
 163
 164 : read-record ( -- record/f )
 165     4 read [ be> 4 read be> read-shape record boa ] [ f ] if* ;
 166
 167 : read-records ( -- records )
 168     [ read-record dup ] [ ] produce nip ;
 169
 170 : read-shp ( -- header records )
 171     read-header read-records ;
 172
 173 : file>shp ( path -- header records )
 174     binary [ read-shp ] with-file-reader ;
 175
 176 TUPLE: index offset content-length ;
 177
 178 : read-index ( -- index/f )
 179     4 read [ be> 4 read be> index boa ] [ f ] if* ;
 180
 181 : read-indices ( -- indices )
 182     [ read-index dup ] [ ] produce nip ;
 183
 184 : read-shx ( -- header indices )
 185     read-header read-indices ;
 186
 187 : file>shx ( path -- header indices )
 188     binary [ read-shx ] with-file-reader ;