extra/tetris/tetris.factor

   1 ! Copyright (C) 2006, 2007, 2008 Alex Chapman
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alarms arrays calendar kernel make math math.rectangles math.parser namespaces sequences system tetris.game tetris.gl ui.gadgets ui.gadgets.labels ui.gadgets.worlds ui.gadgets.status-bar ui.gestures ui.render ui ;
   4 FROM: tetris.game => level>> ;
   5 IN: tetris
   6
   7 TUPLE: tetris-gadget < gadget { tetris tetris } { alarm } ;
   8
   9 : <tetris-gadget> ( tetris -- gadget )
  10     tetris-gadget new swap >>tetris ;
  11
  12 M: tetris-gadget pref-dim* drop { 200 400 } ;
  13
  14 : update-status ( gadget -- )
  15     dup tetris>> [
  16         [ "Level: " % level>> # ]
  17         [ " Score: " % score>> # ]
  18         [ paused?>> [ " (Paused)" % ] when ] tri
  19     ] "" make swap show-status ;
  20
  21 M: tetris-gadget draw-gadget* ( gadget -- )
  22     [
  23         [ dim>> first2 ] [ tetris>> ] bi draw-tetris
  24     ] keep update-status ;
  25
  26 : new-tetris ( gadget -- gadget )
  27     [ <new-tetris> ] change-tetris ;
  28
  29 : unless-paused ( tetris quot -- )
  30     over tetris>> paused?>> [
  31         2drop
  32     ] [
  33         call
  34     ] if ; inline
  35
  36 tetris-gadget H{
  37     { T{ button-down f f 1 }     [ request-focus ] }
  38     { T{ key-down f f "UP" }     [ [ tetris>> rotate-right ] unless-paused ] }
  39     { T{ key-down f f "d" }      [ [ tetris>> rotate-left ] unless-paused ] }
  40     { T{ key-down f f "f" }      [ [ tetris>> rotate-right ] unless-paused ] }
  41     { T{ key-down f f "e" }      [ [ tetris>> rotate-left ] unless-paused ] }
  42     { T{ key-down f f "u" }      [ [ tetris>> rotate-right ] unless-paused ] }
  43     { T{ key-down f f "LEFT" }   [ [ tetris>> move-left ] unless-paused ] }
  44     { T{ key-down f f "RIGHT" }  [ [ tetris>> move-right ] unless-paused ] }
  45     { T{ key-down f f "DOWN" }   [ [ tetris>> move-down ] unless-paused ] }
  46     { T{ key-down f f " " }      [ [ tetris>> move-drop ] unless-paused ] }
  47     { T{ key-down f f "p" }      [ tetris>> toggle-pause ] }
  48     { T{ key-down f f "n" }      [ new-tetris drop ] }
  49 } set-gestures
  50
  51 : tick ( gadget -- )
  52     [ tetris>> ?update ] [ relayout-1 ] bi ;
  53
  54 M: tetris-gadget graft* ( gadget -- )
  55     [ [ tick ] curry 100 milliseconds every ] keep alarm<< ;
  56
  57 M: tetris-gadget ungraft* ( gadget -- )
  58     [ cancel-alarm f ] change-alarm drop ;
  59
  60 : tetris-window ( -- )
  61     [
  62         <default-tetris> <tetris-gadget>
  63         "Tetris" open-status-window
  64     ] with-ui ;
  65
  66 MAIN: tetris-window