extra/units/units.factor

   1 USING: accessors arrays io kernel math namespaces splitting
   2 prettyprint sequences sorting vectors words inverse summary
   3 shuffle math.functions sets ;
   4 IN: units
   5
   6 TUPLE: dimensioned value top bot ;
   7
   8 ERROR: dimensions-not-equal ;
   9
  10 M: dimensions-not-equal summary drop "Dimensions do not match" ;
  11
  12 : remove-one ( seq obj -- seq )
  13     1array split1 append ;
  14
  15 : 2remove-one ( seq seq obj -- seq seq )
  16     [ remove-one ] curry bi@ ;
  17
  18 : symbolic-reduce ( seq seq -- seq seq )
  19     2dup intersect
  20     [ first 2remove-one symbolic-reduce ] unless-empty ;
  21
  22 : <dimensioned> ( n top bot -- obj )
  23     symbolic-reduce
  24     [ natural-sort ] bi@
  25     dimensioned boa ;
  26
  27 : >dimensioned< ( d -- n top bot )
  28     [ bot>> ] [ top>> ] [ value>> ] tri ;
  29
  30 \ <dimensioned> [ [ dimensioned boa ] undo ] define-inverse
  31
  32 : dimensions ( dimensioned -- top bot )
  33     [ top>> ] [ bot>> ] bi ;
  34
  35 : check-dimensions ( d d -- )
  36     [ dimensions 2array ] same?
  37     [ dimensions-not-equal ] unless ;
  38
  39 : 2values ( dim dim -- val val ) [ value>> ] bi@ ;
  40
  41 : <dimension-op ( dim dim -- top bot val val )
  42     2dup check-dimensions dup dimensions 2swap 2values ;
  43
  44 : dimension-op> ( top bot val -- dim )
  45     -rot <dimensioned> ;
  46
  47 : d+ ( d d -- d ) <dimension-op + dimension-op> ;
  48
  49 : d- ( d d -- d ) <dimension-op - dimension-op> ;
  50
  51 : scalar ( n -- d )
  52     { } { } <dimensioned> ;
  53
  54 : d* ( d d -- d )
  55     [ dup number? [ scalar ] when ] bi@
  56     [ [ top>> ] bi@ append ] 2keep
  57     [ [ bot>> ] bi@ append ] 2keep
  58     2values * dimension-op> ;
  59
  60 : d-neg ( d -- d ) -1 d* ;
  61
  62 : d-sq ( d -- d ) dup d* ;
  63
  64 : d-recip ( d -- d' )
  65     >dimensioned< recip dimension-op> ;
  66
  67 : d/ ( d d -- d ) d-recip d* ;
  68
  69 : comparison-op ( d d -- n n ) 2dup check-dimensions 2values ;
  70
  71 : d< ( d d -- ? ) comparison-op < ;
  72
  73 : d<= ( d d -- ? ) comparison-op <= ;
  74
  75 : d> ( d d -- ? ) comparison-op > ;
  76
  77 : d>= ( d d -- ? ) comparison-op >= ;
  78
  79 : d= ( d d -- ? ) comparison-op number= ;
  80
  81 : d~ ( d d delta -- ? ) [ comparison-op ] dip ~ ;
  82
  83 : d-min ( d d -- d ) [ d< ] most ;
  84
  85 : d-max ( d d -- d ) [ d> ] most ;
  86
  87 : d-product ( v -- d ) 1 scalar [ d* ] reduce ;
  88
  89 : d-sum ( v -- d ) unclip-slice [ d+ ] reduce ;
  90
  91 : d-infimum ( v -- d ) unclip-slice [ d-min ] reduce ;
  92
  93 : d-supremum ( v -- d ) unclip-slice [ d-max ] reduce ;
  94
  95 \ d+ [ d- ] [ d- ] define-math-inverse
  96 \ d- [ d+ ] [ d- ] define-math-inverse
  97 \ d* [ d/ ] [ d/ ] define-math-inverse
  98 \ d/ [ d* ] [ d/ ] define-math-inverse
  99 \ d-recip [ d-recip ] define-inverse