extra/slides/slides.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays hashtables help.markup help.stylesheet io
   4 io.styles kernel math models namespaces sequences ui ui.gadgets
   5 ui.gadgets.books ui.gadgets.panes ui.gestures ui.pens.gradient
   6 parser accessors colors fry ;
   7 IN: slides
   8
   9 CONSTANT: stylesheet
  10     H{
  11         { default-span-style
  12             H{
  13                 { font-name "sans-serif" }
  14                 { font-size 36 }
  15             }
  16         }
  17         { default-block-style
  18             H{
  19                 { wrap-margin 1100 }
  20             }
  21         }
  22         { code-style
  23             H{
  24                 { font-name "monospace" }
  25                 { font-size 36 }
  26                 { page-color T{ rgba f 0.4 0.4 0.4 0.3 } }
  27             }
  28         }
  29         { snippet-style
  30             H{
  31                 { font-name "monospace" }
  32                 { font-size 36 }
  33                 { foreground T{ rgba f 0.1 0.1 0.4 1 } }
  34             }
  35         }
  36         { table-content-style
  37             H{ { wrap-margin 1000 } }
  38         }
  39         { list-style
  40             H{ { table-gap { 10 20 } } }
  41         }
  42     }
  43
  44 : $title ( string -- )
  45     [ H{ { font-name "sans-serif" } { font-size 48 } } format ] ($block) ;
  46
  47 : $divider ( -- )
  48     [
  49         <gadget>
  50         {
  51             T{ rgba f 0.25 0.25 0.25 1.0 }
  52             T{ rgba f 1.0 1.0 1.0 0.0 }
  53         } <gradient> >>interior
  54         { 800 10 } >>dim
  55         { 1 0 } >>orientation
  56         gadget.
  57     ] ($block) ;
  58
  59 : page-theme ( gadget -- )
  60     { T{ rgba f 0.8 0.8 1.0 1.0 } T{ rgba f 0.8 1.0 1.0 1.0 } } <gradient>
  61     >>interior drop ;
  62
  63 : <page> ( list -- gadget )
  64     [
  65         stylesheet clone [
  66             [ print-element ] with-default-style
  67         ] bind
  68     ] make-pane
  69     dup page-theme ;
  70
  71 : $slide ( element -- )
  72     unclip $title
  73     $divider
  74     $list ;
  75
  76 TUPLE: slides < book ;
  77
  78 : <slides> ( slides -- gadget )
  79     0 <model> slides new-book [ <page> add-gadget ] reduce ;
  80
  81 : change-page ( book n -- )
  82     over control-value + over children>> length rem
  83     swap model>> set-model ;
  84
  85 : next-page ( book -- ) 1 change-page ;
  86
  87 : prev-page ( book -- ) -1 change-page ;
  88
  89 : (strip-tease) ( data n -- data )
  90     [ first3 ] dip head 3array ;
  91
  92 : strip-tease ( data -- seq )
  93     dup third length 1 - [
  94         2 + (strip-tease)
  95     ] with map ;
  96
  97 SYNTAX: STRIP-TEASE:
  98     parse-definition strip-tease [ parsed ] each ;
  99
 100 \ slides H{
 101     { T{ button-down } [ request-focus ] }
 102     { T{ key-down f f "DOWN" } [ next-page ] }
 103     { T{ key-down f f "UP" } [ prev-page ] }
 104 } set-gestures
 105
 106 : slides-window ( slides -- )
 107     '[ _ <slides> "Slides" open-window ] with-ui ;