extra/spider/spider.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors fry html.parser html.parser.analyzer
   4 http.client kernel tools.time sets assocs sequences
   5 concurrency.combinators io threads namespaces math multiline
   6 math.parser inspector urls logging combinators.short-circuit
   7 continuations calendar prettyprint dlists deques locals ;
   8 IN: spider
   9
  10 TUPLE: spider base count max-count sleep max-depth initial-links
  11 filters spidered todo nonmatching quiet ;
  12
  13 TUPLE: spider-result url depth headers fetch-time parsed-html
  14 links processing-time timestamp ;
  15
  16 TUPLE: todo-url url depth ;
  17
  18 : <todo-url> ( url depth -- todo-url )
  19     todo-url new
  20         swap >>depth
  21         swap >>url ;
  22
  23 TUPLE: unique-deque assoc deque ;
  24
  25 : <unique-deque> ( -- unique-deque )
  26     H{ } clone <dlist> unique-deque boa ;
  27
  28 : push-url ( url depth unique-deque -- )
  29     [ <todo-url> ] dip
  30     [ [ [ t ] dip url>> ] [ assoc>> ] bi* set-at ]
  31     [ deque>> push-back ] 2bi ;
  32
  33 : pop-url ( unique-deque -- todo-url ) deque>> pop-front ;
  34
  35 : peek-url ( unique-deque -- todo-url ) deque>> peek-front ;
  36
  37 : <spider> ( base -- spider )
  38     >url
  39     spider new
  40         over >>base
  41         swap 0 <unique-deque> [ push-url ] keep >>todo
  42         <unique-deque> >>nonmatching
  43         0 >>max-depth
  44         0 >>count
  45         1/0. >>max-count
  46         H{ } clone >>spidered ;
  47
  48 <PRIVATE
  49
  50 : apply-filters ( links spider -- links' )
  51     filters>> [ '[ [ _ 1&& ] filter ] call( seq -- seq' ) ] when* ;
  52
  53 : push-links ( links level unique-deque -- )
  54     '[ _ _ push-url ] each ;
  55
  56 : add-todo ( links level spider -- )
  57     todo>> push-links ;
  58
  59 : add-nonmatching ( links level spider -- )
  60     nonmatching>> push-links ;
  61
  62 : filter-base-links ( spider spider-result -- base-links nonmatching-links )
  63     [ base>> host>> ] [ links>> prune ] bi*
  64     [ host>> = ] with partition ;
  65
  66 : add-spidered ( spider spider-result -- )
  67     [ [ 1+ ] change-count ] dip
  68     2dup [ spidered>> ] [ dup url>> ] bi* rot set-at
  69     [ filter-base-links ] 2keep
  70     depth>> 1+ swap
  71     [ add-nonmatching ]
  72     [ tuck [ apply-filters ] 2dip add-todo ] 2bi ;
  73
  74 : normalize-hrefs ( links spider -- links' )
  75     [ [ >url ] map ] dip
  76     base>> swap [ derive-url ] with map ;
  77
  78 : print-spidering ( url depth -- )
  79     "depth: " write number>string write
  80     ", spidering: " write . yield ;
  81
  82 :: new-spidered-result ( spider url depth -- spider-result )
  83     f url spider spidered>> set-at
  84     [ url http-get ] benchmark :> fetch-time :> html :> headers
  85     [
  86         html parse-html [ ] [ find-hrefs spider normalize-hrefs ] bi
  87     ] benchmark :> processing-time :> links :> parsed-html
  88     url depth headers fetch-time parsed-html links processing-time
  89     now spider-result boa ;
  90
  91 :: spider-page ( spider url depth -- )
  92     spider quiet>> [ url depth print-spidering ] unless
  93     spider url depth new-spidered-result :> spidered-result
  94     spider quiet>> [ spidered-result describe ] unless
  95     spider spidered-result add-spidered ;
  96
  97 \ spider-page ERROR add-error-logging
  98
  99 : spider-sleep ( spider -- )
 100     sleep>> [ sleep ] when* ;
 101
 102 :: queue-initial-links ( spider -- spider )
 103     spider initial-links>> spider normalize-hrefs 0 spider add-todo spider ;
 104
 105 : spider-page? ( spider -- ? )
 106     {
 107         [ todo>> deque>> deque-empty? not ]
 108         [ [ todo>> peek-url depth>> ] [ max-depth>> ] bi < ]
 109         [ [ count>> ] [ max-count>> ] bi < ]
 110     } 1&& ;
 111
 112 : setup-next-url ( spider -- spider url depth )
 113     dup todo>> pop-url [ url>> ] [ depth>> ] bi ;
 114
 115 : spider-next-page ( spider -- )
 116     setup-next-url spider-page ;
 117
 118 PRIVATE>
 119
 120 : run-spider-loop ( spider -- )
 121     dup spider-page? [
 122         [ spider-next-page ] [ run-spider-loop ] bi
 123     ] [
 124         drop
 125     ] if ;
 126
 127 : run-spider ( spider -- spider )
 128     "spider" [
 129         queue-initial-links [ run-spider-loop ] keep
 130     ] with-logging ;