extra/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2007 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays documents ui.clipboards ui.commands ui.gadgets
   4 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.labels
   5 ui.gadgets.scrollers ui.gadgets.theme ui.render ui.gestures io
   6 kernel math models namespaces opengl opengl.gl sequences strings
   7 io.styles math.vectors sorting colors combinators assocs
   8 math.order ;
   9 IN: ui.gadgets.editors
  10
  11 TUPLE: editor
  12 self
  13 font color caret-color selection-color
  14 caret mark
  15 focused? ;
  16
  17 : <loc> ( -- loc ) { 0 0 } <model> ;
  18
  19 : init-editor-locs ( editor -- )
  20     <loc> over set-editor-caret
  21     <loc> swap set-editor-mark ;
  22
  23 : editor-theme ( editor -- )
  24     black over set-editor-color
  25     red over set-editor-caret-color
  26     selection-color over set-editor-selection-color
  27     monospace-font swap set-editor-font ;
  28
  29 : <editor> ( -- editor )
  30     <document> <gadget> editor construct-control
  31     dup dup set-editor-self
  32     dup init-editor-locs
  33     dup editor-theme ;
  34
  35 : field-theme ( gadget -- )
  36     gray <solid> swap set-gadget-boundary ;
  37
  38 : construct-editor ( object class -- tuple )
  39     >r { set-gadget-delegate } r> construct
  40     dup dup set-editor-self ; inline
  41
  42 : activate-editor-model ( editor model -- )
  43     2dup add-connection
  44     dup activate-model
  45     swap gadget-model add-loc ;
  46
  47 : deactivate-editor-model ( editor model -- )
  48     2dup remove-connection
  49     dup deactivate-model
  50     swap gadget-model remove-loc ;
  51
  52 M: editor graft*
  53     dup
  54     dup editor-caret activate-editor-model
  55     dup editor-mark activate-editor-model ;
  56
  57 M: editor ungraft*
  58     dup
  59     dup editor-caret deactivate-editor-model
  60     dup editor-mark deactivate-editor-model ;
  61
  62 : editor-caret* ( editor -- loc ) editor-caret model-value ;
  63
  64 : editor-mark* ( editor -- loc ) editor-mark model-value ;
  65
  66 : set-caret ( loc editor -- )
  67     [ gadget-model validate-loc ] keep
  68     editor-caret set-model ;
  69
  70 : change-caret ( editor quot -- )
  71     over >r >r dup editor-caret* swap gadget-model r> call r>
  72     set-caret ; inline
  73
  74 : mark>caret ( editor -- )
  75     dup editor-caret* swap editor-mark set-model ;
  76
  77 : change-caret&mark ( editor quot -- )
  78     over >r change-caret r> mark>caret ; inline
  79
  80 : editor-line ( n editor -- str ) control-value nth ;
  81
  82 : editor-font* ( editor -- font ) editor-font open-font ;
  83
  84 : line-height ( editor -- n )
  85     editor-font* "" string-height ;
  86
  87 : y>line ( y editor -- line# )
  88     [ line-height / >fixnum ] keep gadget-model validate-line ;
  89
  90 : point>loc ( point editor -- loc )
  91     [
  92         >r first2 r> tuck y>line dup ,
  93         >r dup editor-font* r>
  94         rot editor-line x>offset ,
  95     ] { } make ;
  96
  97 : clicked-loc ( editor -- loc )
  98     [ hand-rel ] keep point>loc ;
  99
 100 : click-loc ( editor model -- )
 101     >r clicked-loc r> set-model ;
 102
 103 : focus-editor ( editor -- )
 104     t over set-editor-focused? relayout-1 ;
 105
 106 : unfocus-editor ( editor -- )
 107     f over set-editor-focused? relayout-1 ;
 108
 109 : (offset>x) ( font col# str -- x )
 110     swap head-slice string-width ;
 111
 112 : offset>x ( col# line# editor -- x )
 113     [ editor-line ] keep editor-font* -rot (offset>x) ;
 114
 115 : loc>x ( loc editor -- x ) >r first2 swap r> offset>x ;
 116
 117 : line>y ( lines# editor -- y )
 118     line-height * ;
 119
 120 : caret-loc ( editor -- loc )
 121     [ editor-caret* ] keep 2dup loc>x
 122     rot first rot line>y 2array ;
 123
 124 : caret-dim ( editor -- dim )
 125     line-height 0 swap 2array ;
 126
 127 : scroll>caret ( editor -- )
 128     dup gadget-graft-state second [
 129         dup caret-loc over caret-dim { 1 0 } v+ <rect>
 130         over scroll>rect
 131     ] when drop ;
 132
 133 : draw-caret ( -- )
 134     editor get editor-focused? [
 135         editor get
 136         dup editor-caret-color gl-color
 137         dup caret-loc origin get v+
 138         swap caret-dim over v+
 139         [ { 0.5 -0.5 } v+ ] bi@ gl-line
 140     ] when ;
 141
 142 : line-translation ( n -- loc )
 143     editor get line-height * 0.0 swap 2array ;
 144
 145 : translate-lines ( n -- )
 146     line-translation gl-translate ;
 147
 148 : draw-line ( editor str -- )
 149     >r editor-font r> { 0 0 } draw-string ;
 150
 151 : first-visible-line ( editor -- n )
 152     clip get rect-loc second origin get second -
 153     swap y>line ;
 154
 155 : last-visible-line ( editor -- n )
 156     clip get rect-extent nip second origin get second -
 157     swap y>line 1+ ;
 158
 159 : with-editor ( editor quot -- )
 160     [
 161         swap
 162         dup first-visible-line \ first-visible-line set
 163         dup last-visible-line \ last-visible-line set
 164         dup gadget-model document set
 165         editor set
 166         call
 167     ] with-scope ; inline
 168
 169 : visible-lines ( editor -- seq )
 170     \ first-visible-line get
 171     \ last-visible-line get
 172     rot control-value <slice> ;
 173
 174 : with-editor-translation ( n quot -- )
 175     >r line-translation origin get v+ r> with-translation ;
 176     inline
 177
 178 : draw-lines ( -- )
 179     \ first-visible-line get [
 180         editor get dup editor-color gl-color
 181         dup visible-lines
 182         [ draw-line 1 translate-lines ] with each
 183     ] with-editor-translation ;
 184
 185 : selection-start/end ( editor -- start end )
 186     dup editor-mark* swap editor-caret* sort-pair ;
 187
 188 : (draw-selection) ( x1 x2 -- )
 189     2dup = [ 2 + ] when
 190     0.0 swap editor get line-height glRectd ;
 191
 192 : draw-selected-line ( start end n -- )
 193     [ start/end-on-line ] keep tuck
 194     >r >r editor get offset>x r> r>
 195     editor get offset>x
 196     (draw-selection) ;
 197
 198 : draw-selection ( -- )
 199     editor get editor-selection-color gl-color
 200     editor get selection-start/end
 201     over first [
 202         2dup [
 203             >r 2dup r> draw-selected-line
 204             1 translate-lines
 205         ] each-line 2drop
 206     ] with-editor-translation ;
 207
 208 M: editor draw-gadget*
 209     [ draw-selection draw-lines draw-caret ] with-editor ;
 210
 211 M: editor pref-dim*
 212     dup editor-font* swap control-value text-dim ;
 213
 214 : contents-changed
 215     editor-self swap
 216     over editor-caret [ over validate-loc ] (change-model)
 217     over editor-mark [ over validate-loc ] (change-model)
 218     drop relayout ;
 219
 220 : caret/mark-changed
 221     nip editor-self dup relayout-1 scroll>caret ;
 222
 223 M: editor model-changed
 224     {
 225         { [ 2dup gadget-model eq? ] [ contents-changed ] }
 226         { [ 2dup editor-caret eq? ] [ caret/mark-changed ] }
 227         { [ 2dup editor-mark eq? ] [ caret/mark-changed ] }
 228     } cond ;
 229
 230 M: editor gadget-selection?
 231     selection-start/end = not ;
 232
 233 M: editor gadget-selection
 234     [ selection-start/end ] keep gadget-model doc-range ;
 235
 236 : remove-selection ( editor -- )
 237     [ selection-start/end ] keep gadget-model remove-doc-range ;
 238
 239 M: editor user-input*
 240     [ selection-start/end ] keep gadget-model set-doc-range t ;
 241
 242 : editor-string ( editor -- string )
 243     gadget-model doc-string ;
 244
 245 : set-editor-string ( string editor -- )
 246     gadget-model set-doc-string ;
 247
 248 M: editor gadget-text* editor-string % ;
 249
 250 : extend-selection ( editor -- )
 251     dup request-focus dup editor-caret click-loc ;
 252
 253 : mouse-elt ( -- element )
 254     hand-click# get {
 255         { 1 T{ one-char-elt } }
 256         { 2 T{ one-word-elt } }
 257     } at T{ one-line-elt } or ;
 258
 259 : drag-direction? ( loc editor -- ? )
 260     editor-mark* before? ;
 261
 262 : drag-selection-caret ( loc editor element -- loc )
 263     >r [ drag-direction? ] 2keep
 264     gadget-model
 265     r> prev/next-elt ? ;
 266
 267 : drag-selection-mark ( loc editor element -- loc )
 268     >r [ drag-direction? not ] 2keep
 269     nip dup editor-mark* swap gadget-model
 270     r> prev/next-elt ? ;
 271
 272 : drag-caret&mark ( editor -- caret mark )
 273     dup clicked-loc swap mouse-elt
 274     [ drag-selection-caret ] 3keep
 275     drag-selection-mark ;
 276
 277 : drag-selection ( editor -- )
 278     dup drag-caret&mark
 279     pick editor-mark set-model
 280     swap editor-caret set-model ;
 281
 282 : editor-cut ( editor clipboard -- )
 283     dupd gadget-copy remove-selection ;
 284
 285 : delete/backspace ( elt editor quot -- )
 286     over gadget-selection? [
 287         drop nip remove-selection
 288     ] [
 289         over >r >r dup editor-caret* swap gadget-model
 290         r> call r> gadget-model remove-doc-range
 291     ] if ; inline
 292
 293 : editor-delete ( editor elt -- )
 294     swap [ over >r rot next-elt r> swap ] delete/backspace ;
 295
 296 : editor-backspace ( editor elt -- )
 297     swap [ over >r rot prev-elt r> ] delete/backspace ;
 298
 299 : editor-select-prev ( editor elt -- )
 300     swap [ rot prev-elt ] change-caret ;
 301
 302 : editor-prev ( editor elt -- )
 303     dupd editor-select-prev mark>caret ;
 304
 305 : editor-select-next ( editor elt -- )
 306     swap [ rot next-elt ] change-caret ;
 307
 308 : editor-next ( editor elt -- )
 309     dupd editor-select-next mark>caret ;
 310
 311 : editor-select ( from to editor -- )
 312     tuck editor-caret set-model editor-mark set-model ;
 313
 314 : select-elt ( editor elt -- )
 315     over >r
 316     >r dup editor-caret* swap gadget-model r> prev/next-elt
 317     r> editor-select ;
 318
 319 : start-of-document ( editor -- ) T{ doc-elt } editor-prev ;
 320
 321 : end-of-document ( editor -- ) T{ doc-elt } editor-next ;
 322
 323 : position-caret ( editor -- )
 324     mouse-elt dup T{ one-char-elt } =
 325     [ drop dup extend-selection dup editor-mark click-loc ]
 326     [ select-elt ] if ;
 327
 328 : insert-newline "\n" swap user-input ;
 329
 330 : delete-next-character T{ char-elt } editor-delete ;
 331
 332 : delete-previous-character T{ char-elt } editor-backspace ;
 333
 334 : delete-previous-word T{ word-elt } editor-delete ;
 335
 336 : delete-next-word T{ word-elt } editor-backspace ;
 337
 338 : delete-to-start-of-line T{ one-line-elt } editor-delete ;
 339
 340 : delete-to-end-of-line T{ one-line-elt } editor-backspace ;
 341
 342 editor "general" f {
 343     { T{ key-down f f "DELETE" } delete-next-character }
 344     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 345     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 346     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 347     { T{ key-down f { C+ } "DELETE" } delete-previous-word }
 348     { T{ key-down f { C+ } "BACKSPACE" } delete-next-word }
 349     { T{ key-down f { A+ } "DELETE" } delete-to-start-of-line }
 350     { T{ key-down f { A+ } "BACKSPACE" } delete-to-end-of-line }
 351 } define-command-map
 352
 353 : paste clipboard get paste-clipboard ;
 354
 355 : paste-selection selection get paste-clipboard ;
 356
 357 : cut clipboard get editor-cut ;
 358
 359 editor "clipboard" f {
 360     { T{ paste-action } paste }
 361     { T{ button-up f f 2 } paste-selection }
 362     { T{ copy-action } com-copy }
 363     { T{ button-up } com-copy-selection }
 364     { T{ cut-action } cut }
 365 } define-command-map
 366
 367 : previous-character ( editor -- )
 368     dup gadget-selection? [
 369         dup selection-start/end drop
 370         over set-caret mark>caret
 371     ] [
 372         T{ char-elt } editor-prev
 373     ] if ;
 374
 375 : next-character ( editor -- )
 376     dup gadget-selection? [
 377         dup selection-start/end nip
 378         over set-caret mark>caret
 379     ] [
 380         T{ char-elt } editor-next
 381     ] if ;
 382
 383 : previous-line T{ line-elt } editor-prev ;
 384
 385 : next-line T{ line-elt } editor-next ;
 386
 387 : previous-word T{ word-elt } editor-prev ;
 388
 389 : next-word T{ word-elt } editor-next ;
 390
 391 : start-of-line T{ one-line-elt } editor-prev ;
 392
 393 : end-of-line T{ one-line-elt } editor-next ;
 394
 395 editor "caret-motion" f {
 396     { T{ button-down } position-caret }
 397     { T{ key-down f f "LEFT" } previous-character }
 398     { T{ key-down f f "RIGHT" } next-character }
 399     { T{ key-down f f "UP" } previous-line }
 400     { T{ key-down f f "DOWN" } next-line }
 401     { T{ key-down f { C+ } "LEFT" } previous-word }
 402     { T{ key-down f { C+ } "RIGHT" } next-word }
 403     { T{ key-down f f "HOME" } start-of-line }
 404     { T{ key-down f f "END" } end-of-line }
 405     { T{ key-down f { C+ } "HOME" } start-of-document }
 406     { T{ key-down f { C+ } "END" } end-of-document }
 407 } define-command-map
 408
 409 : select-all T{ doc-elt } select-elt ;
 410
 411 : select-line T{ one-line-elt } select-elt ;
 412
 413 : select-word T{ one-word-elt } select-elt ;
 414
 415 : selected-word ( editor -- string )
 416     dup gadget-selection?
 417     [ dup select-word ] unless
 418     gadget-selection ;
 419
 420 : select-previous-character T{ char-elt } editor-select-prev ;
 421
 422 : select-next-character T{ char-elt } editor-select-next ;
 423
 424 : select-previous-line T{ line-elt } editor-select-prev ;
 425
 426 : select-next-line T{ line-elt } editor-select-next ;
 427
 428 : select-previous-word T{ word-elt } editor-select-prev ;
 429
 430 : select-next-word T{ word-elt } editor-select-next ;
 431
 432 : select-start-of-line T{ one-line-elt } editor-select-prev ;
 433
 434 : select-end-of-line T{ one-line-elt } editor-select-next ;
 435
 436 : select-start-of-document T{ doc-elt } editor-select-prev ;
 437
 438 : select-end-of-document T{ doc-elt } editor-select-next ;
 439
 440 editor "selection" f {
 441     { T{ button-down f { S+ } } extend-selection }
 442     { T{ drag } drag-selection }
 443     { T{ gain-focus } focus-editor }
 444     { T{ lose-focus } unfocus-editor }
 445     { T{ delete-action } remove-selection }
 446     { T{ select-all-action } select-all }
 447     { T{ key-down f { C+ } "l" } select-line }
 448     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 449     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 450     { T{ key-down f { S+ } "UP" } select-previous-line }
 451     { T{ key-down f { S+ } "DOWN" } select-next-line }
 452     { T{ key-down f { S+ C+ } "LEFT" } select-previous-word }
 453     { T{ key-down f { S+ C+ } "RIGHT" } select-next-word }
 454     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 455     { T{ key-down f { S+ } "END" } select-end-of-line }
 456     { T{ key-down f { S+ C+ } "HOME" } select-start-of-document }
 457     { T{ key-down f { S+ C+ } "END" } select-end-of-document }
 458 } define-command-map
 459
 460 ! Multi-line editors
 461 TUPLE: multiline-editor ;
 462
 463 : <multiline-editor> ( -- editor )
 464     <editor> multiline-editor construct-editor ;
 465
 466 multiline-editor "general" f {
 467     { T{ key-down f f "RET" } insert-newline }
 468     { T{ key-down f { S+ } "RET" } insert-newline }
 469     { T{ key-down f f "ENTER" } insert-newline }
 470 } define-command-map
 471
 472 TUPLE: source-editor ;
 473
 474 : <source-editor> ( -- editor )
 475     <multiline-editor> source-editor construct-editor ;
 476
 477 ! Fields are like editors except they edit an external model
 478 TUPLE: field model editor ;
 479
 480 : <field-border> ( gadget -- border )
 481     2 <border>
 482     { 1 0 } over set-border-fill
 483     dup field-theme ;
 484
 485 : <field> ( model -- gadget )
 486     <editor> dup <field-border>
 487     { set-field-model set-field-editor set-gadget-delegate }
 488     field construct ;
 489
 490 M: field graft*
 491     dup field-model model-value
 492     over field-editor set-editor-string
 493     dup field-editor gadget-model add-connection ;
 494
 495 M: field ungraft*
 496     dup field-editor gadget-model remove-connection ;
 497
 498 M: field model-changed
 499     nip
 500     dup field-editor editor-string
 501     swap field-model set-model ;