extra/smalltalk/parser/parser-tests.factor

   1 IN: smalltalk.parser.tests
   2 USING: smalltalk.parser smalltalk.ast peg.ebnf tools.test accessors
   3 io.files io.encodings.ascii kernel ;
   4
   5 EBNF: test-Character
   6 test         = <foreign parse-smalltalk Character>
   7 ;EBNF
   8
   9 [ CHAR: a ] [ "a" test-Character ] unit-test
  10
  11 EBNF: test-Comment
  12 test         = <foreign parse-smalltalk Comment>
  13 ;EBNF
  14
  15 [ T{ ast-comment f "Hello, this is a comment." } ]
  16 [ "\"Hello, this is a comment.\"" test-Comment ]
  17 unit-test
  18
  19 [ T{ ast-comment f "Hello, \"this\" is a comment." } ]
  20 [ "\"Hello, \"\"this\"\" is a comment.\"" test-Comment ]
  21 unit-test
  22
  23 EBNF: test-Identifier
  24 test         = <foreign parse-smalltalk Identifier>
  25 ;EBNF
  26
  27 [ "OrderedCollection" ] [ "OrderedCollection" test-Identifier ] unit-test
  28
  29 EBNF: test-Literal
  30 test         = <foreign parse-smalltalk Literal>
  31 ;EBNF
  32
  33 [ nil ] [ "nil" test-Literal ] unit-test
  34 [ 123 ] [ "123" test-Literal ] unit-test
  35 [ HEX: deadbeef ] [ "16rdeadbeef" test-Literal ] unit-test
  36 [ -123 ] [ "-123" test-Literal ] unit-test
  37 [ 1.2 ] [ "1.2" test-Literal ] unit-test
  38 [ -1.24 ] [ "-1.24" test-Literal ] unit-test
  39 [ 12.4e7 ] [ "12.4e7" test-Literal ] unit-test
  40 [ 12.4e-7 ] [ "12.4e-7" test-Literal ] unit-test
  41 [ -12.4e7 ] [ "-12.4e7" test-Literal ] unit-test
  42 [ CHAR: x ] [ "$x" test-Literal ] unit-test
  43 [ "Hello, world" ] [ "'Hello, world'" test-Literal ] unit-test
  44 [ "Hello, 'funny' world" ] [ "'Hello, ''funny'' world'" test-Literal ] unit-test
  45 [ T{ symbol f "foo" } ] [ "#foo" test-Literal ] unit-test
  46 [ T{ symbol f "+" } ] [ "#+" test-Literal ] unit-test
  47 [ T{ symbol f "at:put:" } ] [ "#at:put:" test-Literal ] unit-test
  48 [ T{ symbol f "Hello world" } ] [ "#'Hello world'" test-Literal ] unit-test
  49 [ B{ 1 2 3 4 } ] [ "#[1 2 3 4]" test-Literal ] unit-test
  50 [ { nil t f } ] [ "#(nil true false)" test-Literal ] unit-test
  51 [ { nil { t f } } ] [ "#(nil (true false))" test-Literal ] unit-test
  52 [ T{ ast-block f { } { } } ] [ "[]" test-Literal ] unit-test
  53 [ T{ ast-block f { "x" } { T{ ast-return f T{ ast-name f "x" } } } } ] [ "[ :x|^x]" test-Literal ] unit-test
  54 [ T{ ast-block f { } { T{ ast-return f self } } } ] [ "[^self]" test-Literal ] unit-test
  55
  56 [
  57     T{ ast-block
  58        { arguments { "i" } }
  59        { body
  60          {
  61              T{ ast-message-send
  62                 { receiver T{ ast-name { name "i" } } }
  63                 { selector "print" }
  64              }
  65          }
  66        }
  67     }
  68 ]
  69 [ "[ :i | i print ]" test-Literal ] unit-test
  70
  71 EBNF: test-FormalBlockArgumentDeclarationList
  72 test         = <foreign parse-smalltalk FormalBlockArgumentDeclarationList>
  73 ;EBNF
  74
  75 [ V{ "x" "y" "elt" } ] [ ":x :y :elt" test-FormalBlockArgumentDeclarationList ] unit-test
  76
  77 EBNF: test-Operand
  78 test         = <foreign parse-smalltalk Operand>
  79 ;EBNF
  80
  81 [ { 123 15.6 { t f } } ] [ "#(123 15.6 (true false))" test-Operand ] unit-test
  82 [ T{ ast-name f "x" } ] [ "x" test-Operand ] unit-test
  83
  84 EBNF: test-Expression
  85 test         = <foreign parse-smalltalk Expression>
  86 ;EBNF
  87
  88 [ self ] [ "self" test-Expression ] unit-test
  89 [ { 123 15.6 { t f } } ] [ "#(123 15.6 (true false))" test-Expression ] unit-test
  90 [ T{ ast-name f "x" } ] [ "x" test-Expression ] unit-test
  91 [ T{ ast-message-send f 5 "print" { } } ] [ "5 print" test-Expression ] unit-test
  92 [ T{ ast-message-send f T{ ast-message-send f 5 "squared" { } } "print" { } } ] [ "5 squared print" test-Expression ] unit-test
  93 [ T{ ast-message-send f 2 "+" { 2 } } ] [ "2+2" test-Expression ] unit-test
  94
  95 [
  96     T{ ast-message-send f
  97         T{ ast-message-send f 3 "factorial" { } }
  98         "+"
  99         { T{ ast-message-send f 4 "factorial" { } } }
 100     }
 101 ]
 102 [ "3 factorial + 4 factorial" test-Expression ] unit-test
 103
 104 [
 105     T{ ast-message-send f
 106         T{ ast-message-send f 3 "factorial" { } }
 107         "+"
 108         { T{ ast-message-send f 4 "factorial" { } } }
 109     }
 110 ]
 111 [ "   3 factorial + 4 factorial" test-Expression ] unit-test
 112
 113 [
 114     T{ ast-message-send f
 115         T{ ast-message-send f 3 "factorial" { } }
 116         "+"
 117         { T{ ast-message-send f 4 "factorial" { } } }
 118     }
 119 ]
 120 [ "   3 factorial + 4 factorial     " test-Expression ] unit-test
 121
 122 [
 123     T{ ast-message-send f
 124         T{ ast-message-send f
 125             T{ ast-message-send f 3 "factorial" { } }
 126             "+"
 127             { 4 }
 128         }
 129         "factorial"
 130         { }
 131     }
 132 ]
 133 [ "(3 factorial + 4) factorial" test-Expression ] unit-test
 134
 135 [
 136     T{ ast-message-send
 137        { receiver
 138          T{ ast-message-send
 139             { receiver
 140               T{ ast-message-send
 141                  { receiver 1 }
 142                  { selector "<" }
 143                  { arguments { 10 } }
 144               }
 145             }
 146             { selector "ifTrue:ifFalse:" }
 147             { arguments
 148               {
 149                   T{ ast-block { body { "HI" } } }
 150                   T{ ast-block { body { "BYE" } } }
 151               }
 152             }
 153          }
 154        }
 155        { selector "print" }
 156     }
 157 ]
 158 [ "((1 < 10) ifTrue: [ 'HI' ] ifFalse: [ 'BYE' ]) print" test-Expression ] unit-test
 159
 160 [
 161     T{ ast-message-send
 162        { receiver
 163          T{ ast-message-send
 164             { receiver { T{ ast-block { body { "a" } } } } }
 165             { selector "at:" }
 166             { arguments { 0 } }
 167          }
 168        }
 169        { selector "value" }
 170     }
 171 ]
 172 [ "(#(['a']) at: 0) value" test-Expression ] unit-test
 173
 174 EBNF: test-FinalStatement
 175 test         = <foreign parse-smalltalk FinalStatement>
 176 ;EBNF
 177
 178 [ T{ ast-name f "value" } ] [ "value" test-FinalStatement ] unit-test
 179 [ T{ ast-return f T{ ast-name f "value" } } ] [ "^value" test-FinalStatement ] unit-test
 180 [ T{ ast-assignment f T{ ast-name f "value" } 5 } ] [ "value:=5" test-FinalStatement ] unit-test
 181
 182 EBNF: test-LocalVariableDeclarationList
 183 test         = <foreign parse-smalltalk LocalVariableDeclarationList>
 184 ;EBNF
 185
 186 [ T{ ast-local-variables f { "i" "j" } } ] [ " |  i j   |" test-LocalVariableDeclarationList ] unit-test
 187
 188
 189 EBNF: test-KeywordMessageSend
 190 test         = <foreign parse-smalltalk KeywordMessageSend>
 191 ;EBNF
 192
 193 [ T{ ast-message-send f T{ ast-name f "x" } "foo:bar:" { 1 2 } } ]
 194 [ "x foo:1 bar:2" test-KeywordMessageSend ] unit-test
 195
 196 [
 197     T{ ast-message-send
 198         f
 199         T{ ast-message-send f
 200             T{ ast-message-send f 3 "factorial" { } }
 201             "+"
 202             { T{ ast-message-send f 4 "factorial" { } } }
 203         }
 204         "between:and:"
 205         { 10 100 }
 206     }
 207 ]
 208 [ "3 factorial + 4 factorial between: 10 and: 100" test-KeywordMessageSend ] unit-test
 209
 210 [ ] [ "vocab:smalltalk/parser/test.st" ascii file-contents parse-smalltalk drop ] unit-test