extra/tar/tar.factor

   1 ! Copyright (C) 2009 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors byte-arrays combinators io io.backend
   4 io.directories io.encodings.binary io.files io.files.links
   5 io.pathnames io.streams.byte-array io.streams.string kernel
   6 math math.parser namespaces sequences summary typed ;
   7 IN: tar
   8
   9 CONSTANT: zero-checksum 256
  10 CONSTANT: block-size 512
  11
  12 SYMBOL: to-link
  13
  14 : save-link ( link -- )
  15     to-link get push ;
  16
  17 TUPLE: tar-header name mode uid gid size mtime checksum typeflag
  18 linkname magic version uname gname devmajor devminor prefix ;
  19
  20 ERROR: checksum-error header ;
  21
  22 : trim-string ( seq -- newseq ) [ "\0 " member? ] trim-tail ;
  23
  24 : read-c-string ( n -- str )
  25     read [ zero? ] trim-tail "" like ;
  26
  27 : read-tar-header ( -- header )
  28     tar-header new
  29         100 read-c-string >>name
  30         8 read-c-string trim-string oct> >>mode
  31         8 read-c-string trim-string oct> >>uid
  32         8 read-c-string trim-string oct> >>gid
  33         12 read-c-string trim-string oct> >>size
  34         12 read-c-string trim-string oct> >>mtime
  35         8 read-c-string trim-string oct> >>checksum
  36         read1 >>typeflag
  37         100 read-c-string >>linkname
  38         6 read >>magic
  39         2 read >>version
  40         32 read-c-string >>uname
  41         32 read-c-string >>gname
  42         8 read trim-string oct> >>devmajor
  43         8 read trim-string oct> >>devminor
  44         155 read-c-string >>prefix ;
  45
  46 TYPED: checksum-header ( seq: byte-array -- n )
  47     148 cut-slice 8 tail-slice [ 0 [ + ] reduce ] bi@ + 256 + >fixnum ;
  48
  49 : read-data-blocks ( header -- )
  50     dup size>> 0 > [
  51         block-size read [
  52             over size>> dup block-size <= [
  53                 head write drop
  54             ] [
  55                 drop write
  56                 [ block-size - ] change-size
  57                 read-data-blocks
  58             ] if
  59         ] [
  60             drop
  61         ] if*
  62     ] [
  63         drop
  64     ] if ; inline recursive
  65
  66 : parse-tar-header ( seq -- header )
  67     dup checksum-header dup zero-checksum = [
  68         2drop
  69         tar-header new
  70             0 >>size
  71             0 >>checksum
  72     ] [
  73         [
  74             binary [ read-tar-header ] with-byte-reader
  75             dup checksum>>
  76         ] dip = [ checksum-error ] unless
  77     ] if ;
  78
  79 ERROR: unknown-typeflag ch ;
  80
  81 M: unknown-typeflag summary
  82     ch>> [ "Unknown typeflag: " ] dip prefix ;
  83
  84 : read/write-blocks ( header path -- )
  85     binary [ read-data-blocks ] with-file-writer ;
  86
  87 ! Normal file
  88 : typeflag-0 ( header -- )
  89     dup name>> read/write-blocks ;
  90
  91 TUPLE: hard-link linkname name ;
  92 C: <hard-link> hard-link
  93
  94 TUPLE: symbolic-link linkname name ;
  95 C: <symbolic-link> symbolic-link
  96
  97 ! Hard link, don't call normalize-path
  98 : typeflag-1 ( header -- )
  99     [ linkname>> ] [ name>> ] bi <hard-link> save-link ;
 100
 101 ! Symlink, don't call normalize-path
 102 : typeflag-2 ( header -- )
 103     [ linkname>> ] [ name>> ] bi <symbolic-link> save-link ;
 104
 105 ! character special
 106 : typeflag-3 ( header -- ) unknown-typeflag ;
 107
 108 ! Block special
 109 : typeflag-4 ( header -- ) unknown-typeflag ;
 110
 111 ! Directory
 112 : typeflag-5 ( header -- )
 113     name>> make-directories ;
 114
 115 ! FIFO
 116 : typeflag-6 ( header -- ) unknown-typeflag ;
 117
 118 ! Contiguous file
 119 : typeflag-7 ( header -- ) unknown-typeflag ;
 120
 121 ! Global extended header
 122 : typeflag-8 ( header -- ) unknown-typeflag ;
 123
 124 ! Extended header
 125 : typeflag-9 ( header -- ) unknown-typeflag ;
 126
 127 ! Global POSIX header
 128 : typeflag-g ( header -- )
 129     ! Read something like: 52 comment=9f2a940965286754f3a34d5737c3097c05db8725
 130     ! and drop it
 131     [ read-data-blocks ] with-string-writer drop ;
 132
 133 ! Extended POSIX header
 134 : typeflag-x ( header -- ) unknown-typeflag ;
 135
 136 ! Solaris access control list
 137 : typeflag-A ( header -- ) unknown-typeflag ;
 138
 139 ! GNU dumpdir
 140 : typeflag-D ( header -- ) unknown-typeflag ;
 141
 142 ! Solaris extended attribute file
 143 : typeflag-E ( header -- ) unknown-typeflag ;
 144
 145 ! Inode metadata
 146 : typeflag-I ( header -- ) unknown-typeflag ;
 147
 148 ! Long link name
 149 : typeflag-K ( header -- ) unknown-typeflag ;
 150
 151 ! Long file name
 152 : typeflag-L ( header -- )
 153     drop
 154     ;
 155     ! [ read-data-blocks ] with-string-writer
 156     ! [ zero? ] trim-tail filename set
 157     ! filename get make-directories ;
 158
 159 ! Multi volume continuation entry
 160 : typeflag-M ( header -- ) unknown-typeflag ;
 161
 162 ! GNU long file name
 163 : typeflag-N ( header -- ) unknown-typeflag ;
 164
 165 ! Sparse file
 166 : typeflag-S ( header -- ) unknown-typeflag ;
 167
 168 ! Volume header
 169 : typeflag-V ( header -- ) unknown-typeflag ;
 170
 171 ! Vendor extended header type
 172 : typeflag-X ( header -- ) unknown-typeflag ;
 173
 174 : parse-tar ( -- )
 175     block-size read dup length block-size = [
 176         parse-tar-header
 177         dup typeflag>>
 178         {
 179             { 0 [ typeflag-0 ] }
 180             { CHAR: 0 [ typeflag-0 ] }
 181             ! { CHAR: 1 [ typeflag-1 ] }
 182             { CHAR: 2 [ typeflag-2 ] }
 183             ! { CHAR: 3 [ typeflag-3 ] }
 184             ! { CHAR: 4 [ typeflag-4 ] }
 185             { CHAR: 5 [ typeflag-5 ] }
 186             ! { CHAR: 6 [ typeflag-6 ] }
 187             ! { CHAR: 7 [ typeflag-7 ] }
 188             { CHAR: g [ typeflag-g ] }
 189             ! { CHAR: x [ typeflag-x ] }
 190             ! { CHAR: A [ typeflag-A ] }
 191             ! { CHAR: D [ typeflag-D ] }
 192             ! { CHAR: E [ typeflag-E ] }
 193             ! { CHAR: I [ typeflag-I ] }
 194             ! { CHAR: K [ typeflag-K ] }
 195             { CHAR: L [ typeflag-L ] }
 196             ! { CHAR: M [ typeflag-M ] }
 197             ! { CHAR: N [ typeflag-N ] }
 198             ! { CHAR: S [ typeflag-S ] }
 199             ! { CHAR: V [ typeflag-V ] }
 200             ! { CHAR: X [ typeflag-X ] }
 201             { f [ drop ] }
 202         } case parse-tar
 203     ] [
 204         drop
 205     ] if ;
 206
 207 GENERIC: do-link ( object -- )
 208
 209 M: hard-link do-link
 210     [ linkname>> ] [ name>> ] bi make-hard-link ;
 211
 212 M: symbolic-link do-link
 213     [ linkname>> ] [ name>> ] bi make-link ;
 214
 215 ! FIXME: linux tar calls unlinkat and makelinkat
 216 : make-links ( -- )
 217     to-link get [
 218         [ name>> ?delete-file ] [ do-link ] bi
 219     ] each ;
 220
 221 : untar ( path -- )
 222     normalize-path dup parent-directory [
 223         V{ } clone to-link [
 224             binary [ parse-tar ] with-file-reader
 225             make-links
 226         ] with-variable
 227     ] with-directory ;