extra/synth/synth.factor

   1 ! Copyright (C) 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel locals math math.constants math.functions memoize openal openal.alut synth.buffers sequences sequences.modified sequences.repeating ;
   4 IN: synth
   5
   6 MEMO: single-sine-wave ( samples/wave -- seq )
   7     [ <iota> ] [ pi 2 * swap / [ * sin ] curry ] bi map ;
   8
   9 : (sine-wave) ( samples/wave n-samples -- seq )
  10     [ single-sine-wave ] dip <cycles> ;
  11
  12 : sine-wave ( sample-freq freq seconds -- seq )
  13     pick * >integer [ /i ] dip (sine-wave) ;
  14
  15 : >sine-wave-buffer ( freq seconds buffer -- buffer )
  16     [ sample-freq>> -rot sine-wave ] keep swap >>data ;
  17
  18 : >silent-buffer ( seconds buffer -- buffer )
  19     [ sample-freq>> * >integer 0 <repetition> ] [ data<< ] [ ] tri ;
  20
  21 TUPLE: harmonic n amplitude ;
  22 C: <harmonic> harmonic
  23
  24 TUPLE: note hz secs ;
  25 C: <note> note
  26
  27 : harmonic-freq ( note harmonic -- freq )
  28     n>> swap hz>> * ;
  29
  30 :: note-harmonic-data ( harmonic note buffer -- data )
  31     buffer sample-freq>> note harmonic harmonic-freq note secs>> sine-wave
  32     harmonic amplitude>> <scaled> ;
  33
  34 : >note ( harmonics note buffer -- buffer )
  35     [ [ note-harmonic-data ] 2curry map <summed> ] [ data<< ] [ ] tri ;