]> gitweb.factorcode.org Git - factor.git/blob - extra/terrain/terrain.factor
Merge branch 'master' of git://factorcode.org/git/factor
[factor.git] / extra / terrain / terrain.factor
1 USING: accessors arrays combinators game-input game-loop
2 game-input.scancodes grouping kernel literals locals
3 math math.constants math.functions math.matrices math.order
4 math.vectors opengl opengl.capabilities opengl.gl
5 opengl.shaders opengl.textures opengl.textures.private
6 sequences sequences.product specialized-arrays.float
7 terrain.generation terrain.shaders ui ui.gadgets
8 ui.gadgets.worlds ui.pixel-formats game-worlds method-chains
9 math.affine-transforms noise ui.gestures ;
10 IN: terrain
11
12 CONSTANT: FOV $[ 2.0 sqrt 1+ ]
13 CONSTANT: NEAR-PLANE $[ 1.0 1024.0 / ]
14 CONSTANT: FAR-PLANE 2.0
15 CONSTANT: PLAYER-START-LOCATION { 0.5 0.51 0.5 }
16 CONSTANT: PLAYER-HEIGHT $[ 1.0 256.0 / ]
17 CONSTANT: GRAVITY $[ 1.0 4096.0 / ]
18 CONSTANT: JUMP $[ 1.0 1024.0 / ]
19 CONSTANT: MOUSE-SCALE $[ 1.0 10.0 / ]
20 CONSTANT: MOVEMENT-SPEED $[ 1.0 16384.0 / ]
21 CONSTANT: FRICTION { 0.95 0.99 0.95 }
22 CONSTANT: COMPONENT-SCALE { 0.5 0.01 0.0005 0.0 }
23 CONSTANT: SKY-PERIOD 1200
24 CONSTANT: SKY-SPEED 0.0005
25
26 CONSTANT: terrain-vertex-size { 512 512 }
27 CONSTANT: terrain-vertex-distance { $[ 1.0 512.0 / ] $[ 1.0 512.0 / ] }
28 CONSTANT: terrain-vertex-row-length $[ 512 1 + 2 * ]
29
30 TUPLE: player
31     location yaw pitch velocity velocity-modifier ;
32
33 TUPLE: terrain-world < game-world
34     player
35     sky-image sky-texture sky-program
36     terrain terrain-segment terrain-texture terrain-program
37     terrain-vertex-buffer ;
38
39 M: terrain-world tick-length
40     drop 1000 30 /i ;
41
42 : frustum ( dim -- -x x -y y near far )
43     dup first2 min v/n
44     NEAR-PLANE FOV / v*n first2 [ [ neg ] keep ] bi@
45     NEAR-PLANE FAR-PLANE ;
46
47 : set-modelview-matrix ( gadget -- )
48     GL_DEPTH_BUFFER_BIT glClear
49     GL_MODELVIEW glMatrixMode
50     glLoadIdentity
51     player>>
52     [ pitch>> 1.0 0.0 0.0 glRotatef ]
53     [ yaw>> 0.0 1.0 0.0 glRotatef ]
54     [ location>> vneg first3 glTranslatef ] tri ;
55
56 : vertex-array-vertex ( x z -- vertex )
57     [ terrain-vertex-distance first * ]
58     [ terrain-vertex-distance second * ] bi*
59     [ 0 ] dip float-array{ } 3sequence ;
60
61 : vertex-array-row ( z -- vertices )
62     dup 1 + 2array
63     terrain-vertex-size first 1 + iota
64     2array [ first2 swap vertex-array-vertex ] product-map
65     concat ;
66
67 : vertex-array ( -- vertices )
68     terrain-vertex-size second iota
69     [ vertex-array-row ] map concat ;
70
71 : >vertex-buffer ( bytes -- buffer )
72     [ GL_ARRAY_BUFFER ] dip GL_STATIC_DRAW <gl-buffer> ;
73
74 : draw-vertex-buffer-row ( i -- )
75     [ GL_TRIANGLE_STRIP ] dip
76     terrain-vertex-row-length * terrain-vertex-row-length
77     glDrawArrays ;
78
79 : draw-vertex-buffer ( buffer -- )
80     [ GL_ARRAY_BUFFER ] dip [
81         3 GL_FLOAT 0 f glVertexPointer
82         terrain-vertex-size second iota [ draw-vertex-buffer-row ] each
83     ] with-gl-buffer ;
84
85 : degrees ( deg -- rad )
86     pi 180.0 / * ;
87
88 :: eye-rotate ( yaw pitch v -- v' )
89     yaw degrees neg :> y
90     pitch degrees neg :> p
91     y cos :> cosy
92     y sin :> siny
93     p cos :> cosp
94     p sin :> sinp
95
96     cosy         0.0       siny        neg  3array
97     siny sinp *  cosp      cosy sinp *      3array
98     siny cosp *  sinp neg  cosy cosp *      3array 3array
99     v swap v.m ;
100
101 : forward-vector ( player -- v )
102     yaw>> 0.0
103     ${ 0.0 0.0 MOVEMENT-SPEED } vneg eye-rotate ;
104 : rightward-vector ( player -- v )
105     yaw>> 0.0
106     ${ MOVEMENT-SPEED 0.0 0.0 } eye-rotate ;
107 : clamp-pitch ( pitch -- pitch' )
108     90.0 min -90.0 max ;
109
110
111 : walk-forward ( player -- )
112     dup forward-vector [ v+ ] curry change-velocity drop ;
113 : walk-backward ( player -- )
114     dup forward-vector [ v- ] curry change-velocity drop ;
115 : walk-leftward ( player -- )
116     dup rightward-vector [ v- ] curry change-velocity drop ;
117 : walk-rightward ( player -- )
118     dup rightward-vector [ v+ ] curry change-velocity drop ;
119 : jump ( player -- )
120     [ ${ 0.0 JUMP 0.0 } v+ ] change-velocity drop ;
121 : rotate-leftward ( player x -- )
122     [ - ] curry change-yaw drop ;
123 : rotate-rightward ( player x -- )
124     [ + ] curry change-yaw drop ;
125 : look-horizontally ( player x -- )
126     [ + ] curry change-yaw drop ;
127 : look-vertically ( player x -- )
128     [ + clamp-pitch ] curry change-pitch drop ;
129
130
131 : rotate-with-mouse ( player mouse -- )
132     [ dx>> MOUSE-SCALE * look-horizontally ]
133     [ dy>> MOUSE-SCALE * look-vertically ] 2bi ;
134
135
136 terrain-world H{
137     { T{ key-down { mods { A+ } } { sym "RET" } } [ toggle-fullscreen ] }
138 } set-gestures
139
140 :: handle-input ( world -- )
141     world player>> :> player
142     read-keyboard keys>> :> keys
143     key-left-shift keys nth [
144         { 2.0 1.0 2.0 } player (>>velocity-modifier)
145     ] when
146     key-left-shift keys nth [
147         { 1.0 1.0 1.0 } player (>>velocity-modifier)
148     ] unless
149
150     key-w keys nth [ player walk-forward ] when 
151     key-s keys nth [ player walk-backward ] when 
152     key-a keys nth [ player walk-leftward ] when 
153     key-d keys nth [ player walk-rightward ] when 
154     key-q keys nth [ player -1 look-horizontally ] when 
155     key-e keys nth [ player 1 look-horizontally ] when 
156     key-left-arrow keys nth [ player -1 look-horizontally ] when 
157     key-right-arrow keys nth [ player 1 look-horizontally ] when 
158     key-down-arrow keys nth [ player 1 look-vertically ] when 
159     key-up-arrow keys nth [ player -1 look-vertically ] when 
160     key-space keys nth [ player jump ] when 
161     key-escape keys nth [ world close-window ] when
162     player read-mouse rotate-with-mouse
163     reset-mouse ;
164
165 : apply-friction ( velocity -- velocity' )
166     FRICTION v* ;
167
168 : apply-gravity ( velocity -- velocity' )
169     1 over [ GRAVITY - ] change-nth ;
170
171 : clamp-coords ( coords dim -- coords' )
172     [ { 0 0 } vmax ] dip { 2 2 } v- vmin ;
173
174 :: pixel-indices ( coords dim -- indices )
175     coords vfloor [ >integer ] map dim clamp-coords :> floor-coords
176     floor-coords first2 dim first * + :> base-index
177     base-index dim first + :> next-row-index
178
179     base-index
180     base-index 1 +
181     next-row-index
182     next-row-index 1 + 4array ;
183
184 :: terrain-height-at ( segment point -- height )
185     segment dim>> :> dim
186     dim point v* :> pixel
187     pixel dup vfloor v- :> pixel-mantissa
188     segment bitmap>> 4 <groups> :> pixels
189     pixel dim pixel-indices :> indices
190     
191     indices [ pixels nth COMPONENT-SCALE v. 255.0 / ] map
192     first4 pixel-mantissa bilerp ;
193
194 : collide ( segment location -- location' )
195     [ [ first ] [ third ] bi 2array terrain-height-at PLAYER-HEIGHT + ]
196     [ [ 1 ] 2dip [ max ] with change-nth ]
197     [ ] tri ;
198
199 : scaled-velocity ( player -- velocity )
200     [ velocity>> ] [ velocity-modifier>> ] bi v* ;
201
202 : tick-player ( world player -- )
203     [ apply-friction apply-gravity ] change-velocity
204     dup scaled-velocity [ v+ [ terrain-segment>> ] dip collide ] curry with change-location
205     drop ;
206
207 M: terrain-world tick*
208     [ dup focused?>> [ handle-input ] [ drop ] if ]
209     [ dup player>> tick-player ] bi ;
210
211 : set-texture-parameters ( texture -- )
212     GL_TEXTURE_2D GL_TEXTURE0 bind-texture-unit
213     GL_TEXTURE_2D GL_TEXTURE_MIN_FILTER GL_LINEAR glTexParameteri
214     GL_TEXTURE_2D GL_TEXTURE_MAG_FILTER GL_LINEAR glTexParameteri
215     GL_TEXTURE_2D GL_TEXTURE_WRAP_S GL_CLAMP_TO_EDGE glTexParameteri
216     GL_TEXTURE_2D GL_TEXTURE_WRAP_T GL_CLAMP_TO_EDGE glTexParameteri ;
217
218 : sky-gradient ( world -- t )
219     game-loop>> tick-number>> SKY-PERIOD mod SKY-PERIOD /f ;
220 : sky-theta ( world -- theta )
221     game-loop>> tick-number>> SKY-SPEED * ;
222
223 BEFORE: terrain-world begin-world
224     "2.0" { "GL_ARB_vertex_buffer_object" "GL_ARB_shader_objects" }
225     require-gl-version-or-extensions
226     GL_DEPTH_TEST glEnable
227     GL_TEXTURE_2D glEnable
228     GL_VERTEX_ARRAY glEnableClientState
229     PLAYER-START-LOCATION 0.0 0.0 { 0.0 0.0 0.0 } { 1.0 1.0 1.0 } player boa >>player
230     <perlin-noise-table> 0.01 0.01 <scale> { 512 512 } perlin-noise-image
231     [ >>sky-image ] keep
232     make-texture [ set-texture-parameters ] keep >>sky-texture
233     <terrain> [ >>terrain ] keep
234     { 0 0 } terrain-segment [ >>terrain-segment ] keep
235     make-texture [ set-texture-parameters ] keep >>terrain-texture
236     sky-vertex-shader sky-pixel-shader <simple-gl-program>
237     >>sky-program
238     terrain-vertex-shader terrain-pixel-shader <simple-gl-program>
239     >>terrain-program
240     vertex-array >vertex-buffer >>terrain-vertex-buffer
241     drop ;
242
243 AFTER: terrain-world end-world
244     {
245         [ terrain-vertex-buffer>> delete-gl-buffer ]
246         [ terrain-program>> delete-gl-program ]
247         [ terrain-texture>> delete-texture ]
248         [ sky-program>> delete-gl-program ]
249         [ sky-texture>> delete-texture ]
250     } cleave ;
251
252 M: terrain-world resize-world
253     GL_PROJECTION glMatrixMode
254     glLoadIdentity
255     dim>> [ [ 0 0 ] dip first2 glViewport ]
256     [ frustum glFrustum ] bi ;
257
258 M: terrain-world draw-world*
259     {
260         [ set-modelview-matrix ]
261         [ terrain-texture>> GL_TEXTURE_2D GL_TEXTURE0 bind-texture-unit ]
262         [ sky-texture>> GL_TEXTURE_2D GL_TEXTURE1 bind-texture-unit ]
263         [ GL_DEPTH_TEST glDisable dup sky-program>> [
264             [ nip "sky" glGetUniformLocation 1 glUniform1i ]
265             [ "sky_gradient" glGetUniformLocation swap sky-gradient glUniform1f ]
266             [ "sky_theta" glGetUniformLocation swap sky-theta glUniform1f ] 2tri
267             { -1.0 -1.0 } { 2.0 2.0 } gl-fill-rect
268         ] with-gl-program ]
269         [ GL_DEPTH_TEST glEnable dup terrain-program>> [
270             [ "heightmap" glGetUniformLocation 0 glUniform1i ]
271             [ "component_scale" glGetUniformLocation COMPONENT-SCALE first4 glUniform4f ] bi
272             terrain-vertex-buffer>> draw-vertex-buffer
273         ] with-gl-program ]
274     } cleave gl-error ;
275
276 M: terrain-world pref-dim* drop { 640 480 } ;
277
278 : terrain-window ( -- )
279     [
280         f T{ world-attributes
281             { world-class terrain-world }
282             { title "Terrain" }
283             { pixel-format-attributes {
284                 windowed
285                 double-buffered
286                 T{ depth-bits { value 24 } }
287             } }
288             { grab-input? t }
289         } open-window
290     ] with-ui ;
291
292 MAIN: terrain-window