extra/spheres/spheres.factor

   1 USING: kernel opengl opengl.demo-support opengl.gl opengl.textures
   2 opengl.shaders opengl.framebuffers opengl.capabilities multiline
   3 ui.gadgets accessors sequences ui.render ui math locals arrays
   4 generalizations combinators ui.gadgets.worlds
   5 literals ui.pixel-formats ;
   6 IN: spheres
   7
   8 STRING: plane-vertex-shader
   9 varying vec3 object_position;
  10 void
  11 main()
  12 {
  13     object_position = gl_Vertex.xyz;
  14     gl_Position = ftransform();
  15 }
  16 ;
  17
  18 STRING: plane-fragment-shader
  19 uniform float checker_size_inv;
  20 uniform vec4 checker_color_1, checker_color_2;
  21 varying vec3 object_position;
  22
  23 bool
  24 checker_color(vec3 p)
  25 {
  26     vec3 pprime = checker_size_inv * object_position;
  27     return fract((floor(pprime.x) + floor(pprime.z)) * 0.5) == 0.0;
  28 }
  29
  30 void
  31 main()
  32 {
  33     float distance_factor = (gl_FragCoord.z * 0.5 + 0.5);
  34     distance_factor = pow(distance_factor, 500.0)*0.5;
  35
  36     gl_FragColor = checker_color(object_position)
  37         ? mix(checker_color_1, checker_color_2, distance_factor)
  38         : mix(checker_color_2, checker_color_1, distance_factor);
  39 }
  40 ;
  41
  42 STRING: sphere-vertex-shader
  43 attribute vec3 center;
  44 attribute float radius;
  45 attribute vec4 surface_color;
  46 varying float vradius;
  47 varying vec3 sphere_position;
  48 varying vec4 world_position, vcolor;
  49
  50 void
  51 main()
  52 {
  53     world_position = gl_ModelViewMatrix * vec4(center, 1);
  54     sphere_position = gl_Vertex.xyz;
  55
  56     gl_Position = gl_ProjectionMatrix * (world_position + vec4(sphere_position * radius, 0));
  57
  58     vcolor = surface_color;
  59     vradius = radius;
  60 }
  61 ;
  62
  63 STRING: sphere-solid-color-fragment-shader
  64 uniform vec3 light_position;
  65 varying vec4 vcolor;
  66
  67 const vec4 ambient = vec4(0.25, 0.2, 0.25, 1.0);
  68 const vec4 diffuse = vec4(0.75, 0.8, 0.75, 1.0);
  69
  70 vec4
  71 sphere_color(vec3 point, vec3 normal)
  72 {
  73     vec3 transformed_light_position = (gl_ModelViewMatrix * vec4(light_position, 1)).xyz;
  74     vec3 direction = normalize(transformed_light_position - point);
  75     float d = max(0.0, dot(normal, direction));
  76
  77     return ambient * vcolor + diffuse * vec4(d * vcolor.rgb, vcolor.a);
  78 }
  79 ;
  80
  81 STRING: sphere-texture-fragment-shader
  82 uniform samplerCube surface_texture;
  83
  84 vec4
  85 sphere_color(vec3 point, vec3 normal)
  86 {
  87     vec3 reflect = reflect(normalize(point), normal);
  88     return textureCube(surface_texture, reflect * gl_NormalMatrix);
  89 }
  90 ;
  91
  92 STRING: sphere-main-fragment-shader
  93 varying float vradius;
  94 varying vec3 sphere_position;
  95 varying vec4 world_position;
  96
  97 vec4 sphere_color(vec3 point, vec3 normal);
  98
  99 void
 100 main()
 101 {
 102         float radius = length(sphere_position);
 103         if(radius > 1.0) discard;
 104
 105         vec3 surface = sphere_position + vec3(0.0, 0.0, sqrt(1.0 - radius*radius));
 106         vec4 world_surface = world_position + vec4(surface * vradius, 0);
 107         vec4 transformed_surface = gl_ProjectionMatrix * world_surface;
 108
 109     gl_FragDepth = (transformed_surface.z/transformed_surface.w + 1.0) * 0.5;
 110         gl_FragColor = sphere_color(world_surface.xyz, surface);
 111 }
 112 ;
 113
 114 TUPLE: spheres-world < demo-world
 115     plane-program solid-sphere-program texture-sphere-program
 116     reflection-framebuffer reflection-depthbuffer
 117     reflection-texture ;
 118
 119 M: spheres-world near-plane
 120     drop 1.0 ;
 121 M: spheres-world far-plane
 122     drop 512.0 ;
 123 M: spheres-world distance-step
 124     drop 0.5 ;
 125
 126 : (reflection-dim) ( -- w h )
 127     512 512 ;
 128
 129 : (make-reflection-texture) ( -- texture )
 130     gen-texture [
 131         GL_TEXTURE_CUBE_MAP swap glBindTexture
 132         GL_TEXTURE_CUBE_MAP GL_TEXTURE_MAG_FILTER GL_LINEAR glTexParameteri
 133         GL_TEXTURE_CUBE_MAP GL_TEXTURE_MIN_FILTER GL_LINEAR glTexParameteri
 134         GL_TEXTURE_CUBE_MAP GL_TEXTURE_WRAP_S GL_CLAMP glTexParameteri
 135         GL_TEXTURE_CUBE_MAP GL_TEXTURE_WRAP_T GL_CLAMP glTexParameteri
 136         GL_TEXTURE_CUBE_MAP GL_TEXTURE_WRAP_R GL_CLAMP glTexParameteri
 137         ${
 138             GL_TEXTURE_CUBE_MAP_POSITIVE_X
 139             GL_TEXTURE_CUBE_MAP_POSITIVE_Y
 140             GL_TEXTURE_CUBE_MAP_POSITIVE_Z
 141             GL_TEXTURE_CUBE_MAP_NEGATIVE_X
 142             GL_TEXTURE_CUBE_MAP_NEGATIVE_Y
 143             GL_TEXTURE_CUBE_MAP_NEGATIVE_Z
 144         }
 145         [ 0 GL_RGBA8 (reflection-dim) 0 GL_RGBA GL_UNSIGNED_BYTE f glTexImage2D ]
 146         each
 147     ] keep ;
 148
 149 : (make-reflection-depthbuffer) ( -- depthbuffer )
 150     gen-renderbuffer [
 151         GL_RENDERBUFFER swap glBindRenderbuffer
 152         GL_RENDERBUFFER GL_DEPTH_COMPONENT32 (reflection-dim) glRenderbufferStorage
 153     ] keep ;
 154
 155 : (make-reflection-framebuffer) ( depthbuffer -- framebuffer )
 156     gen-framebuffer dup [
 157         swap [ GL_DRAW_FRAMEBUFFER GL_DEPTH_ATTACHMENT GL_RENDERBUFFER ] dip
 158         glFramebufferRenderbuffer
 159     ] with-framebuffer ;
 160
 161 : (plane-program) ( -- program )
 162     plane-vertex-shader plane-fragment-shader <simple-gl-program> ;
 163 : (solid-sphere-program) ( -- program )
 164     sphere-vertex-shader <vertex-shader> check-gl-shader
 165     sphere-solid-color-fragment-shader <fragment-shader> check-gl-shader
 166     sphere-main-fragment-shader <fragment-shader> check-gl-shader
 167     3array <gl-program> check-gl-program ;
 168 : (texture-sphere-program) ( -- program )
 169     sphere-vertex-shader <vertex-shader> check-gl-shader
 170     sphere-texture-fragment-shader <fragment-shader> check-gl-shader
 171     sphere-main-fragment-shader <fragment-shader> check-gl-shader
 172     3array <gl-program> check-gl-program ;
 173
 174 M: spheres-world begin-world
 175     "2.0" { "GL_ARB_shader_objects" } require-gl-version-or-extensions
 176     { "GL_EXT_framebuffer_object" } require-gl-extensions
 177     GL_DEPTH_TEST glEnable
 178     GL_VERTEX_ARRAY glEnableClientState
 179     0.15 0.15 1.0 1.0 glClearColor
 180     20.0 10.0 20.0 set-demo-orientation
 181     (plane-program) >>plane-program
 182     (solid-sphere-program) >>solid-sphere-program
 183     (texture-sphere-program) >>texture-sphere-program
 184     (make-reflection-texture) >>reflection-texture
 185     (make-reflection-depthbuffer) [ >>reflection-depthbuffer ] keep
 186     (make-reflection-framebuffer) >>reflection-framebuffer
 187     drop ;
 188
 189 M: spheres-world end-world
 190     {
 191         [ reflection-framebuffer>> [ delete-framebuffer ] when* ]
 192         [ reflection-depthbuffer>> [ delete-renderbuffer ] when* ]
 193         [ reflection-texture>> [ delete-texture ] when* ]
 194         [ solid-sphere-program>> [ delete-gl-program ] when* ]
 195         [ texture-sphere-program>> [ delete-gl-program ] when* ]
 196         [ plane-program>> [ delete-gl-program ] when* ]
 197     } cleave ;
 198
 199 M: spheres-world pref-dim*
 200     drop { 640 480 } ;
 201
 202 :: (draw-sphere) ( program center radius -- )
 203     program "center" glGetAttribLocation center first3 glVertexAttrib3f
 204     program "radius" glGetAttribLocation radius glVertexAttrib1f
 205     { -1.0 -1.0 } { 2.0 2.0 } gl-fill-rect ;
 206
 207 :: (draw-colored-sphere) ( program center radius surfacecolor -- )
 208     program "surface_color" glGetAttribLocation surfacecolor first4 glVertexAttrib4f
 209     program center radius (draw-sphere) ;
 210
 211 : sphere-scene ( gadget -- )
 212     GL_DEPTH_BUFFER_BIT GL_COLOR_BUFFER_BIT bitor glClear
 213     [
 214         solid-sphere-program>> [
 215             {
 216                 [ "light_position" glGetUniformLocation 0.0 0.0 100.0 glUniform3f ]
 217                 [ {  7.0  0.0  0.0 } 1.0 { 1.0 0.0 0.0 1.0 } (draw-colored-sphere) ]
 218                 [ { -7.0  0.0  0.0 } 1.0 { 0.0 1.0 0.0 1.0 } (draw-colored-sphere) ]
 219                 [ {  0.0  0.0  7.0 } 1.0 { 0.0 0.0 1.0 1.0 } (draw-colored-sphere) ]
 220                 [ {  0.0  0.0 -7.0 } 1.0 { 1.0 1.0 0.0 1.0 } (draw-colored-sphere) ]
 221                 [ {  0.0  7.0  0.0 } 1.0 { 1.0 0.0 1.0 1.0 } (draw-colored-sphere) ]
 222                 [ {  0.0 -7.0  0.0 } 1.0 { 0.0 1.0 1.0 1.0 } (draw-colored-sphere) ]
 223             } cleave
 224         ] with-gl-program
 225     ] [
 226         plane-program>> [
 227             {
 228                 [ "checker_size_inv" glGetUniformLocation 0.125 glUniform1f ]
 229                 [ "checker_color_1"  glGetUniformLocation 1.0 0.0 0.0 1.0 glUniform4f ]
 230                 [ "checker_color_2"  glGetUniformLocation 1.0 1.0 1.0 1.0 glUniform4f ]
 231             } cleave
 232             GL_QUADS [
 233                 -1000.0 -30.0  1000.0 glVertex3f
 234                 -1000.0 -30.0 -1000.0 glVertex3f
 235                  1000.0 -30.0 -1000.0 glVertex3f
 236                  1000.0 -30.0  1000.0 glVertex3f
 237             ] do-state
 238         ] with-gl-program
 239     ] bi ;
 240
 241 : reflection-frustum ( gadget -- -x x -y y near far )
 242     [ near-plane ] [ far-plane ] bi
 243     [ drop dup [ -+ ] bi@ ] 2keep ;
 244
 245 : (reflection-face) ( gadget face -- )
 246     swap reflection-texture>> [
 247         GL_DRAW_FRAMEBUFFER
 248         GL_COLOR_ATTACHMENT0
 249     ] 2dip 0 glFramebufferTexture2D
 250     check-framebuffer ;
 251
 252 : (draw-reflection-texture) ( gadget -- )
 253     dup reflection-framebuffer>> [ {
 254         [ drop 0 0 (reflection-dim) glViewport ]
 255         [
 256             GL_PROJECTION glMatrixMode
 257             glPushMatrix glLoadIdentity
 258             reflection-frustum glFrustum
 259             GL_MODELVIEW glMatrixMode
 260             glLoadIdentity
 261             180.0 0.0 0.0 1.0 glRotatef
 262         ]
 263         [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Z (reflection-face) ]
 264         [ sphere-scene ]
 265         [ GL_TEXTURE_CUBE_MAP_POSITIVE_X (reflection-face)
 266           90.0 0.0 1.0 0.0 glRotatef ]
 267         [ sphere-scene ]
 268         [ GL_TEXTURE_CUBE_MAP_POSITIVE_Z (reflection-face)
 269           90.0 0.0 1.0 0.0 glRotatef glPushMatrix ]
 270         [ sphere-scene ]
 271         [ GL_TEXTURE_CUBE_MAP_NEGATIVE_X (reflection-face)
 272           90.0 0.0 1.0 0.0 glRotatef ]
 273         [ sphere-scene ]
 274         [ GL_TEXTURE_CUBE_MAP_NEGATIVE_Y (reflection-face)
 275           glPopMatrix glPushMatrix -90.0 1.0 0.0 0.0 glRotatef ]
 276         [ sphere-scene ]
 277         [ GL_TEXTURE_CUBE_MAP_POSITIVE_Y (reflection-face)
 278           glPopMatrix 90.0 1.0 0.0 0.0 glRotatef ]
 279         [ sphere-scene ]
 280         [
 281             [ 0 0 ] dip dim>> first2 glViewport
 282             GL_PROJECTION glMatrixMode
 283             glPopMatrix
 284         ]
 285     } cleave ] with-framebuffer ;
 286
 287 M: spheres-world draw-world*
 288     {
 289         [ (draw-reflection-texture) ]
 290         [ demo-world-set-matrix ]
 291         [ sphere-scene ]
 292         [ reflection-texture>> GL_TEXTURE_CUBE_MAP GL_TEXTURE0 bind-texture-unit ]
 293         [
 294             texture-sphere-program>> [
 295                 [ "surface_texture" glGetUniformLocation 0 glUniform1i ]
 296                 [ { 0.0 0.0 0.0 } 4.0 (draw-sphere) ]
 297                 bi
 298             ] with-gl-program
 299         ]
 300     } cleave ;
 301
 302 : spheres-window ( -- )
 303     [
 304         f T{ world-attributes
 305             { world-class spheres-world }
 306             { title "Spheres" }
 307             { pixel-format-attributes {
 308                 windowed
 309                 double-buffered
 310                 T{ depth-bits { value 16 } }
 311             } }
 312         } open-window
 313     ] with-ui ;
 314
 315 MAIN: spheres-window